WOLFRAM

Wolfram 语言与系统参考资料中心

KochCurve[n]

给出表示第 n 步科赫曲线的线段.

KochCurve[n,{θ1,θ2,…}]

在连续的相对角度 θi 上取各个步骤的单位长度线段.

KochCurve[n,{{r1,θ1},{r2,θ2},…}]

在连续的步骤上取与 ri 成比例的线段长度.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
曲线指定  
曲线样式  
选项  
DataRange  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

KochCurve

KochCurve[n]

给出表示第 n 步科赫曲线的线段.

KochCurve[n,{θ1,θ2,…}]

在连续的相对角度 θi 上取各个步骤的单位长度线段.

KochCurve[n,{{r1,θ1},{r2,θ2},…}]

在连续的步骤上取与 ri 成比例的线段长度.

更多信息和选项

  • KochCurve 亦称为科赫雪花.
  • KochCurve[n] 产生过程是从单位线段开始，重复移除后续单元的中间的三分之一，并用一个三角形进行替换. »
  • KochCurve[n] 等价于 KochCurve[n,{0,60 °,-120 °,60 °}].
  • KochCurve 接受 DataRange 选项，可用来指定坐标应占据的范围.

范例

打开所有单元 关闭所有单元

基本范例  (2)

二维科赫曲线：

Wolfram Language code: Graphics[KochCurve[2]]

科赫网格的近似长度：

Wolfram Language code: Table[ArcLength[KochCurve[n]], {n, 5}]//Rationalize

公式：

Wolfram Language code: FindSequenceFunction[%, n]

柯西雪花的前 4 个迭代：

Wolfram Language code: Table[Graphics[GeometricTransformation[KochCurve[i], {RotationTransform[Pi, {1 / 2, 0}], RotationTransform[-Pi / 3, {1, 0}], RotationTransform[Pi / 3, {0, 0}]}]], {i, 4}]

范围  (7)

曲线指定  (3)

二维科赫曲线：

Wolfram Language code: Graphics[KochCurve[2]]

近似第 n 步科赫曲线：

Wolfram Language code: Table[Graphics[KochCurve[n]], {n, 1, 4}]

指定相对角度上线段的长度：

Wolfram Language code: Graphics@KochCurve[2, {{1, 0}, {1, 90°}, {1, -90°}, {2, -90°}, {1, 90°}, {1, 90°}, {1, -90°}}]

曲线样式  (4)

不同粗细的科赫曲线：

Wolfram Language code: Table[Graphics[{Thickness[i], KochCurve[3]}], {i, {Medium, Large}}]

线段粗细成比例：

Wolfram Language code: Table[Graphics[{Thickness[i], KochCurve[2]}], {i, {.005, .05, .1}}]

用打印机点指定粗细：

Wolfram Language code: Table[Graphics[{AbsoluteThickness[i], KochCurve[2]}], {i, {1, 5, 10}}]

虚线：

Wolfram Language code: Table[Graphics[{Dashing[i], KochCurve[3]}], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics[{d, KochCurve[3]}], {d, {Dotted, Dashed, DotDashed}}]

有颜色的曲线：

Wolfram Language code: Table[Graphics[{c, KochCurve[3]}], {c, {Red, Green, Blue, Yellow}}]

选项  (1)

DataRange  (1)

DataRange 允许指定所生成的网格坐标的范围：

Wolfram Language code: KochCurve[1]

指定不同的范围：

Wolfram Language code: KochCurve[1, DataRange -> {{-1, 1}, {-1, 1}}]

应用  (4)

KochCurve 产生过程是重复移除单元的中间的三分之一，并用一个三角形进行替换：

Wolfram Language code: Column[Table[Graphics[KochCurve[n]], {n, 1, 3}]]

生成 Cesàro 分形：

Wolfram Language code: Graphics[KochCurve[3, {0, 85°, -85°, -85°, 85°}]]

二次 1 型曲线：

Wolfram Language code: Graphics[KochCurve[3, {0, 90°, -90°, -90°, 90°}]]

二次 2 型曲线：

Wolfram Language code: Graphics[KochCurve[3, {{1, 0}, {1, 90°}, {1, -90°}, {2, -90°}, {1, 90°}, {1, 90°}, {1, -90°}}]]

属性和关系  (3)

KochCurve 由线段组成：

Wolfram Language code: KochCurve[1]

AnglePath 可用来生成科赫曲线的第一次迭代：

Wolfram Language code: path = {{1, 0}, {1, 90°}, {1, -90°}, {1, -90°}, {1, 0°}, {1, 90°}, {1, 90°}, {1, -90°}};
Wolfram Language code: {Graphics[KochCurve[1, path]], Graphics[Line[AnglePath[path]]]}

DataRange -> range 等价于使用 RescalingTransform[{...},range]：

Wolfram Language code: Region[KochCurve[2, DataRange -> {{1, 2}, {1, 3}}], Frame -> True]

使用 RescalingTransform：

Wolfram Language code: box = TransformedRegion[mr = KochCurve[2], RescalingTransform[RegionBounds[mr], {{1, 2}, {1, 3}}]];
Wolfram Language code: Region[box, Frame -> True]

巧妙范例  (1)

柯西雪花的动画：

Wolfram Language code: Animate[Graphics[GeometricTransformation[KochCurve[i], {RotationTransform[Pi, {1 / 2, 0}], RotationTransform[-Pi / 3, {1, 0}], RotationTransform[Pi / 3, {0, 0}]}]], {i, 1, 6, 1}]
Wolfram Research (2017)，KochCurve，Wolfram 语言函数，https://reference.wolfram.com/language/ref/KochCurve.html.

文本

Wolfram Research (2017)，KochCurve，Wolfram 语言函数，https://reference.wolfram.com/language/ref/KochCurve.html.

CMS

Wolfram 语言. 2017. "KochCurve." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/KochCurve.html.

APA

Wolfram 语言. (2017). KochCurve. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/KochCurve.html 年

BibTeX

@misc{reference.wolfram_2026_kochcurve, author="Wolfram Research", title="{KochCurve}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/KochCurve.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_kochcurve, organization={Wolfram Research}, title={KochCurve}, year={2017}, url={https://reference.wolfram.com/language/ref/KochCurve.html}, note=[Accessed: 03-November-2026]}