WOLFRAM

Wolfram 语言与系统参考资料中心

FrequencySamplingFilterKernel[{a1,…,ak}]

从幅值 ai 使用频率采样方法创建有限脉冲响应 (FIR) 滤波核.

FrequencySamplingFilterKernel[{a1,…,ak},m]

创建类型为 m 的 FIR 滤波器内核.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
"Shifted"  
WorkingPrecision  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

FrequencySamplingFilterKernel

FrequencySamplingFilterKernel[{a1,…,ak}]

从幅值 ai 使用频率采样方法创建有限脉冲响应 (FIR) 滤波核.

FrequencySamplingFilterKernel[{a1,…,ak},m]

创建类型为 m 的 FIR 滤波器内核.

更多信息和选项

  • 对于幅值列表 {a1,a2,…,ak} 创建的 FIR 滤波器的可能类型 m 是：
  • 默认类型是 .
  • 频率采样方法对从 0 到 的频率域进行均匀采样.
  • FrequencySamplingFilterKernel 默认情况下使用整数的倍数 处的频率域的采样，其中 是滤波器的长度. 设置 "Shifted"->True 下，频率从 0 平移 . »
  • 幅值应该是非负的. 通常，数值 ai=0 指定了抑止频带，并且数值 ai=1 指定了传输频带.
  • 由 FrequencySamplingFilterKernel 返回的内核 ker 可用于 ListConvolve[ker,data] 中，以对 data 应用滤波器.
  • 可给出以下选项：
  • "Shifted" False第一个频率是否偏离 0
    WorkingPrecision MachinePrecision内部计算使用的精度

范例

打开所有单元 关闭所有单元

基本范例  (1)

一个低通 FIR 滤波器：

Wolfram Language code: h = FrequencySamplingFilterKernel[{1, 1, 1, 0, 0, 0, 0}]

滤波器的幅值响应：

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}, PlotRange -> All]

范围  (7)

具有偶数对称和奇数长度的类型 1 FIR 内核：

Wolfram Language code: h = FrequencySamplingFilterKernel[{1, 1, 1, 0, 0, 0}, 1]
Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

具有偶数对称和偶数长度的类型 2 FIR 内核：

Wolfram Language code: h = FrequencySamplingFilterKernel[{1, 1, 1, 0, 0, 0}, 2]
Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

具有奇数对称和奇数长度的类型 3 FIR 内核：

Wolfram Language code: h = FrequencySamplingFilterKernel[{0, 0, 1, 1, 0, 0}, 3]
Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}, PlotRange -> All]

一个奇对称偶数长度（类型 4）的高通核：

Wolfram Language code: h = FrequencySamplingFilterKernel[{0, 0, 0, 1, 1, 1}, 4]
Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

全频带微分 FIR 核：

Wolfram Language code: h = FrequencySamplingFilterKernel[(Range[4] - 1 / 2) / 4, 4, "Shifted" -> True]; Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

根据随机幅值列表创建滤波器：

Wolfram Language code: a = RandomReal[1, 6]
Wolfram Language code: h = FrequencySamplingFilterKernel[a, 1]; Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}, PlotRange -> All]

从任意函数创建滤波器：

Wolfram Language code: a = Table[1 / 2(Cos[x] + 1), {x, 0, π, π / 5}]//N
Wolfram Language code: h = FrequencySamplingFilterKernel[a, 1]; Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}, PlotRange -> All]

选项  (2)

"Shifted"  (1)

默认情况下，第一个频率在 0 处采样：

Wolfram Language code: a = FrequencySamplingFilterKernel[{1, 1, 0, 0}]
Wolfram Language code: Show[Plot[Abs[ListFourierSequenceTransform[a, x]], {x, 0, π}, PlotRange -> All], ListPlot[{{(0Pi / 14), 1}, {(4Pi / 14), 1}, {(8Pi / 14), 0}, {12Pi / 14, 0}}, Filling -> 0, PlotStyle -> {Red, PointSize[Large]}]]

设置 "Shifted"->True，第一频率从 0 位移 ：

Wolfram Language code: a = FrequencySamplingFilterKernel[{1, 1, 0, 0}, "Shifted" -> True]
Wolfram Language code: Show[Plot[Abs[ListFourierSequenceTransform[a, x]], {x, 0, π}, PlotRange -> All], ListPlot[{{(2Pi / 14), 1}, {(6Pi / 14), 1}, {(10Pi / 14), 0}, {Pi, 0}}, Filling -> 0, PlotStyle -> {Red, PointSize[Large]}]]

WorkingPrecision  (1)

默认情况下使用 MachinePrecision：

Wolfram Language code: h = FrequencySamplingFilterKernel[{1, 1, 1, 1, 0, 0, 0, 0}]

使用 2 位精度的算术：

Wolfram Language code: g = Rationalize[#, 0]& /@ FrequencySamplingFilterKernel[{1, 1, 1, 1, 0, 0, 0, 0}, WorkingPrecision -> 2]

比较两个结果：

Wolfram Language code: Plot[Evaluate[{Abs[ListFourierSequenceTransform[h, x]], Abs[ListFourierSequenceTransform[g, x]]}], {x, 0, π}, PlotRange -> All]

应用  (2)

通过低通滤波器内核进行卷积，对数据进行平滑处理：

Wolfram Language code: data = Table[ Sin[x] + RandomReal[.2], {x, 0, 2 Pi, 0.05}]; ker = FrequencySamplingFilterKernel[{1, 1, 0, 0, 0, 0, 0}]; ListLinePlot /@ {data, ListConvolve[ker, data, 7]}

把导数滤波器应用图像的行：

Wolfram Language code: a = FrequencySamplingFilterKernel[{(1/8), (3/8), (5/8), (7/8)}, 4, "Shifted" -> True]; ImageConvolve[[image], {a}]//ImageAdjust

属性和关系  (1)

把窗应用于 FIR 滤波器，以减少幅值响应中的波纹：

Wolfram Language code: fir = FrequencySamplingFilterKernel[{1, 1, 1, 0, 0, 0}]
Wolfram Language code: win = Array[BlackmanWindow, Length[fir], {-1 / 2, 1 / 2}];
Wolfram Language code: Plot[Evaluate[Abs[ListFourierSequenceTransform[#, x]]& /@ {fir, win fir}], {x, 0, π}]
Wolfram Research (2012)，FrequencySamplingFilterKernel，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FrequencySamplingFilterKernel.html.

文本

Wolfram Research (2012)，FrequencySamplingFilterKernel，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FrequencySamplingFilterKernel.html.

CMS

Wolfram 语言. 2012. "FrequencySamplingFilterKernel." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/FrequencySamplingFilterKernel.html.

APA

Wolfram 语言. (2012). FrequencySamplingFilterKernel. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FrequencySamplingFilterKernel.html 年

BibTeX

@misc{reference.wolfram_2026_frequencysamplingfilterkernel, author="Wolfram Research", title="{FrequencySamplingFilterKernel}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/FrequencySamplingFilterKernel.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_frequencysamplingfilterkernel, organization={Wolfram Research}, title={FrequencySamplingFilterKernel}, year={2012}, url={https://reference.wolfram.com/language/ref/FrequencySamplingFilterKernel.html}, note=[Accessed: 03-November-2026]}