WOLFRAM

Wolfram 语言与系统参考资料中心

HoldAll

是一个属性，指定一个函数的所有自变量保持不计算的形式.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
技术笔记
相关指南
相关的工作流程
历史
按以下格式引用：

HoldAll

HoldAll

是一个属性，指定一个函数的所有自变量保持不计算的形式.

更多信息

  • 用户可以使用 Evaluate 以可控方式计算带有 HoldAll 属性函数的自变量.
  • 即使一个函数有 HoldAll 属性，默认情况下，出现在它自变量中的 Sequence 对象仍然会被压平，Unevaluated 封装会被剥除，且会使用和自变量相关的上值. »

范例

打开所有单元 关闭所有单元

基本范例  (1)

为函数 f 赋予属性 HoldAll：

Wolfram Language code: SetAttributes[f, HoldAll]

因此，在进入（在本例中不存在的）函数体之前，参数不会被求值：

Wolfram Language code: f[1 + 1, 2 + 2, 3 + 3]

将其与一个没有任何属性的函数 g 进行比较：

Wolfram Language code: g[1 + 1, 2 + 2, 3 + 3]

范围  (2)

这是计算结果的完全形式：

Wolfram Language code: FullForm[1 - 1]

这是计算前输入的完全形式：

Wolfram Language code: HoldForm[FullForm[1 - 1]]

这是因为 HoldForm 具有 HoldAll 属性，所以才能实现这一点：

Wolfram Language code: Attributes[HoldForm]

为函数 inout 赋予属性 HoldAll：

Wolfram Language code: SetAttributes[inout, HoldAll]

定义一个具有两个参数的函数，它返回用 Hold 封装的这两个参数，以及未进行封装的第一个参数：

Wolfram Language code: inout[in_, tag_] := {Hold[in], in, Hold[tag]}

在进入函数体之前，两个参数都不会被求值，但第一个参数会在函数内部被求值：

Wolfram Language code: inout[1 - 1, 1 + 1]

应用  (3)

许多具有作用域行为的函数都有 HoldAll 属性：

Wolfram Language code: Attributes[Plot//Evaluate]

绘制函数列表，不同的函数使用不同的样式：

Wolfram Language code: Plot[{Sin[x], Cos[x]}, {x, 0, 2π}]

如果列表结构不明显，则不分别提供样式：

Wolfram Language code: Plot[Through[{Sin, Cos}[x]], {x, 0, 2π}]

使用 Evaluate 使得列表结构清晰明显：

Wolfram Language code: Plot[Evaluate[Through[{Sin, Cos}[x]]], {x, 0, 2π}]

在列表中不同的向量值函数仍然会以不同的样式展示：

Wolfram Language code: Plot[{Through[{Sin, Cos}[x]], Through[{Tan, Cot}[x]]}, {x, 0, 2π}]

用 HoldAll 和 Unevaluated 在计算发生时抑制符号计算：

Wolfram Language code: SetAttributes[symbolLength, HoldAll]; symbolLength[s_Symbol] := StringLength[SymbolName[Unevaluated[s]]]

求一个符号名的长度，即使它有一个值：

Wolfram Language code: xyzzy = 1;
Wolfram Language code: symbolLength[xyzzy]

实现您自己的控制结构：

Wolfram Language code: until::usage = "until[cond,cmd] repeats evaluating cmd until cond is True.";
Wolfram Language code: SetAttributes[until, HoldAll]
Wolfram Language code: until[cond_, cmd_] := While[True, cmd;If[cond, Return[]]]
Wolfram Language code: i = 1; until[Prime[i] > 10 ^ 6, i++];i

属性和关系  (12)

Hold 是一个带有属性 HoldAll 的容器：

Wolfram Language code: Attributes[Hold]
Wolfram Language code: Hold[1 + 2]

在符号上运算的函数通常需要 HoldAll 属性：

Wolfram Language code: i = 5; Protect[i]

没有这个属性，它们会在符号值上运算：

Wolfram Language code: Protect[Evaluate[i]]

类似 Table 的控制结构会避免对它们的参数进行计算：

Wolfram Language code: i = 5;
Wolfram Language code: Table[i, {i, 1, 4}]

否则，全局值会干扰它们的操作：

Wolfram Language code: Table[Evaluate[i], {i, 1, 4}]

用 Evaluate 强制计算一个 HoldAll 函数的参数：

Wolfram Language code: Attributes[Unprotect]
Wolfram Language code: syms = {Plus, Times};
Wolfram Language code: Unprotect[Evaluate[syms]]

强制对延迟定义的右侧进行求值：

Wolfram Language code: Expand[(1 + x) ^ 3]
Wolfram Language code: f[x_] := Evaluate[%]
Wolfram Language code: Definition[f]

使用 Unevaluated 来暂时将函数视为具有属性 HoldAll：

Wolfram Language code: Length[Unevaluated[1 + 2 + 3]]
Wolfram Language code: Length[1 + 2 + 3]

抑制对纯函数参数的求值：

Wolfram Language code: Function[e, Hold[e], {HoldAll}][1 + 2]
Wolfram Language code: Function[e, Hold[e]][1 + 2]

对具有 HoldAll 属性的函数，依然存在序列连接：

Wolfram Language code: SetAttributes[f, HoldAll] f[Sequence[a, b, c]]

Unevaluated 在进入函数体之前会被剥离：

Wolfram Language code: f[x_] := Hold[x] f[Unevaluated[1 + 1]]
Wolfram Language code: _[___, g, ___] ^:= "upvalue" f[Sequence[a, b, c], g]

属性 HoldAllComplete 会抑制全部这三种行为：

Wolfram Language code: Attributes[HoldComplete]
Wolfram Language code: HoldComplete[Sequence[a, b, c], g]

替换操作可用在一个保持不计算的表达式上：

Wolfram Language code: Hold[f[1 + 2]] /. f[x_] :> g[x]

插入一个保持不计算的表达式：

Wolfram Language code: Insert[Hold[x + x], y, {1, 2}]

NHoldAll 保护 N 的参数，否则以正常方式对它们进行计算：

Wolfram Language code: Attributes[Derivative]
Wolfram Language code: N[Derivative[1 + 1]]
Wolfram Language code: N[f[1 + 1]]

HoldPattern 保护模式不进行计算，但不干扰模式匹配：

Wolfram Language code: {HoldPattern[_ + _], _ + _}
Wolfram Research (1988)，HoldAll，Wolfram 语言函数，https://reference.wolfram.com/language/ref/HoldAll.html.

文本

Wolfram Research (1988)，HoldAll，Wolfram 语言函数，https://reference.wolfram.com/language/ref/HoldAll.html.

CMS

Wolfram 语言. 1988. "HoldAll." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/HoldAll.html.

APA

Wolfram 语言. (1988). HoldAll. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/HoldAll.html 年

BibTeX

@misc{reference.wolfram_2026_holdall, author="Wolfram Research", title="{HoldAll}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/HoldAll.html}", note=[Accessed: 05-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_holdall, organization={Wolfram Research}, title={HoldAll}, year={1988}, url={https://reference.wolfram.com/language/ref/HoldAll.html}, note=[Accessed: 05-November-2026]}