WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

MeanAround[{x1,x2,x3,…}]

xiの平均とその不確かさを説明するAroundオブジェクトを与える．

MeanAround[{{x11,x12,…},{x21,…},…}]

ベクトル xiの平均とその共分散を説明するVectorAroundオブジェクトを与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
不確かさのあるスカラー平均  
不確かさのあるベクトル平均  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

MeanAround

MeanAround[{x1,x2,x3,…}]

xiの平均とその不確かさを説明するAroundオブジェクトを与える．

MeanAround[{{x11,x12,…},{x21,…},…}]

ベクトル xiの平均とその共分散を説明するVectorAroundオブジェクトを与える．

詳細

  • オブジェクト xiは，数，数量，あるいはAroundオブジェクトでよい．
  • MeanAround[{Around[x1,δ1],…}]は xiの重み付き平均を，重みが1/δi2に比例するとして計算する．
  • n 個の数または数量のリストについて，MeanAround[list]はAround[Mean[list],]を与える．
  • n 個のベクトルについて，MeanAround[list]はVectorAround[Mean[list],]を与える．
  • MeanAround[{{x11,x12,…},{x21,x22,…},…}]の xijは，すべての x1j，すべての x2j等の単位が互換であるなら，数量でよい．
  • 単数形のMeanAround[{x}]は不確かさが0の x を返すと定義されている．

例題

すべて開く すべて閉じる

例  (5)

不確かさでタグ付けされた数のリストの平均を求める：

Wolfram Language code: MeanAround[{1, 2, 3, 4, 3, 2, 1}]

不確かさが共分散行列として表されたベクトルのリストの平均を求める：

Wolfram Language code: MeanAround[{{1, 1}, {2, 2}, {3, 3}}]
Wolfram Language code: MeanAround[{{1, 1}, {0, 2}, {3, 1}}]

不確かさでタグ付けされたQuantityオブジェクトのリストの平均を求める：

Wolfram Language code: list = {Quantity[0.49114, "Meters"], Quantity[1.59556, "Yards"], Quantity[58.864, "Centimeters"], Quantity[0.59244, "Meters"], Quantity[14.6046, "Inches"]};
Wolfram Language code: UnitConvert[list]
Wolfram Language code: MeanAround[list]

3を中心とした正規分布のシミュレーションの平均を求める：

Wolfram Language code: SeedRandom[123]; data = RandomVariate[NormalDistribution[3, 0.5], 10]
Wolfram Language code: MeanAround[data]

シミュレーションにより多くの点が含まれていれば，平均の不確かさは低くなる：

Wolfram Language code: SeedRandom[123]; data = RandomVariate[NormalDistribution[3, 0.5], 10 ^ 4];
Wolfram Language code: MeanAround[data]

ベクトルのリストについてのMeanAroundはVectorAroundオブジェクトを返す：

Wolfram Language code: RandomVariate[MultinormalDistribution[{2, 3}, {{1, 0.5}, {0.5, 2}}], 10]
Wolfram Language code: MeanAround[%]

スコープ  (4)

不確かさのあるスカラー平均  (3)

数のリストについて平均Aroundオブジェクトを計算する：

Wolfram Language code: data = {2.745, 2.964, 2.203, 3.768, 4.339, 2.341, 2.452, 3.071, 3.052, 2.163};
Wolfram Language code: MeanAround[data]

エネルギーのリストについて，平均Around オブジェクトを計算する：

Wolfram Language code: data = {Quantity[3.62, "Joules"], Quantity[2.91, "Joules"], Quantity[3.16, "Joules"], Quantity[2.95, "Joules"], Quantity[2.24, "Joules"], Quantity[3.160591821875137, "Joules"], Quantity[2.11, "Joules"], Quantity[3.77, "Joules"], Quantity[3.11, "Joules"], Quantity[2.36, "Joules"]}
Wolfram Language code: MeanAround[data]

Aroundオブジェクトのリストの重み付き平均を求める：

Wolfram Language code: list = {Around[0.49114, 0.04205430639900287], Around[0.59556, 0.009586202141021988], Around[0.58864, 0.039668541726954415], Around[0.59244, 0.07593245740260027], Around[0.46046, 0.029440780862296734], Around[0.49334, 0.019166637500261305], Around[0.41232, 0.029567347205657818], Around[0.47712, 0.029548139370204562], Around[0.48596, 0.08931941281826966], Around[0.5557, 0.08274315688817477]};
Wolfram Language code: MeanAround[list]

もとの不確かさを無視した裸値についてのMeanAroundの結果と比較する：

Wolfram Language code: MeanAround[Through[list["Value"]]]

もとのリストについての直接平均と比較する：

Wolfram Language code: Mean[list]

不確かさのあるベクトル平均  (1)

{length,time}ペアのリストの平均を計算する：

Wolfram Language code: QuantityArray[RandomVariate[MultinormalDistribution[{2, 3}, {{1, 0.5}, {0.5, 2}}], 100], {"Meters", "Seconds"}]
Wolfram Language code: MeanAround[%]

アプリケーション  (1)

100個のランダムな映画実体をダウンロードし，上映時間を求める：

Wolfram Language code: movies = RandomEntity["Movie", 100];
Wolfram Language code: runtimes = DeleteMissing[EntityValue[movies, "Runtime"]]

上演時間の値は幅広く分布している：

Wolfram Language code: MinMax[runtimes]

次は，上映時間の平均値と標準偏差である：

Wolfram Language code: N@{Mean[runtimes], StandardDeviation[runtimes]}

次は，不確かさを含む平均である：

Wolfram Language code: MeanAround[runtimes]
Wolfram Language code: Histogram[runtimes, 20]

特性と関係  (2)

正規分布を取ってそのシミュレーションを行う：

Wolfram Language code: dist = NormalDistribution[5, 0.3];
Wolfram Language code: scalars = RandomVariate[dist, 100];

Around[scalars]は分布の平均と標準偏差を推定する：

Wolfram Language code: Around[scalars]

Around[dist]は分布 dist における真のパラメータを与える：

Wolfram Language code: Around[dist]

MeanAround[scalars]は分布の平均と平均の標準誤差を記述する：

Wolfram Language code: MeanAround[scalars]

2Dベクトルの多変量正規分布を取ってそのシミュレーションを行う：

Wolfram Language code: vdist = MultinormalDistribution[{5, -4}, {{0.3, -0.1}, {-0.1, 0.2}}];
Wolfram Language code: Dimensions[vectors = RandomVariate[vdist, 100]]

VectorAround[vectors]は分布の平均と共分散行列を推定する：

Wolfram Language code: VectorAround[vectors]

MeanAround[scalars]は分布の平均とその平均に関連する共分散行列を記述する：

Wolfram Language code: MeanAround[vectors]
Wolfram Research (2019), MeanAround, Wolfram言語関数， https://reference.wolfram.com/language/ref/MeanAround.html.

テキスト

Wolfram Research (2019), MeanAround, Wolfram言語関数， https://reference.wolfram.com/language/ref/MeanAround.html.

CMS

Wolfram Language. 2019. "MeanAround." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MeanAround.html.

APA

Wolfram Language. (2019). MeanAround. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MeanAround.html

BibTeX

@misc{reference.wolfram_2026_meanaround, author="Wolfram Research", title="{MeanAround}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/MeanAround.html}", note=[Accessed: 11-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_meanaround, organization={Wolfram Research}, title={MeanAround}, year={2019}, url={https://reference.wolfram.com/language/ref/MeanAround.html}, note=[Accessed: 11-November-2026]}