WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ListCorrelate[ker,list]

核 ker と list との相関を形成する．

ListCorrelate[ker,list,k]

ker の k 次の要素が list の各要素と整列されている循環相関を形成する．

ListCorrelate[ker,list,{kL,kR}]

最初の要素がlist[[1]] ker[[kL]]を含み，最後の要素が list[[-1]] ker[[kR]]を含む循環相関を形成する．

ListCorrelate[ker,list,klist,p]

最後が要素 p の反復により list を充填する相関を形成する．

ListCorrelate[ker,list,klist,{p1,p2,…}]

list の最後を piの循環反復で充填して相関を形成する．

ListCorrelate[ker,list,klist,padding,g,h]

g がTimesの代りに，h がPlusの代りに使用される一般化された相関を形成する．

ListCorrelate[ker,list,klist,padding,g,h,lev]

ker および list のレベル lev の要素を用いた相関を形成する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

ListCorrelate

ListCorrelate[ker,list]

核 ker と list との相関を形成する．

ListCorrelate[ker,list,k]

ker の k 次の要素が list の各要素と整列されている循環相関を形成する．

ListCorrelate[ker,list,{kL,kR}]

最初の要素がlist[[1]] ker[[kL]]を含み，最後の要素が list[[-1]] ker[[kR]]を含む循環相関を形成する．

ListCorrelate[ker,list,klist,p]

最後が要素 p の反復により list を充填する相関を形成する．

ListCorrelate[ker,list,klist,{p1,p2,…}]

list の最後を piの循環反復で充填して相関を形成する．

ListCorrelate[ker,list,klist,padding,g,h]

g がTimesの代りに，h がPlusの代りに使用される一般化された相関を形成する．

ListCorrelate[ker,list,klist,padding,g,h,lev]

ker および list のレベル lev の要素を用いた相関を形成する．

詳細

  • 核 Krとリスト asから，ListCorrelate[ker,list]は，を計算する．総和の範囲は核がリストの両側にはみ出さないこととする．
  • 一次元のリストに対しては，ListCorrelate[ker,list]はListConvolve[Reverse[ker],list]に等価である．
  • 高次元のリストに対しては ker はすべてのレベルで反転される必要がある．
  • kLおよび kRの設定は，ListConvolveでListCorrelateに相対的に反転される．
  • ListCorrelateでの{kL,kR}の共通な設定
  • {1,-1}はみ出しなし（デフォルト）
    {1,1}右端で最大はみ出し
    {-1,-1}左端で最大はみ出し
    {-1,1}両端で最大はみ出し

例題

すべて開く すべて閉じる

例  (4)

核{x,y}をデータのリストと相関させる：

Wolfram Language code: ListCorrelate[{x, y}, {a, b, c, d, e, f}]

循環相関をもとのデータと同じ長さにする：

Wolfram Language code: ListCorrelate[{x, y}, {a, b, c, d, e, f}, 1]

核内の要素2をデータの連続する要素と揃える：

Wolfram Language code: ListCorrelate[{x, y}, {a, b, c, d, e, f}, 2]

データを循環的に使う代りに，zzzで充填する：

Wolfram Language code: ListCorrelate[{x, y}, {a, b, c, d, e, f}, 1, zzz]

二次元的相関：

Wolfram Language code: ListCorrelate[{{1, 1}, {1, 1}}, {{a, b, c}, {d, e, f}, {g, h, i}}]

スコープ  (5)

厳密演算で相関を計算する：

Wolfram Language code: ker = Differences[Range[10] ^ 2]; list = 1 / Range[20];
Wolfram Language code: ListCorrelate[ker, list]

機械演算を使用する：

Wolfram Language code: ListCorrelate[N[ker], N[list]]

24桁精度の演算を使用する：

Wolfram Language code: ListCorrelate[N[ker, 24], N[list, 24]]

複合データの相関：

Wolfram Language code: ListCorrelate[{1, I}, RandomComplex[1 + I, 5]]

二次元相関：

Wolfram Language code: ListCorrelate[{{1, 0, 1}, {0, -4, 0}, {1, 0, 1}}, Array[Subscript[a, #]&, {4, 4}]]

二次元循環相関：

Wolfram Language code: c = ListCorrelate[{{1, 0, 1}, {0, -4, 0}, {1, 0, 1}}, Array[Subscript[a, #]&, {4, 4}], {1, 1}];
Wolfram Language code: MatrixForm[c]

はみ出しを最大にし，充填はゼロにした二次元相関：

Wolfram Language code: c = ListCorrelate[{{1, 0, 1}, {0, -4, 0}, {1, 0, 1}}, Array[Subscript[a, #]&, {4, 4}], {-1, 1}, 0];
Wolfram Language code: MatrixForm[c]

一般化と拡張  (4)

PlusとTimesの代りに関数fと関数gを使う：

Wolfram Language code: ListCorrelate[{x, y, z}, {1, 2, 3, 4, 5}, {1, -1}, {x, y, z}, f, g]

はみ出しは最大にし，ゼロ充填にして，PlusとTimesの代りに関数fと関数gを使う：

Wolfram Language code: ListCorrelate[{x, y, z}, {1, 2, 3, 4, 5}, {-1, 1}, 0, f, g]

はみ出しは最大で空充填として，PlusとTimesの代りに関数fと関数gを使う：

Wolfram Language code: ListCorrelate[{x, y, z}, {1, 2, 3, 4, 5}, {-1, 1}, {}, f, g]

ListCorrelateはTimeSeriesと使うことができる：

Wolfram Language code: ts = TimeSeries[Table[Subscript[x, t], {t, 12}]]
Wolfram Language code: ts["Path"]
Wolfram Language code: ListCorrelate[{1 / 2, 1 / 2}, ts, {1}]
Wolfram Language code: %["Path"]

アプリケーション  (6)

重み付きの移動平均でデータを滑らかにする：

Wolfram Language code: x = N[Range[1000] / 1000]; data = RandomReal[{-1, 1}, 1000] + 2 Sin[7 x];

重みを平均するための正規化されたガウス(Gauss)分布：

Wolfram Language code: w = Exp[-.01 N[Range[-24, 24] ^ 2]]; w /= Total[w];
Wolfram Language code: smoother = ListCorrelate[w, data];
Wolfram Language code: Show[ListLinePlot[Transpose[{x, data}]], ListLinePlot[Transpose[{Take[x, {25, -25}], smoother}], PlotStyle -> Red]]

画像のガウスの平滑化：

Wolfram Language code: img = 256 - Import["ExampleData/turtle.jpg", "Data"]; ArrayPlot[img]

5×5画素ステンシルのガウス核：

Wolfram Language code: g[σ_][x_, y_] := (1/2 π σ^2)Exp[-(1/2σ^2)(x ^ 2 + y ^ 2)]; gk = N[Outer[g[1], Range[-2, 2], Range[-2, 2]]];

画像の平滑化：

Wolfram Language code: smooth = ListCorrelate[gk, img];
Wolfram Language code: ArrayPlot[smooth]

画像の辺の検知：

Wolfram Language code: img = 256 - Import["ExampleData/ocelot.jpg", "Data"]; ArrayPlot[img]

ラプラス(Laplace)のフィルタ核と相関させる：

Wolfram Language code: dimg = ListCorrelate[{{1, 0, 1}, {0, -4, 0}, {1, 0, 1}}, img];
Wolfram Language code: ArrayPlot[dimg]

ガウスのラプラスフィルタ核を使う：

Wolfram Language code: g[σ_][x_, y_] := (1/2 π σ^2)Exp[-(1/2σ^2)(x ^ 2 + y ^ 2)]; f[σ_][x_, y_] = D[g[σ][x, y], {x, 2}] + D[g[σ][x, y], {y, 2}];
Wolfram Language code: ker = Outer[f[1.5], N[Range[-5, 5]], N[Range[-5, 5]]]; ListPlot3D[ker, PlotRange -> All]
Wolfram Language code: dimg = ListCorrelate[ker, img];
Wolfram Language code: ArrayPlot[dimg]

パスカル(Pascal)の三角形を生成する：

Wolfram Language code: NestList[ListCorrelate[{1, 1}, #, {-1, 1}, 0]&, {1}, 10]
Wolfram Language code: Column[%, Center]

加法的なセルオートマトン：

Wolfram Language code: {ArrayPlot[PadRight[Mod[NestList[ListCorrelate[{1, 1}, #, {-1, 1}, 0]&, {1}, 100], 2]]], ArrayPlot[PadRight[Mod[NestList[ListCorrelate[{1, 2}, #, {-1, 1}, 0]&, {1}, 100], 5]]]}

有限差分式を一様にサンプルされた関数に適用する：

Wolfram Language code: n = 100;h = 1. / n; x = N[h Range[n]]; f = Sin[2 π x];
Wolfram Language code: ListPlot[{f, ListCorrelate[({-1, 0, 1}/2 h), f, 2]}, DataRange -> {0, 1}]

異なる数の格子点についての誤差を示す：

Wolfram Language code: Table[n = 10 ^ k; h = 1. / n;x = N[h Range[n]]; ListPlot[2π Cos[2 π x] - ListCorrelate[({-1, 0, 1}/2 h), Sin[2 π x], 2], DataRange -> {h, 1}] , {k, 1, 3}]

第2微分近似について異なる数の格子点についての誤差を示す：

Wolfram Language code: Table[n = 10 ^ k; h = 1. / n;x = N[h Range[n]]; ListPlot[-4 π^2Sin[2 π x] - ListCorrelate[({-1, 16, -30, 16, -1}/12 h^2), Sin[2 π x], 3], DataRange -> {h, 1}] , {k, 1, 3}]

特性と関係  (3)

ListCorrelateは核を逆にしたListConvolveに等しい：

Wolfram Language code: ker = RandomReal[1, {123}]; list = RandomReal[1, {10000}];
Wolfram Language code: ListConvolve[ker, list] == ListCorrelate[Reverse[ker], list]

2つのランダムベクトルを生成する：

Wolfram Language code: {a, b} = RandomReal[1, {2, 31}];

ベクトルから巡回行列を構築する関数：

Wolfram Language code: circulant[v_] := ToeplitzMatrix[v, RotateRight[Reverse[v]]]

巡回相関は巡回行列による乗算に等しい：

Wolfram Language code: ListCorrelate[a, b, {-1, -1}] == circulant[Reverse[a]].b

巡回相関は離散フーリエ変換領域における乗算にも等しい：

Wolfram Language code: ListCorrelate[a, b, {-1, -1}] == InverseFourier[Fourier[Reverse[a]] Fourier[b]] Sqrt[31]

2つのランダムベクトルを生成する：

Wolfram Language code: {a, b} = RandomReal[1, {2, 31}];

ベクトルから上三角テプリッツ行列を構築する関数：

Wolfram Language code: uttoep[v_] := With[{n = Length[v]}, ToeplitzMatrix[First[v]UnitVector[n, 1], v]]

充填なしの巡回相関は上三角テプリッツ行列による乗算に等しい：

Wolfram Language code: ListCorrelate[a, b, 1, 0] == uttoep[a].b
Wolfram Research (1999), ListCorrelate, Wolfram言語関数， https://reference.wolfram.com/language/ref/ListCorrelate.html.

テキスト

Wolfram Research (1999), ListCorrelate, Wolfram言語関数， https://reference.wolfram.com/language/ref/ListCorrelate.html.

CMS

Wolfram Language. 1999. "ListCorrelate." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ListCorrelate.html.

APA

Wolfram Language. (1999). ListCorrelate. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ListCorrelate.html

BibTeX

@misc{reference.wolfram_2026_listcorrelate, author="Wolfram Research", title="{ListCorrelate}", year="1999", howpublished="\url{https://reference.wolfram.com/language/ref/ListCorrelate.html}", note=[Accessed: 02-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_listcorrelate, organization={Wolfram Research}, title={ListCorrelate}, year={1999}, url={https://reference.wolfram.com/language/ref/ListCorrelate.html}, note=[Accessed: 02-November-2026]}