WOLFRAM

Wolfram 语言与系统参考资料中心

MeijerG[{{a1,…,an},{an+1,…,ap}},{{b1,…,bm},{bm+1,…,bq}},z]

给出 Meijer G-函数 .

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
Show More Show More
函数的属性  
微分  
积分  
级数展开  
推广和延伸  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

MeijerG

MeijerG[{{a1,…,an},{an+1,…,ap}},{{b1,…,bm},{bm+1,…,bq}},z]

给出 Meijer G-函数 .

更多信息

  • 数学函数，适宜于符号和数值操作.
  • 实数 r 的 Meijer G 函数的通用形式 MeijerG[alist,blist,z,r] 被定义为 ，其中，在默认情况下 .
  • 在许多特殊的情形下，MeijerG 自动被转化为其它函数.

范例

打开所有单元 关闭所有单元

基本范例  (6)

数值运算：

Wolfram Language code: N[MeijerG[{{}, {2}}, {{(1/2), (3/2)}, {}}, 3], 50]

许多特殊函数是 MeijerG 的特殊情况：

Wolfram Language code: MeijerG[{{}, {}}, {{v}, {-v}}, z]
Wolfram Language code: MeijerG[{{(1/2), (1/2), (1/2)}, {}}, {{0}, {-(3/2), -(3/2)}}, -x]

在实数的子集上绘图：

Wolfram Language code: Plot[MeijerG[{{1 / 2}, {}}, {{1 / 3}, {}}, x], {x, 0, 3}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[MeijerG[{{1 / 2}, {}}, {{1 / 3}, {}}, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在原点的级数展开：

Wolfram Language code: Series[MeijerG[{{a}, {}}, {{d}, {}}, x], {x, 0, 2}]

在 Infinity 的级数展开：

Wolfram Language code: Series[MeijerG[{{a}, {}}, {{d}, {}}, x], {x, ∞, 5}]

范围  (35)

数值计算  (7)

数值化计算：

Wolfram Language code: MeijerG[{{1}, {2}}, {{2.3, 1.5}, {4}}, 3]
Wolfram Language code: MeijerG[{{31, 4}, {2, 3}}, {{5, 1.5}, {.1}}, 3]

高精度计算：

Wolfram Language code: N[MeijerG[{{1}, {2}}, {{2 / 3, 1 / 5}, {4}}, 3], 50]//Chop

输出的精度与输入的精度一致：

Wolfram Language code: MeijerG[{{1}, {2}}, {{2, 1.333333333333333333333333333}, {4}}, 3]//Chop

复数输入：

Wolfram Language code: MeijerG[{{I + 3}, {2.}}, {{2 / 3, 1 / 5}, {4}}, 3]

高精度的高效计算：

Wolfram Language code: MeijerG[{{1}, {3}}, {{2 / 3, 1 / 5}, {4}}, 3`100]//Timing//Chop
Wolfram Language code: MeijerG[{{6}, {2}}, {{2 / 3, 1 / 5}, {4}}, 3`1000];//Timing

MeijerG 在其第三个参数中对列表进行元素遍历：

Wolfram Language code: MeijerG[{{1 / 3}, {}}, {{1 / 2}, {1}}, {0.1, 0.3, 0.5}, 1 / 2]

MeijerG 在其第三个参数中对稀疏数组和结构化数组进行元素遍历：

Wolfram Language code: MeijerG[{{1 / 3}, {}}, {{1 / 2}, {1}}, SparseArray[Automatic, {2, 2}, 0, {1, {{0, 1, 2}, {{1}, {2}}}, {1, 1}}], 1 / 2]
Wolfram Language code: MeijerG[{{1 / 3}, {}}, {{1 / 2}, {1}}, SymmetrizedArray[StructuredArray`StructuredData[{2, 2}, {{{1, 1} -> 1, {1, 2} -> 1/2, {2, 2} -> 1/3}, Symmetric[{1, 2}]}]], 1 / 2]

用 Around 计算普通的统计区间：

Wolfram Language code: MeijerG[{{}, {}}, {{5}, {4}}, Around[.2, 0.01]]

逐项计算数组中每个元素的值：

Wolfram Language code: MeijerG[{{}, {}}, {{5}, {4}}, {{1 / 2, 2}, {0, 1 / 2}}]

或用 MatrixFunction 计算矩阵形式的 MeijerG 函数：

Wolfram Language code: MatrixFunction[MeijerG[{{}, {}}, {{5}, {4}}, #]&, {{1 / 2, 2}, {0, 1 / 2}}]//FullSimplify

特殊值  (5)

在固定点的值：

Wolfram Language code: MeijerG[{{}, {}}, {{5}, {4}}, 5]
Wolfram Language code: MeijerG[{{1 / 2, 1 / 2}, {}}, {{1}, {1}}, 2]

符号式计算：

Wolfram Language code: MeijerG[{{1 / 2}, {}}, {{0}, {0}}, x]
Wolfram Language code: MeijerG[{{1 / 2, 3 / 2}, {}}, {{0}, {0}}, x]

零处的值：

Wolfram Language code: MeijerG[{{1 / 2}, {1 / 2}}, {{}, {}}, 0]
Wolfram Language code: MeijerG[{{1 / 2}, {}}, {{1}, {}}, 0]
Wolfram Language code: MeijerG[{{1 / 2}, {}}, {{0}, {0}}, 0]

对于简单参数，MeijerG 计算为更简单的函数：

Wolfram Language code: MeijerG[{{}, {}}, {{b}, {}}, -x]
Wolfram Language code: MeijerG[{{}, {}}, {{b}, {b - 1 / 2}}, x]//FullSimplify

求 MeijerG[{{},{}},{{1/2},{3/2}},x] 的正最小：

Wolfram Language code: xmin = x /. FindRoot[D[MeijerG[{{}, {}}, {{1 / 2}, {3 / 2}}, x], x] == 0, {x, 2}]
Wolfram Language code: Plot[MeijerG[{{}, {}}, {{1 / 2}, {3 / 2}}, x], {x, 0, 10}, Epilog -> Style[Point[{xmin, MeijerG[{{}, {}}, {{1 / 2}, {3 / 2}}, xmin]}], PointSize[Large], Red]]

可视化  (2)

绘制各种参数值的 MeijerG 函数：

Wolfram Language code: Plot[{MeijerG[{{(1/2), (1/2)}, {}}, {{1 / 2}, {-1 / 2}}, x], MeijerG[{{(1/2), (1/2)}, {}}, {{1 / 3}, {-1 / 3}}, x], MeijerG[{{(1/2), (1/2)}, {}}, {{1 / 4}, {-1 / 4}}, x]}, {x, 0, 10}]

绘制 MeijerG[{{1},{}},{{1/2,1,3/2},{}},z ] 实部：

Wolfram Language code: ComplexContourPlot[Re[MeijerG[{{1}, {}}, {{1 / 2, 1, 3 / 2}, {}}, z]], {z, -4 - 4 I, 4 + 4 I}, Contours -> 20]

绘制 MeijerG[{{1},{}},{{1/2,1,3/2},{}},z ] 虚部：

Wolfram Language code: ComplexContourPlot[Im[MeijerG[{{1}, {}}, {{1 / 2, 1, 3 / 2}, {}}, z]], {z, -4 - 4 I, 4 + 4 I}, Contours -> 20]

函数的属性  (9)

的实定义域和复定义域：

Wolfram Language code: FunctionDomain[MeijerG[{{1 / 2, 3 / 2}, {}}, {{0}, {0}}, x], x]
Wolfram Language code: FunctionDomain[MeijerG[{{1 / 2, 3 / 2}, {}}, {{0}, {0}}, z], z, Complexes]

MeijerG 线性作用于最后参数的列表：

Wolfram Language code: MeijerG[{{I / 3}, {}}, {{1 / 2, 1, 3 / 2}, {}}, {-0.5, 0.5}]

并非解析函数：

Wolfram Language code: FunctionAnalytic[MeijerG[{{1 / 2, 3 / 2}, {}}, {{0}, {0}}, x], x]

有奇点和断点：

Wolfram Language code: FunctionSingularities[MeijerG[{{1 / 2, 3 / 2}, {}}, {{0}, {0}}, x], x]
Wolfram Language code: FunctionDiscontinuities[MeijerG[{{1 / 2, 3 / 2}, {}}, {{0}, {0}}, x], x]

在其实定义域上为非递增函数：

Wolfram Language code: FunctionMonotonicity[{MeijerG[{{1 / 2, 3 / 2}, {}}, {{0}, {0}}, x], x > -1}, x]

为单射函数：

Wolfram Language code: FunctionInjective[MeijerG[{{1 / 2, 3 / 2}, {}}, {{0}, {0}}, x], x]
Wolfram Language code: Plot[{MeijerG[{{1 / 2, 3 / 2}, {}}, {{0}, {0}}, x], -7}, {x, -2, 3}]

不是满射函数：

Wolfram Language code: FunctionSurjective[MeijerG[{{1 / 2, 3 / 2}, {}}, {{0}, {0}}, x], x]
Wolfram Language code: Plot[{MeijerG[{{1 / 2, 3 / 2}, {}}, {{0}, {0}}, x], 5}, {x, -5, 5}]

在实定义域上为负：

Wolfram Language code: FunctionSign[{MeijerG[{{1 / 2, 3 / 2}, {}}, {{0}, {0}}, x], x > -1}, x, StrictInequalities -> True]

在实定义域上为凸函数：

Wolfram Language code: FunctionConvexity[{MeijerG[{{1 / 2, 3 / 2}, {}}, {{0}, {0}}, x], x > -1}, x]

TraditionalForm 格式化：

Wolfram Language code: MeijerG[{{1}, {}}, {{1 / 2, 1, 3 / 2}, {}}, z]//TraditionalForm
Wolfram Language code: MeijerG[{{1}, {}}, {{1 / 2, 1, 3 / 2}, {}}, z, (1/2)]//TraditionalForm

微分  (3)

关于 z 的一阶导数：

Wolfram Language code: D[MeijerG[{{Subscript[a, 1], Subscript[a, 2]}, {Subscript[a, 3], Subscript[a, 4]}}, {{v}, {-v}}, z], z]

关于 z 的高阶导数：

Wolfram Language code: Table[D[MeijerG[{{}, {}}, {{b}, {c}}, z], {z, k}], {k, 1, 3}]//FullSimplify

b=3 和 c=2 时，绘制关于 z 的高阶导数：

Wolfram Language code: Plot[Evaluate[% /. { b -> 3, c -> 2}], {z, -10, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

关于 z 的 阶导数公式：

Wolfram Language code: D[MeijerG[{{}, {}}, {{v}, {-v}}, z], {z, k}]// FullSimplify

积分  (3)

使用 Integrate 计算不定积分：

Wolfram Language code: Integrate[MeijerG[{{Subscript[a, 1], Subscript[a, 2]}, {Subscript[a, 3], Subscript[a, 4]}}, {{b}, {-b}}, z], z]

验证反导数：

Wolfram Language code: FullSimplify[D[%, z]]

定积分：

Wolfram Language code: Integrate[MeijerG[{{1}, {2}}, {{1 / 2}, {-1 / 2}}, z], {z, 0, 5}]

更多积分：

Wolfram Language code: Integrate[z MeijerG[{{1 / 2}, {2}}, {{1 / 2}, {-3}}, z], z]//FullSimplify
Wolfram Language code: Integrate[ z MeijerG[{{1 / 2}, {2}}, {{1 / 2}, {-3}}, z^2], {z, 0, 3}]//FullSimplify

级数展开  (6)

使用 Series 求泰勒展开：

Wolfram Language code: Series[MeijerG[{{a}, {}}, {{d}, {}}, x], {x, 0, 2}]//Normal//FullSimplify

绘制 附近的前三个近似：

Wolfram Language code: terms = Normal@Table[Series[MeijerG[{{2}, {}}, {{1 / 3}, {}}, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{MeijerG[{{2}, {}}, {{1 / 3}, {}}, x], terms}, {x, 0, 10}]

使用 SeriesCoefficient 产生级数展开的一般项：

Wolfram Language code: SeriesCoefficient[MeijerG[{{a}, {}}, {{d}, {}}, x], {x, 1, m}]

求 Infinity 处的级数展开：

Wolfram Language code: Series[MeijerG[{{a}, {}}, {{d}, {}}, x], {x, Infinity, 1}]

对数情况下的级数展开：

Wolfram Language code: Series[MeijerG[{{}, {}}, {{a, a + 1}, {}}, z], {z, 0, 1}]

普通点的泰勒展开：

Wolfram Language code: Series[MeijerG[{{a}, {}}, {{d}, {}}, x], {x, x0, 2}]// Normal//FullSimplify

推广和延伸  (1)

计算一个广义的 Meijer G 函数：

Wolfram Language code: MeijerG[{{}, {}}, {{a}, {b}}, z, (1/3)]

类似普通的 Meijer G 函数有不同的分支切割结构：

Wolfram Language code: MeijerG[{{}, {}}, {{a}, {b}}, z^3]
Wolfram Language code: % / %%
Wolfram Language code: PowerExpand[%, Assumptions -> {}]

应用  (5)

定义从 BetaDistribution 中抽取的独立随机变量的乘积：

Wolfram Language code: avec = {2, 3 / 2, 5 / 2};bvec = {3 / 2, 1, 2}; prod𝒟 = TransformedDistribution[x1 x2 x3, MapThread[#1BetaDistribution[#2, #3]&, {{x1, x2, x3}, avec, bvec}]]

分布的 PDF 定义为 MeijerG：

Wolfram Language code: pdf = Refine[PDF[prod𝒟, x], 0 < x < 1]

用 FunctionExpand 来以更简洁的函数表达：

Wolfram Language code: pdf2 = Simplify[FunctionExpand[pdf], 0 < x < 1]

比较 PDF 图像和随机变量的 Histogram：

Wolfram Language code: sample = RandomVariate[prod𝒟, 10 ^ 6];
Wolfram Language code: Show[Histogram[sample, {0.005}, PDF], Plot[pdf2, {x, 0, 1}]]

解微分方程：

Wolfram Language code: DSolve[f''[r] + ((1/r) - 2r)f'[r] + (1 - (4/r^2))f[r] == 0, f[r], r]

MeijerG 给出对数部分：

Wolfram Language code: Series[f[r] /. %, {r, 0, 2}, Assumptions -> r > 0]

Integrate 可以返回涉及 MeijerG 的答案：

Wolfram Language code: Integrate[KelvinKer[1 / 2, x], x]
Wolfram Language code: Integrate[x Exp[-(x^2 + (1/x))], {x, 0, Infinity}]

求解三阶奇异 ODE，用 HypergeometricPFQ 和 MeijerG 函数表示解：

Wolfram Language code: DSolve[x y'''[x] + x y'[x] - y[x] == 0, y, x]

验证 ODE 的通解的各个组成部分是线性独立的：

Wolfram Language code: Wronskian[Coefficient[y[x] /. %[[1]], Table[C[i], {i, 3}]], x]

三项式方程 的解的公式：

Wolfram Language code: x[m_, n_Integer, t_] /; m < n := Exp[-2 π I(m - 1/n - 1)] - (t/(2 π)^n - 3 / 2)Sqrt[(n/(n - 1)^3)]MeijerG[{Append[(Range[n - 1]/n), (n - 2/n - 1)], {}}, {(Range[0, n - 2]/n - 1), {-(1/n - 1)}}, -(t n^(n/n - 1)/n - 1)Exp[2 π I(m - 1/n - 1)], (1/n - 1)]

五次方程式 的首根：

Wolfram Language code: x[1, 5, 1]//TraditionalForm
Wolfram Language code: N[%, 20]

检验解：

Wolfram Language code: x ^ 5 - x + 1 == 0 /. x -> %

属性和关系  (1)

使用 FunctionExpand 把 MeijerG 展开成更简单的函数：

Wolfram Language code: MeijerG[{{(1/2), 1}, {1}}, {{(1/2)}, {}}, z]
Wolfram Language code: FunctionExpand[%]

可能存在的问题  (3)

对某些参数，MeijerG 没有定义：

Wolfram Language code: MeijerG[{{}, {}}, {{}, {0}}, z]

是一个 的 MeijerG 函数的奇点：

Wolfram Language code: MeijerG[{{(1/2), 1}, {3, 4}}, {{(1/5)}, {}}, 0]
Wolfram Language code: MeijerG[{{(1/2), 1}, {3, 4}}, {{(1/5)}, {}}, z]//FunctionExpand
Wolfram Language code: Series[%, {z, 0, 0}, Assumptions -> z > 0]

对 ， MeijerG 是一个分段解析函数：

Wolfram Language code: FunctionExpand[MeijerG[{{(1/2)}, {(1/3)}}, {{(1/5)}, {(1/7)}}, z]]
Wolfram Language code: Plot3D[Evaluate[Im[%] /. z -> x - I y], {x, -3 / 2, 3 / 2}, {y, -3 / 2, 3 / 2}, MaxRecursion -> 1, Exclusions -> {x ^ 2 + y ^ 2 == 1, {y == 0, x < 0}}]

巧妙范例  (2)

解决 SIAM 100‐digit 挑战问题： 找到最大值：

Wolfram Language code: int[α_] = Assuming[0 ≤ α ≤ 5, (2 + Sin[10 α]) Subsuperscript[∫, (1/2), ∞](((-1 + 2 u/u))^α Sin[α u]/u^2)ⅆu]

绘制积分：

Wolfram Language code: Plot[int[α], {α, 10^-3, 5}, WorkingPrecision -> 15, MaxRecursion -> 1, PlotPoints -> 30]

数值方法找到最大值：

Wolfram Language code: FindMaximum[int[α], {α, (3/4), (1/2), 1}, WorkingPrecision -> 50, PrecisionGoal -> 20]//N[#, 20]&//Quiet

产生许多初级和特殊函数作为 MeijerG 的特例：

Wolfram Language code: Table[MeijerG[{Table[2, {k, p}], {}}, {{1 / 2}, Table[k, {k, q}]}, z], {p, 0, 4}, {q, p, 3}]//TraditionalForm
Wolfram Research (1996)，MeijerG，Wolfram 语言函数，https://reference.wolfram.com/language/ref/MeijerG.html.

文本

Wolfram Research (1996)，MeijerG，Wolfram 语言函数，https://reference.wolfram.com/language/ref/MeijerG.html.

CMS

Wolfram 语言. 1996. "MeijerG." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/MeijerG.html.

APA

Wolfram 语言. (1996). MeijerG. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/MeijerG.html 年

BibTeX

@misc{reference.wolfram_2026_meijerg, author="Wolfram Research", title="{MeijerG}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/MeijerG.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_meijerg, organization={Wolfram Research}, title={MeijerG}, year={1996}, url={https://reference.wolfram.com/language/ref/MeijerG.html}, note=[Accessed: 03-November-2026]}