WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

GatherBy[list,f]

list 中の要素を，f を適用したときに同じ値を返す要素ごとのサブリストにする．

GatherBy[list,{f1,f2,…}]

list をレベル i で fiを使うネストしたサブリストにする．

GatherBy[f]

式に適用可能なGatherByの演算子形を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
関連リンク
履歴
引用書式

GatherBy

GatherBy[list,f]

list 中の要素を，f を適用したときに同じ値を返す要素ごとのサブリストにする．

GatherBy[list,{f1,f2,…}]

list をレベル i で fiを使うネストしたサブリストにする．

GatherBy[f]

式に適用可能なGatherByの演算子形を表す．

詳細

  • GatherBy[{e1,e2,e3,…},f]は各 i について f[ei]を評価し，eiをどのように集めるかを決める．
  • GatherBy[list,…]は，list 中の要素の順番に従った結果を返す．
  • GatherBy[list,…]で生成される各サブリストにおける要素の出現順は list におけるそれと等しい．サブリスト全体が list におけるのと同じ順で最初の要素が現れるように並べられる．
  • GatherBy[list,Identity]はGather[list]に等しい． »
  • GatherByは事実上同値分割を行う．
  • GatherBy[list,{f1,f2}]はMap[GatherBy[#,f2]&,GatherBy[list,f1]]に等しい． »
  • GatherBy[f][list]はGatherBy[list,f]に等しい． »

例題

すべて開く すべて閉じる

例  (2)

データを奇数と偶数のリストに分ける：

Wolfram Language code: GatherBy[{1, 2, 3, 4, 5}, OddQ]

最初の部分で分ける：

Wolfram Language code: GatherBy[{{a, 1}, {b, 1}, {a, 2}, {d, 1}, {b, 3}}, First]

スコープ  (4)

剰余で集める：

Wolfram Language code: GatherBy[Range[10], Mod[#, 3]&]

第一成分によってグループ化し，そのグループ内では最後の成分によってグループ化する：

Wolfram Language code: Tuples[{{a, b}, {1, 2}, {x, y}}]
Wolfram Language code: GatherBy[%, {First, Last}]

Framedを使ってグループ化を表示する：

Wolfram Language code: Map[Framed, %, {1, 2}]

GatherBy演算子を定義する：

Wolfram Language code: op = GatherBy[Last];

整数データを収集するために演算子を用い，各グループを列のそれぞれ別個の行に配置する：

Wolfram Language code: ints = RandomInteger[4, {10, 3}]; op[ints]//Column

演算子を使って文字列データを集める：

Wolfram Language code: words = RandomChoice[RandomWord[5], {10, 2}]; op[words]//Column

連想のリストを作成する：

Wolfram Language code: data = Table[AssociationThread[CharacterRange["a", "c"] -> RandomInteger[5, 3]], {10}]

キー"a"の値で集める：

Wolfram Language code: Framed /@ GatherBy[data, #a&]

GatherByの演算子形式を用いて，キー"a"と"b"の値によって収集する：

Wolfram Language code: Map[Framed, GatherBy[{#a&, #b&}][data], {1, 2}]

アプリケーション  (4)

文字列を最初の文字によってソートし，次に分ける：

Wolfram Language code: words = RandomChoice[WordData[], {1000}];
Wolfram Language code: f = StringTake[#, {1}]&;
Wolfram Language code: GatherBy[SortBy[words, f], f]//Short

年ごとに日付を集める：

Wolfram Language code: Flatten@Table[DateString[{y, m}, {"Month", "/", "YearShort"}], {y, RandomChoice[Range[2000, 2010], 5]}, {m, RandomChoice[Range[12], 3]}]
Wolfram Language code: GatherBy[%, DateList[{#, {"Month", "/", "YearShort"}}][[1]]&]

データのシミュレーションを行う：

Wolfram Language code: data = Transpose[{RandomReal[5, 10], RandomChoice[{a, b, c}, 10], RandomReal[10, 10]}]

第2要素の値に基づいて要素をグループ化する：

Wolfram Language code: gathered = GatherBy[data, #[[2]]&]

各グループ内のデータ点の数を数える：

Wolfram Language code: Map[{#[[1, 2]], Length[#[[All, -1]]]}&, gathered]

グループごとに第3要素の平均を計算する：

Wolfram Language code: Map[{#[[1, 2]], Mean[#[[All, -1]]]}&, gathered]

最後の tol ビットの丸めるに基づいて，機械数を同値類ごとにグループ化する：

Wolfram Language code: tol = 7; f[x_] := Module[{re = Round[RealExponent[x, 2]], e}, e = (53 - tol - re); m = 2 ^ e; N[Round[x m] / m]];

1に近い相異なる機械数の順序付けられていないサンプルを生成する：

Wolfram Language code: ϵ = $MachineEpsilon; r = RandomSample[Table[1 + k ϵ, {k, 100}]]

同値類ごとに収集する：

Wolfram Language code: g = GatherBy[r, f]

の因子 がどのようにグループ化されたかを示す：

Wolfram Language code: Round[(g - 1) / ϵ]

次は，となるような同値の代表 と値 である：

Wolfram Language code: Table[{InputForm[r = f[x]], (r - 1) / ϵ}, {x, g[[All, 1]]}]

特性と関係  (4)

GatherBy[list,Identity]はGather[list]に等しい：

Wolfram Language code: list = RandomInteger[10, 10]; GatherBy[list, Identity] === Gather[list]

GatherBy[list,f]はGather[list,(f[#1]===f[#2])&]に等しい：

Wolfram Language code: m = RandomInteger[1, {10, 5}]; GatherBy[m, Norm] == Gather[m, (Norm[#1] === Norm[#2])&]

グループを，各グループのノルムとともに表示する：

Wolfram Language code: Grid[Map[{MatrixForm[#], Norm[First[#]]}&, GatherBy[m, Norm] ]]

GatherBy[list,{f1,f2}]はMap[GatherBy[#,f2]&,GatherBy[list,f1]]に等しい：

Wolfram Language code: list = Range[-4, 4]; GatherBy[list, {Positive, EvenQ}] === Map[GatherBy[#, EvenQ]&, GatherBy[list, Positive]]

GatherBy[f][list]はGatherBy[list,f]に等しい：

Wolfram Language code: list = Range[-4, 4]; GatherBy[EvenQ][list] === GatherBy[list, EvenQ]
Wolfram Research (2008), GatherBy, Wolfram言語関数， https://reference.wolfram.com/language/ref/GatherBy.html （2026年に更新）.

テキスト

Wolfram Research (2008), GatherBy, Wolfram言語関数， https://reference.wolfram.com/language/ref/GatherBy.html （2026年に更新）.

CMS

Wolfram Language. 2008. "GatherBy." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/GatherBy.html.

APA

Wolfram Language. (2008). GatherBy. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GatherBy.html

BibTeX

@misc{reference.wolfram_2026_gatherby, author="Wolfram Research", title="{GatherBy}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/GatherBy.html}", note=[Accessed: 04-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_gatherby, organization={Wolfram Research}, title={GatherBy}, year={2026}, url={https://reference.wolfram.com/language/ref/GatherBy.html}, note=[Accessed: 04-November-2026]}