WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FoxH[{{{a1,α1},…,{an,αn}},{{an+1,αn+1},…,{ap,αp}}},{{{b1,β1},…,{bm,βm}},{{bm+1,βm+1},…,{bq,βq}}},z]

FoxのH関数 である．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

FoxH

FoxH[{{{a1,α1},…,{an,αn}},{{an+1,αn+1},…,{ap,αp}}},{{{b1,β1},…,{bm,βm}},{{bm+1,βm+1},…,{bq,βq}}},z]

FoxのH関数 である．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • FoxHはMeijerG関数を一般化するもので，Mellin–Barnes積分 で定義される．ただし，と は正の実数で積分はの極をの極から分割する経路 に沿っている．
  • 経路 には以下の3つの選択肢がある．
    a. はで始まってで終るループで，のすべての極を正の方向に一度取り囲む．
    b. はで始まってで終るループで，のすべての極を負の方向に一度取り囲む．
    c. は，始まり，のすべての極がの極から分離されるように へ向かう曲線である．
  • および について なら， FoxHはMeijerGに特化されている．
  • FoxHは，多くの特殊ケースで他の関数に自動的に変換される．
  • FoxHは任意の複素パラメータについて評価できる．
  • FoxHは任意の数値精度で評価できる．
  • FoxHは自動的にリストに縫い込まれる． »

例題

すべて開く すべて閉じる

例  (5)

数値的に解釈する：

Wolfram Language code: FoxH[{{{(1/2), 1}}, {{(1/3), 2}}}, {{{(1/4), 3}}, {{π, 4}}}, 0.2]

FoxH関数をプロットする：

Wolfram Language code: Plot[FoxH[{{{(1/2), (2/3)}}, {}}, {{{(3/4), (4/5)}}, {{(5/6), (6/7)}}}, x], {x, 0, 10}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[FoxH[{{}, {}}, {{{-1, 1 / 2}}, {}}, z], {z, -3 - 3I, 3 + 3I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[FoxH[{{{a1, 1 / 2}}, {}}, {{{b1, 1}}, {}}, z], {z, 0, 1}]

Infinityにおける最高次の漸近項：

Wolfram Language code: Asymptotic[FoxH[{{{a1, 1}}, {}}, {{{b1, 1 / 2}}, {}}, z], z -> ∞]

スコープ  (28)

数値評価  (7)

高精度で評価する：

Wolfram Language code: N[FoxH[{{{1 / 10, 6 / 5}, {13 / 10, 1}}, {{17 / 5, 2}}}, {{{7 / 5, 2}}, {{1 / 5, 1}}}, 1 / 5], 50]

出力精度は入力精度に従う：

Wolfram Language code: FoxH[{{{1 / 10, 6 / 5}, {13 / 10, 1}}, {{17 / 5, 2}}}, {{{7 / 5, 2}}, {{1 / 5, 1}}}, 0.20000000000000000001]

FoxHは複素数パラメータの と を取る：

Wolfram Language code: FoxH[{{{1 / 10 + I, 6 / 5}, {13 / 10, 1}}, {{17 / 5, 2}}}, {{{7 / 5, 2}}, {{1 / 5, 1}}}, 1 / 5`20]
Wolfram Language code: FoxH[{{{1 / 10 + I, 6 / 5}, {1 / 2I, 1}}, {{17 / 5, 2}}}, {{{-4I, 2}}, {{1 / 5, 1}}}, 1 / 5`20]

FoxHは複素引数を取る：

Wolfram Language code: FoxH[{{{1 / 10 + I, 6 / 5}, {13 / 10, 1}}, {{17 / 5, 2}}}, {{{7 / 5, 2}}, {{1 / 5, 1}}}, 1 / 5`20 - I]

FoxHを高精度で効率的に評価する：

Wolfram Language code: FoxH[{{{1 / 10, 6 / 5}, {13 / 10, 1}}, {{17 / 5, 2}}}, {{{7 / 5, 2}}, {{1 / 5, 1}}}, 1 / 5`200]//Timing

自動縫込みを使って配列の要素ごとの値を計算する：

Wolfram Language code: FoxH[{{}, {}}, {{{1 + I, 1}}, {{3, 1}}}, {{1 / 2, -1}, {0, 1 / 2}}]

MatrixFunctionを使って行列のFoxH関数を計算することもできる：

Wolfram Language code: MatrixFunction[FoxH[{{}, {}}, {{{1 + I, 1}}, {{3, 1}}}, #]&, {{1 / 2, -1}, {0, 1 / 2}}]//FullSimplify

Aroundを使って平均的な場合の統計区間を計算する：

Wolfram Language code: FoxH[ {{{0, 1}}, {}}, {{{0, 1}}, {{0, 1}}}, Around[.9, 0.1]]

特定の値  (3)

固定点における値：

Wolfram Language code: FoxH[{{{0, 1}}, {}}, {{{0, 1}}, {{0, 1}}}, 5]
Wolfram Language code: FoxH[{{}, {}}, {{{1 + I, 1}}, {{3, 1}}}, 1]

FoxHを記号的に評価する：

Wolfram Language code: FoxH[{{{a, 1}}, {}}, {{{0, 1}}, {{b, 1}}}, z]
Wolfram Language code: FoxH[{{}, {{1, 1}}}, {{{1 / 2, 1}}, {}}, z]

零点における値：

Wolfram Language code: FoxH[{{{1 / 2, 1}}, {}}, {{{0, 1}}, {}}, 0]
Wolfram Language code: FoxH[{{{0, 1}}, {}}, {{{0, 1}}, {{0, 1 / 2}}}, 0]

可視化  (4)

FoxH関数族をプロットする：

Wolfram Language code: Plot[Evaluate[Table[FoxH[{{{(1/2), (2/3)}}, {}}, {{{b1, (4/5)}}, {{(5/6), (6/7)}}}, x], {b1, 0, 3}]], {x, 0, 10}, PlotRange -> All]

FoxH[{{},{}},{{{-1,1/2}},{}}, z]のComplexContourPlot：

Wolfram Language code: f = FoxH[{{}, {}}, {{{-1, 1 / 2}}, {}}, z];
Wolfram Language code: ComplexContourPlot[{Re[f], Im[f]}, {z, 4}, Contours -> 24]

AbsArgPlotとReImPlotを使ってFoxHの複素値を実数上にプロットする：

Wolfram Language code: AbsArgPlot[FoxH[{{{1 / 2, 1 / 4}}, {}}, {{{I, 3}}, {}}, x], {x, -1, 1}]
Wolfram Language code: ReImPlot[FoxH[{{{1 / 2, 1 / 4}}, {}}, {{{1 / 3 - 1 / 50I, 1}}, {}}, x], {x, -1, 1}]

FoxHをパラメータ および の関数としてプロットする：

Wolfram Language code: Plot3D[FoxH[{{}, {}}, {{{Subscript[b, 1], 1 / 2}}, {}}, x], {Subscript[b, 1], 0, 1}, {x, 0, 3}, ...]

関数の特性  (5)

FoxHは，単純なパラメータについて評価するとより簡単な関数になる：

Wolfram Language code: FoxH[{{{Subscript[a, 1], 2}, {Subscript[a, 2], 2}}, {{Subscript[a, 3], 2}}}, {{{Subscript[b, 1], 2}}, {{Subscript[b, 2], 2}}}, z]
Wolfram Language code: FoxH[{{}, {}}, {{{b, 1 / 2}}, {}}, z]

FoxHはとのペアについて対称である：

Wolfram Language code: FoxH[{{{Subscript[a, 1], Subscript[α, 1]}, {Subscript[a, 2], Subscript[α, 2]}}, {}}, {{}, {}}, z] == FoxH[{{{Subscript[a, 2], Subscript[α, 2]}, {Subscript[a, 1], Subscript[α, 1]}}, {}}, {{}, {}}, z]
Wolfram Language code: FoxH[{{}, {}}, {{}, {{Subscript[b, 1], Subscript[β, 1]}, {Subscript[b, 2], Subscript[β, 2]}}}, z] == FoxH[{{}, {}}, {{}, {{Subscript[b, 2], Subscript[β, 2]}, {Subscript[b, 1], Subscript[β, 1]}}}, z]

FoxHは，ペアのいくつかが等しい場合は，より簡単なFoxHに簡約できるかもしれない：

Wolfram Language code: FoxH[{{{Subscript[a, 1], Subscript[α, 1]}}, {}}, {{}, {{Subscript[a, 1], Subscript[α, 1]}, {Subscript[b, 2], Subscript[β, 2]}}}, z]

より複雑なケース：

Wolfram Language code: FoxH[{{{a1, A1}}, {{a2, A2}, {a3, A3}}}, {{{b1, B1}, {a2, A2}}, {{a1, A1}, {b2, B2}}}, z]

FoxHは要素単位で最後の引数のリストに縫い込まれる：

Wolfram Language code: FoxH[{{{1 / 10, 6 / 5}, {13 / 10, 1}}, {{17 / 5, 2}}}, {{{7 / 5, 2}}, {{1 / 5, 1}}}, {1 / 5`20, -0.1, 2I}]
Wolfram Language code: FoxH[{{{0.1, 3}}, {}}, {{{4 / 5, 3 / 2}}, {}}, (| | | | :- | :---- | | π | u | | v | (π/2) |)]

TraditionalFormによる表示：

Wolfram Language code: FoxH[{{{a, Sqrt[2]}}, {}}, {{{b, 3}}, {}}, z]//TraditionalForm
Wolfram Language code: FoxH[{{{1, 1}, {2, (1/2)}}, {{3, (1/3)}}}, {{{4, (1/4)}}, {{5, (1/5)}}}, z + (p/q)]//TraditionalForm

微分  (2)

z についての一次導関数：

Wolfram Language code: foxH = FoxH[{{{a1, α1}, {a2, α2}}, {{a3, α3}}}, {{{b1, β1}}, {{b2, β2}}}, z];
Wolfram Language code: D[foxH, z]

z についてのより高次の導関数：

Wolfram Language code: **D[foxH, {z, 4}] **

z についての特定のFoxHの 次導関数の式：

Wolfram Language code: D[FoxH[{{}, {}}, {{{ν, 1}}, {{-ν, 1}}}, z], {z, k}]// FullSimplify

積分  (3)

Integrateを使って不定積分を計算する：

Wolfram Language code: Integrate[FoxH[{{{a1, α1}}, {{a2, α2}}}, {{{b1, β1}}, {{b2, β2}}}, z], z]

不定積分を計算することでこれを確かめる：

Wolfram Language code: D[%, z]

定積分：

Wolfram Language code: Integrate[FoxH[{{{1, 1}}, {{2, 1}}}, {{{1 / 2, 1}}, {{-1 / 2, 1}}}, z], {z, 0, 5}]

その他の積分：

Wolfram Language code: Integrate[z^2 FoxH[{{{a1, α1}}, {{a2, α2}}}, {{{b1, β1}}, {{b2, β2}}}, z], z]
Wolfram Language code: Integrate[z FoxH[{{{1 / 2, 1}}, {{2, 1}}}, {{{1 / 2, 1}}, {{-3, 1}}}, z^2], {z, 0, 3}]

級数展開  (4)

原点におけるあるFoxH関数の級数展開を得る：

Wolfram Language code: Series[FoxH[{{{1, 1}}, {{2, 1 / 3}}}, {{{3, 2}}, {{4, 3}}}, x], {x, 0, 2}]

の周りのFoxH関数の最初の3つの近似：

Wolfram Language code: terms = Normal@Table[Series[FoxH[{{{1, 1}}, {{2, 1 / 10}}}, {{{3, 2}}, {{4, 3}}}, x], {x, 0, m}], {m, 0, 2}]

これらの近似をプロットする：

Wolfram Language code: Plot[Evaluate[{terms, FoxH[{{{1, 1}}, {{2, 1 / 10}}}, {{{3, 2}}, {{4, 3}}}, x]}], {x, 0, 100}]

原点における一般的なFoxH関数の級数展開を求める：

Wolfram Language code: Series[FoxH[{{{Subscript[a, 1], 1}}, {{Subscript[a, 2], 1 / 3}}}, {{{Subscript[b, 1], 1}, {Subscript[b, 2], 1 / 2}}, {{Subscript[b, 3], 3}}}, x], x -> 0]

Infinityにおける一般的なFoxH関数の級数展開を求める：

Wolfram Language code: Series[FoxH[{{{Subscript[a, 1], 1}, {Subscript[a, 2], 1 / 3}}, {{Subscript[a, 3], 3}}}, {{{Subscript[b, 1], 1}}, {{Subscript[b, 2], 2}}}, x], x -> ∞]

SeriesCoefficientを使って級数展開の一般項を得る：

Wolfram Language code: SeriesCoefficient[FoxH[{{{a, 1}}, {}}, {{{b, 1}}, {}}, x], {x, 1, m}]

アプリケーション  (3)

FoxHReduceを使ってほとんどすべての数学関数のFoxHによる表現を得る：

Wolfram Language code: FoxHReduce[Sin[a x], x]

より珍しい組合せ：

Wolfram Language code: FoxHReduce[E^-x UnitStep[1 - Abs[x]], x]

三項式 の根はFoxHによって書くことができる：

Wolfram Language code: root = (1/2) t FoxH[{{{0, 1}, {0, (3/2)}}, {}}, {{{0, 1}}, {{-1, 1}, {0, (1/2)}}}, -t] - 1;

についてこれを確認する：

Wolfram Language code: t = N[(1/4), 20]; z^3 - z - t /. z -> root

一般的な三項式 の根もFoxHによって書くことができる：

Wolfram Language code: roots = Exp[(2π I/n - 1)]^-j + (t/n - 1)FoxH[{{{0, 1}, {0, (n/n - 1)}}, {}}, {{{0, 1}}, {{-1, 1}, {0, (1/n - 1)}}}, t Exp[(2π I/n - 1)]^j];

これらの根を と について確認する：

Wolfram Language code: n = 6;
Wolfram Language code: z^n - z - t /. z -> Table[roots, {j, 0, n - 2}]

StableDistributionのPDFを，のときにFoxHによって表す：

Wolfram Language code: StableDistributionPDF[x_, α_, β_, μ_, σ_] := With[{Α = σ (1 + β^2Tan[(π α/2)]^2)^(1/2α), Β = (2/π α)Sign[x - μ]ArcTan[β Tan[(π α/2)]]}, (1/α Α) * FoxH[{{{1 - (1/α), (1/α)}}, {{ (1 - Β/2), (1 + Β/2)}}}, {{{0, 1}}, {{ (1 - Β/2), (1 + Β/2)}}}, (Abs[x - μ]/Α)]]

評価してStableDistributionを使って生成された組込みのPDFと比較する：

Wolfram Language code: Show[{ListPlot[Table[{x, StableDistributionPDF[x, 0.6, 0.4, 0.5, 2]}, {x, -20, 20, 0.2}], ...], Plot[PDF[StableDistribution[1, 0.6, 0.4, 0.5, 2], x], {x, -20, 20}, ...]}]

特性と関係  (3)

数学的特殊関数の多くはFoxHの特殊ケースである：

Wolfram Language code: FoxH[{{}, {}}, {{{b, 1 / 2}}, {}}, z]
Wolfram Language code: FoxH[{{{0, 1}}, {}}, {{{0, 1}}, {{0, 5 / 3}}}, z]
Wolfram Language code: FoxH[{{{a1, 1}}, {{a2, 1}}}, {{{b1, 1}}, {{b2, 1}}}, z]

FunctionExpandを使ってFoxHをより簡単な関数に展開する：

Wolfram Language code: FoxH[{{{1, 1}}, {{0, (1/2)}, {(1/2), 1}}}, {{{(1/2), (1/2)}}, {{0, (1/2)}, {0, 1}, {(1/2), 1}}}, z]
Wolfram Language code: FunctionExpand[%]

FoxHReduceは関数のFoxH表現を返す：

Wolfram Language code: FoxHReduce[Sin[x], x]

考えられる問題  (3)

はFoxHの特異点である：

Wolfram Language code: FoxH[{{{1 / 3, 3}}, {}}, {{{4 / 5, 3 / 2}}, {}}, 0]

原点におけるSeriesはパラメータ が正でパラメータ が正の厳密値のときにのみ得られる：

Wolfram Language code: Series[FoxH[{{{1 / 3, 3 / 2}}, {}}, {{{4 / 5, 3}}, {}}, z], z -> 0]
Wolfram Language code: Series[FoxH[{{{1 / 3, 3 / 2}}, {}}, {{{4 / 5, -3}}, {}}, z], z -> 0]

InfinityにおけるSeriesはパラメータ および が正で後者が厳密値のときにのみ得られる：

Wolfram Language code: Series[FoxH[{{{1 / 3, 3}}, {}}, {{{4 / 5, 3 / 2}}, {}}, z], z -> ∞]
Wolfram Language code: Series[FoxH[{{{1 / 3, -3}}, {}}, {{{4 / 5, 3 / 2}}, {}}, z], z -> ∞]

おもしろい例題  (1)

初等関数および特殊関数の多くはFoxHの特殊ケースである：

Wolfram Language code: FoxHlist = Inactivate[{FoxH[{{}, {}}, {{{0, 1}}, {}}, x], FoxH[{{}, {}}, {{{b, 2}}, {}}, x], FoxH[{{{0, 1}}, {}}, {{{0, 1}}, {{0, (2/3)}}}, x], FoxH[{{{0, 1}}, {}}, {{{0, 1}}, {{2, (2/3)}}}, x], FoxH[{{}, {}}, {{{(n/2), (1/2)}}, {{-(n/2), (1/2)}}}, (x/2)], FoxH[{{{1 - a, 1}, {1 - b, 1}}, {}}, {{{0, 1}}, {{1 - c, 1}}}, x], FoxH[{{{Subscript[a, 1], 1}, {Subscript[a, 2], 1}}, {{Subscript[a, 3], 1}}}, {{{Subscript[b, 1], 1}}, {{Subscript[b, 2], 1}}}, x], FoxH[{{{Subscript[a, 1], 3}, {Subscript[a, 2], 3}}, {{Subscript[a, 2], 3}}}, {{{Subscript[b, 1], 3}}, {{Subscript[b, 2], 3}}}, x]}, FoxH];
Wolfram Language code: Grid[Join[{{Text["FoxH with specific parameters"], Text["Simpler function"]}}, Transpose[{HoldForm /@ FoxHlist /.  Inactive[FoxH] -> FoxH, Activate[FoxHlist]}]], IconizedObject[«Grid options»]]//TraditionalForm
Wolfram Research (2021), FoxH, Wolfram言語関数， https://reference.wolfram.com/language/ref/FoxH.html （2021年に更新）.

テキスト

Wolfram Research (2021), FoxH, Wolfram言語関数， https://reference.wolfram.com/language/ref/FoxH.html （2021年に更新）.

CMS

Wolfram Language. 2021. "FoxH." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/FoxH.html.

APA

Wolfram Language. (2021). FoxH. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FoxH.html

BibTeX

@misc{reference.wolfram_2026_foxh, author="Wolfram Research", title="{FoxH}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/FoxH.html}", note=[Accessed: 05-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_foxh, organization={Wolfram Research}, title={FoxH}, year={2021}, url={https://reference.wolfram.com/language/ref/FoxH.html}, note=[Accessed: 05-November-2026]}