WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Inner[f,list1,list2,g]

Dotを一般化したもので，f が掛け算，g が足し算の役割を担う．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Inner

Inner[f,list1,list2,g]

Dotを一般化したもので，f が掛け算，g が足し算の役割を担う．

詳細

  • Inner[f,{{a,b},{c,d}},{x,y},g]->{g[f[a,x],f[b,y]],g[f[c,x],f[d,y]]}
  • DotのようにInnerは，一次テンソルの最後の指標を二次テンソルの最初の指標で縮約する．Innerを r 階のテンソルと s 階のテンソルに適用すると，階のテンソルが返される．
  • Inner[f,list1,list2]は，g の代りにPlusを使用する． »
  • Inner[f,list1,list2,g,n]は，一次テンソルの n の指標を二次テンソルの最初の指標で縮約する． »
  • list1と list2の頭部は一致しなければならないが，Listである必要はない． »

例題

すべて開く すべて閉じる

例  (3)

「加算操作」 g を使って2つのリストの「f の内側」を計算する：

Wolfram Language code: Inner[f, {a, b}, {x, y}, g]

行列とベクトルの一般化された内積を計算する：

Wolfram Language code: Inner[f, {{a, b}, {c, d}}, {x, y}, g]

慣れ親しんだ操作を使う：

Wolfram Language code: Inner[Times, {a, b}, {x, y}, Plus]
Wolfram Language code: Inner[Power, {a, b, c}, {x, y, z}, Times]

スコープ  (4)

2つの行列の一般化された内積：

Wolfram Language code: Inner[f, {{a, b}, {c, d}}, {{u, v}, {w, x}}, g]

ベクトルを持つ行列の内積：

Wolfram Language code: Inner[f, {{a, b}, {c, d}}, {s, t}, g]

行列を持つベクトルの内積：

Wolfram Language code: Inner[f, {x, y}, {{a, b}, {c, d}}, g]

2つのベクトルのエルミート内積：

Wolfram Language code: a = {1 + I, 3 - I, -5 + 7I}; b = {-2, -3 - I, 6I};
Wolfram Language code: Inner[#1Conjugate[#2]&, a, b]

これが，Dotを使い第2ベクトルを共役させたものと同じであることを確かめる：

Wolfram Language code: a.Conjugate[b]

一般化と拡張  (2)

最初の行列の最初の指標上で縮約する：

Wolfram Language code: Inner[f, {{a, b}, {c, d}}, {{u, v}, {w, x}}, g, 1]

InnerはList以外の頭部とも使える：

Wolfram Language code: Inner[s, f[1], f[2], t]

アプリケーション  (4)

ブール（内）積：

Wolfram Language code: BooleanDot[a_, b_] := Inner[And, a, b, Or]
Wolfram Language code: BooleanDot[(⁠| | | | ----- | ----- | | a1, 1 | a1, 2 | | a2, 1 | a2, 2 |⁠), (⁠| | | | ----- | ----- | | b1, 1 | b1, 2 | | b2, 1 | b2, 2 |⁠)]//MatrixForm//TraditionalForm

ブロック行列（内）積：

Wolfram Language code: BlockDot[a_, b_] := Inner[Dot, a, b, Plus]
Wolfram Language code: BlockDot[(⁠| | | | ----- | ----- | | a1, 1 | a1, 2 | | a2, 1 | a2, 2 |⁠), (⁠| | | | ----- | ----- | | b1, 1 | b1, 2 | | b2, 1 | b2, 2 |⁠)]//MatrixForm//TraditionalForm

ベクトル場の発散は内部微分である：

Wolfram Language code: div[vec_, vars_] := Inner[D, vec, vars, Plus]
Wolfram Language code: div[{-x / (x ^ 2 + y ^ 2), -y / (x ^ 2 + y ^ 2)}, {x, y}]

リスト中の関数を対応する引数に適用する：

Wolfram Language code: Inner[#1[#2]&, {f, g, h}, {a, b, c}, List]

特性と関係  (2)

次は，2つのベクトルのスカラー積である：

Wolfram Language code: Dot[{Subscript[a, 1], Subscript[a, 2], Subscript[a, 3]}, {Subscript[b, 1], Subscript[b, 2], Subscript[b, 3]}]

こうしてもスカラー積が求まる：

Wolfram Language code: Inner[Times, {Subscript[a, 1], Subscript[a, 2], Subscript[a, 3]}, {Subscript[b, 1], Subscript[b, 2], Subscript[b, 3]}, Plus]

積とListを結合するとMapThreadと同じ結果になる：

Wolfram Language code: Inner[f, {a, b, c}, {x, y, z}, List]
Wolfram Language code: MapThread[f, {{a, b, c}, {x, y, z}}]
Wolfram Research (1988), Inner, Wolfram言語関数， https://reference.wolfram.com/language/ref/Inner.html.

テキスト

Wolfram Research (1988), Inner, Wolfram言語関数， https://reference.wolfram.com/language/ref/Inner.html.

CMS

Wolfram Language. 1988. "Inner." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Inner.html.

APA

Wolfram Language. (1988). Inner. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Inner.html

BibTeX

@misc{reference.wolfram_2026_inner, author="Wolfram Research", title="{Inner}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/Inner.html}", note=[Accessed: 01-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_inner, organization={Wolfram Research}, title={Inner}, year={1988}, url={https://reference.wolfram.com/language/ref/Inner.html}, note=[Accessed: 01-November-2026]}