WOLFRAM

Wolfram 语言与系统参考资料中心

FunctionDiscontinuities[f,x]

x∈Reals，求 的断点.

FunctionDiscontinuities[f,x,dom]

x∈dom，求 的断点.

FunctionDiscontinuities[{f1,f2,…},{x1,x2,…},dom]

x1,x2,…∈dom，求 的断点.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
基本应用  
微积分  
可视化  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

FunctionDiscontinuities

FunctionDiscontinuities[f,x]

x∈Reals，求 的断点.

FunctionDiscontinuities[f,x,dom]

x∈dom，求 的断点.

FunctionDiscontinuities[{f1,f2,…},{x1,x2,…},dom]

x1,x2,…∈dom，求 的断点.

更多信息

  • 函数的断点通常用于查找保证函数连续的区域或查找需要进行特殊分析的点和曲线.
  • FunctionDiscontinuities 给出使得 在 中连续的集合 的隐式描述. 不能保证集合 是最小的.
  • 所得的隐式描述由等式、不等式、域的规范以及它们的逻辑组合组成，适合用在 Reduce 和 Solve，等函数中.
  • dom 的可能的值为 Reals 和 Complexes.

范例

打开所有单元 关闭所有单元

基本范例  (4)

求实单变量函数的断点：

Wolfram Language code: FunctionDiscontinuities[Tan[x], x]

求复单变量函数的断点：

Wolfram Language code: FunctionDiscontinuities[Log[x], x, Complexes]

求实多变量函数的断点：

Wolfram Language code: FunctionDiscontinuities[Beta[x, y], {x, y}]

求复多变量函数的断点：

Wolfram Language code: FunctionDiscontinuities[ArcTan[x ^ y], {x, y}, Complexes]

范围  (6)

实单变量函数的断点：

Wolfram Language code: FunctionDiscontinuities[Gamma[x], x]

求位于 和 之间的断点：

Wolfram Language code: Solve[% && -5 ≤ x ≤ 5, x, Reals]

可视化断点：

Wolfram Language code: Plot[Gamma[x], {x, -5, 5}, Epilog -> {PointSize[Medium], Red, Point[{x, 0}] /. %}]

求复合函数的断点：

Wolfram Language code: FunctionDiscontinuities[Floor[1 / (x ^ 2 - 1)], x]

求位于 和 之间的断点集合：

Wolfram Language code: Solve[% && -2 ≤ x ≤ 2 && Abs[1 / (x ^ 2 - 1)] < 7, x, Reals]

可视化断点：

Wolfram Language code: Plot[Floor[1 / (x ^ 2 - 1)], {x, -2, 2}, PlotStyle -> Thick, Epilog -> {Red, Thin, Dotted, InfiniteLine[{x, 0}, {0, 1}] /. %}]

实数上的断点包括函数值不是实数的点：

Wolfram Language code: FunctionDiscontinuities[Sqrt[x], x]

复单变量函数的断点：

Wolfram Language code: FunctionDiscontinuities[ArcTan[z ^ 2], z, Complexes]

按 Re[z] 和 Im[z] 计算断点：

Wolfram Language code: Reduce[%, z]

可视化断点：

Wolfram Language code: Show[{ComplexPlot[ArcTan[z ^ 2], {z, -2 - 2I, 2 + 2I}], Region[Style[ImplicitRegion[%, {Re[z], Im[z]}], Red]]}]

实多变量函数的断点：

Wolfram Language code: FunctionDiscontinuities[(x ^ 2 + y ^ 2)Csc[x y], {x, y}]

可视化断点：

Wolfram Language code: Show[{Plot3D[(x ^ 2 + y ^ 2)Csc[x y], {x, -3, 3}, {y, -3, 3}], ContourPlot3D@@{%, {x, -3, 3}, {y, -3, 3}, {z, -40, 40}, ContourStyle -> {Red, Opacity[0.7]}, Mesh -> False}}]

复映射的断点：

Wolfram Language code: FunctionDiscontinuities[{Sqrt[x - y], Log[x + y]}, {x, y}, Complexes]

应用  (6)

基本应用  (4)

求 x+cos(x) TemplateBox[{{{sin, (, x, )}}}, UnitStepSeq] 的断点：

Wolfram Language code: f = x + Cos[x] UnitStep[Sin[x]];
Wolfram Language code: FunctionDiscontinuities[f, x]

求 和 之间的断点：

Wolfram Language code: Solve[% && -5Pi ≤ x ≤ 5Pi, x, Reals]

可视化断点：

Wolfram Language code: Plot[f, {x, -5Pi, 5Pi}, Epilog -> {Red, Thin, Dotted, InfiniteLine[{x, 0}, {0, 1}] /. %}]

求 max(log(TemplateBox[{x}, Abs]+1),x sin(x)) 的断点：

Wolfram Language code: f = Max[Log[Abs[x] + 1], x Sin[x]];
Wolfram Language code: FunctionDiscontinuities[f, x]

结果显示没有断点：

Wolfram Language code: Reduce[%, x, Reals]

函数 是连续的：

Wolfram Language code: Plot[f, {x, -20, 20}]

求复变函数 的断点：

Wolfram Language code: f = Log[z ^ 3];
Wolfram Language code: FunctionDiscontinuities[f, z, Complexes]

按 Re[z] 和 Im[z] 计算断点：

Wolfram Language code: Reduce[%, z]

可视化断点：

Wolfram Language code: Show[{ComplexPlot[f, {z, -2 - 2I, 2 + 2I}], Region[Style[ImplicitRegion[%, {{Re[z], -2, 2}, {Im[z], -2, 2}}], Red]]}]

给定 和 的断点，求 的断点：

Wolfram Language code: f[y_] := 1 / (y ^ 2 - 1) g[x_] := Csc[x]

假定 和 的断点被包含在 和 的解集中：

Wolfram Language code: Φ = FunctionDiscontinuities[f[y], y]
Wolfram Language code: Ψ = FunctionDiscontinuities[g[x], x]

的断点被包含在 的解集中：

Wolfram Language code: FunctionDiscontinuities[f[g[x]], x]
Wolfram Language code: (Φ /. y -> g[x]) || Ψ

微积分  (1)

如果 在 处是连续的，则 TemplateBox[{{f, (, x, )}, x, a}, Limit2Arg, DisplayFunction -> ({Sequence[{Sequence["lim"], _, DocumentationBuild`Utils`Private`Parenth[{#2, ->, #3}, LimitsPositioning -> True]}], #1} & ), InterpretationFunction -> ({Limit, [, {#1, ,, {#2, ->, #3}}, ]} & )]=f(a)：

Wolfram Language code: f = Sin[5 x] Floor[x + Ceiling[Tan[x] ^ 2]];
Wolfram Language code: FunctionDiscontinuities[f, x]

查看 在 处是否连续：

Wolfram Language code: % /. x -> 5 / 4

可通过简单的替代算出 在 处的极限：

Wolfram Language code: f /. x -> 5 / 4
Wolfram Language code: Limit[f, x -> 5 / 4]
Wolfram Language code: Plot[f, {x, 0, Pi}, Epilog -> {Red, Point[{5 / 4, %}]}]

可视化  (1)

用断点求 Plot 的 Exclusions 设置：

Wolfram Language code: f = Clip[Floor[Gamma[x]], {-10, 10}];
Wolfram Language code: disc = FunctionDiscontinuities[f, x]

将断点转换为 Exclusions 要求的格式：

Wolfram Language code: excl[e_Or] := Join@@(excl /@ List@@e) excl[And[a___, e_Equal, b___]] := {{e, And[a, b]}} excl[e_Equal] := {{e, True}} excl[other_] := {}
Wolfram Language code: ex = excl[disc]

在 Plot 中使用 exclusions：

Wolfram Language code: Plot[f, {x, -1, 1}, Exclusions -> ex]

与不使用 exclusions 的图相比较：

Wolfram Language code: Plot[f, {x, -1, 1}, Exclusions -> None]

属性和关系  (2)

在 FunctionDiscontinuities 给出的集合外函数是连续的：

Wolfram Language code: FunctionDiscontinuities[Tan[x], x]

用 FunctionContinuous 查看连续性：

Wolfram Language code: FunctionContinuous[{Tan[x], Not[%]}, x]

FunctionSingularities 给出一个集合，函数在该集合外解析：

Wolfram Language code: FunctionSingularities[Abs[x] / (x ^ 2 - 1), x]

断点集合是奇点集合的子集：

Wolfram Language code: FunctionDiscontinuities[Abs[x] / (x ^ 2 - 1), x]
Wolfram Language code: Show[{Plot[Abs[x] / (x ^ 2 - 1), {x, -2, 2}], ListPlot[...]}]

可能存在的问题  (2)

返回的断点集合可能不是最小的：

Wolfram Language code: FunctionDiscontinuities[UnitStep[x - 1] UnitStep[-x], x]

该函数完全为零，因此没有断点：

Wolfram Language code: PiecewiseExpand[UnitStep[x - 1] UnitStep[-x]]

当一些断点信息缺失时，将给出错误消息并返回已知的断点：

Wolfram Language code: FunctionDiscontinuities[f[x] + Tan[x], x]
Wolfram Research (2020)，FunctionDiscontinuities，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FunctionDiscontinuities.html.

文本

Wolfram Research (2020)，FunctionDiscontinuities，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FunctionDiscontinuities.html.

CMS

Wolfram 语言. 2020. "FunctionDiscontinuities." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/FunctionDiscontinuities.html.

APA

Wolfram 语言. (2020). FunctionDiscontinuities. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FunctionDiscontinuities.html 年

BibTeX

@misc{reference.wolfram_2026_functiondiscontinuities, author="Wolfram Research", title="{FunctionDiscontinuities}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/FunctionDiscontinuities.html}", note=[Accessed: 02-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_functiondiscontinuities, organization={Wolfram Research}, title={FunctionDiscontinuities}, year={2020}, url={https://reference.wolfram.com/language/ref/FunctionDiscontinuities.html}, note=[Accessed: 02-November-2026]}