Mod

Mod[m,n]

m を n で割った商の剰余を与える．

Mod[m,n,d]

オフセット d を使う．

詳細

Modは剰余演算としても知られている．
記号操作・数値操作の両方に適した数学数関数である．
モジュラー演算，暗号学，乱数生成，プログラムの循環操作等によく使われる．
Mod[m,n]は m を n で割った剰余を与える．
Mod[m,n]は m-n Quotient[m,n]と等価である．

正の整数 m と n について，Mod[m,n]は0から n-1までの整数である．
Mod[m,n,d]の結果は，およびであるようなを与える．

例題

すべて開くすべて閉じる

例 (4)

3を法とする5を計算する：

Wolfram Language code: Mod[5, 3]

1をオフセットとして5を3で割ったときの剰余：

Wolfram Language code: Mod[5, 3, 1]

固定した法で数列をプロットする：

Wolfram Language code: DiscretePlot[Mod[n, 8], {n, 50}]

法を変化させて数列をプロットする：

Wolfram Language code: DiscretePlot[Mod[100, m], {m, 50}]

スコープ (13)

数値評価 (6)

整数を使って計算する：

Wolfram Language code: Mod[17, 5]

オフセットを使って計算する：

Wolfram Language code: Mod[17, 5, 1]

Modは整数に使うことができる：

Wolfram Language code: Mod[17, 5]

有理数：

Wolfram Language code: Mod[5 / 2, 2]

実数：

Wolfram Language code: Mod[Sqrt[28], 3]

複素数：

Wolfram Language code: Mod[5 + 3I, 2]

厳密数：

Wolfram Language code: Mod[Pi, 2]

近似数：

Wolfram Language code: Mod[3.14, 2.]

大きい整数を使って計算する：

Wolfram Language code: Mod[10 ^ 10000, 10007]

Modはリストに縫い込まれる：

Wolfram Language code: Mod[{1, 2, 3, 4, 5}, 3]

TraditionalFormによる表示：

Wolfram Language code: Mod[a, n]//TraditionalForm

記号演算 (7)

モジュラー方程式：

Wolfram Language code: Reduce[Mod[2x + 1, 5] == Mod[x, 7] && 0 < x < 50, x]

Modを総和で使う：

Wolfram Language code: Sum[Mod[n ^ 2, 2], n]

乗積で使う：

Wolfram Language code: Product[Sin[(1/1 + Mod[i ^ 2, 3])], i]

式を簡約する：

Wolfram Language code: FullSimplify[Mod[a, -b] + Mod[-a, b] == 0]

Mod数列を識別する：

Wolfram Language code: FindSequenceFunction[{1, 2, 3, 4, 0, 1, 2, 3, 4, 0}, n]

漸化式：

Wolfram Language code: DifferenceRootReduce[Mod[k, 3], k]

DirichletTransform：

Wolfram Language code: DirichletTransform[Mod[n, 2], n, s]

母関数：

Wolfram Language code: GeneratingFunction[Mod[n, 4], n, x]

Wolfram Language code: ExponentialGeneratingFunction[Mod[n, 4], n, x]//FullSimplify

アプリケーション (19)

基本的なアプリケーション (3)

Modの最初の20の値：

Wolfram Language code:

Grid[{Prepend[Range[20], "n"], Prepend[Table[CarmichaelLambda[n], {n, 20}], "TraditionalFormλ(n)"]}, Background -> {None, {StandardOrange, StandardGray}}, Dividers -> Lighter[Gray, .5], Spacings -> {Automatic, .8}]

固定した法で数列をプロットする：

Wolfram Language code: DiscretePlot[Mod[n, 8], {n, 50}]

法を変化させて数列をプロットする：

Wolfram Language code: DiscretePlot[Mod[100, m], {m, 50}]

Mod[n,8]の母関数：

Wolfram Language code: ModGF[z_] = GeneratingFunction[Mod[n, 8], n, z]

Wolfram Language code:

GraphicsRow[{Plot[ModGF[x], {x, 0, 1}], ContourPlot[Re[ModGF[x + I * y]], {x, -1, 1}, {y, -1, 1}, ContourStyle -> None]}]

指数母関数：

Wolfram Language code: ModEGF[z_] = ExponentialGeneratingFunction[Mod[n, 8], n, z];

Wolfram Language code:

GraphicsRow[{Plot[ModEGF[x], {x, 0, 16}], ContourPlot[Re[ModEGF[x + I * y]], {x, -1, 1}, {y, -1, 1}, ContourStyle -> None]}]

ディリクレ(Dirichlet)級数：

Wolfram Language code: ModL[s_] = Sum[Mod[n, 8] / n ^ s, {n, 1, Infinity}]

Wolfram Language code: GraphicsRow[{Plot[ModL[x], {x, 0, 16}], ContourPlot[Re[ModL[x + I * y]], {x, -1, 1}, {y, -1, 1}, ContourStyle -> None]}]

数値識別子 (1)

与えられた国際標準図書番号(ISBN)が有効かどうかをチェックする：

Wolfram Language code: ISBNs = {"0394380495", "1092312213", "0821801236", "9781944183"};

（各はISBNの桁目）であればISBNは有効である：

Wolfram Language code:

ValidISBNQ[str_] := Module[
	{l}, l = ToExpression[StringPartition[str, 1]];
	If[Mod[Sum[l[[i]]i, {i, 10}], 11] == 0, True, False]
	];

各ISBNが有効かどうかチェックする：

Wolfram Language code: ValidISBNQ /@ ISBNs

暗号 (2)

RSAのような暗号化スキームを構築する．まず法から始める：

Wolfram Language code:

{p, q} = Prime[RandomInteger[{10 ^ 4, 10 ^ 5}, {2}]];
n = p q

n を法とした乗法群の普遍指数を求める：

Wolfram Language code: λ = CarmichaelLambda[n]

秘密鍵：

Wolfram Language code: d = NestWhile[#1 + 1& , Round[n / 3], GCD[λ, #1] =!= 1&]

公開鍵：

Wolfram Language code: e = ModularInverse[d, λ]

メッセージを暗号化する：

Wolfram Language code: PowerMod[ToCharacterCode["RSA in Mathematica"], e, n]

暗号化したものを解読する：

Wolfram Language code: FromCharacterCode[PowerMod[%, d, n]]

アルファベットの文字をシフトさせてメッセージを暗号化するシーザー暗号をModを使って作る：

Wolfram Language code:

EncryptCaesar[msg_, key_] := Module[
	{encr, decr, x, n, nums, res}, 
	encr = Transpose[{Alphabet[], Range[0, 25]}] /. {x_String, n_Integer} -> (x -> n);
	decr = Reverse[encr, 2];
	nums = StringPartition[ToLowerCase[msg], 1] /. encr;
	res = (Mod[nums + key, 26]) /. decr//StringJoin
	];
DecryptCaesar[msg_, key_] := EncryptCaesar[msg, -key];

鍵を使ってメッセージを暗号化する：

Wolfram Language code:

key = 315;
msg = "bewaretheidesofmarch";
EncryptCaesar[msg, key]

メッセージを解読する：

Wolfram Language code: DecryptCaesar[%, key]

整数論 (6)

の形式の数が素数あるいは合成数かどうかをチェックする：

Wolfram Language code: MersennePrimeQ[n_] := TrueQ[Last[NestList[Mod[# ^ 2 - 2, 2 ^ n - 1]&, 4, n - 2]] == 0];

Wolfram Language code: Select[Range[3, 100], MersennePrimeQ]

の形の100より小さい素数を選ぶ：

Wolfram Language code: Select[Array[Prime, PrimePi[100]], Mod[#, 6] == 1&]

フェルマ(Fermat)の小定理：

Wolfram Language code: GCD[7, 11]

Wolfram Language code: Mod[7 ^ (11 - 1), 11]

オイラー(Euler)の定理：

Wolfram Language code: GCD[7, 12]

Wolfram Language code: Mod[7 ^ EulerPhi[12], 12]

ウィルソン(Wilson)の定理：

Wolfram Language code: FunctionExpand[Mod[(p - 1)!, p], p∈Primes]

2を法とした加法の表記法を定義する：

Wolfram Language code: x_⊕y_ := Mod[x + y, 2]

Wolfram Language code: (1⊕0)⊕1

Modを使って線形合同式の系を解く：

Wolfram Language code:

r = {3, 5, 7};
m = {2, 3, 5};
M = (Times@@m/m);
Mod[Dot[r, #^EulerPhi[#]& /@ M], Times@@m]

Wolfram Language code: ChineseRemainder[r, m]

コンピュータサイエンス (3)

現在の時刻をシードとして使用する乱数生成器を作成する：

Wolfram Language code:

x[0] = UnixTime[]
x[k_] := Mod[a^kx[0], m];

法とベースを選ぶ：

Wolfram Language code:

m = 2147483647;
a = 16807;

0から1までの1000個の乱数を計算する：

Wolfram Language code: Histogram[Table[x[i] / m, {i, 0, 1000}], 10]

リストの一部を循環的に抽出する：

Wolfram Language code: {a, b, c}[[Mod[Range[10], 3, 1]]]

逆行列のモジュラー計算：

Wolfram Language code: A = {{3, 4}, {2, 5}};

まず，随伴行列を計算する：

Wolfram Language code:

MinorMatrix[Mat_List ? MatrixQ] := Map[Reverse, Minors[Mat], {0, 1}]
CofactorMatrix[Mat_List ? MatrixQ] := MapIndexed[#1 (-1) ^ (Plus@@#2)&, MinorMatrix[Mat], {2}]
MatrixAdjoint[Mat_] := Transpose[CofactorMatrix[Mat]];

次に，行列の逆モジュラを計算する：

Wolfram Language code:

ModularInverseMatrix[Mat_, m_] := Mod[ModularInverse[Det[Mat], m]MatrixAdjoint[Mat], m];
ModularInverseMatrix[A, 13]

逆モジュラが正しい結果を与えることを確認する：

Wolfram Language code: Mod[A.%, 13]

政治学，経済学，社会学 (2)

ハッシュアルゴリズムに基づいて（アメリカ合衆国の）社会保障番号にメモリアドレスを割り当てる：

Wolfram Language code:

socials = {344401659, 325510778, 212228844, 329938157, 047900151, 372500191, 034367980, 546332190, 509496993, 132489973};

各社会保障番号に場所を，衝突がないことを確認して割り当てる：

Wolfram Language code:

AssignSingle[social_, locations_] := Module[
	{i = 0}, 
	While[MemberQ[locations[[ ;; , 2]], h[i, social]], i++];
	Append[locations, {social, h[i, social]}]
	];
AssignAll[socials_] := Module[
	{l = Length[socials], locations = {}}, 
	For[i = 1, i ≤ l, i++, locations = AssignSingle[socials[[i]], locations]];
	locations
	];

結果を計算する：

Wolfram Language code: AssignAll[socials]

単一の社会保障番号のハッシュを計算する：

Wolfram Language code:

m = 4969;
num = 10 ^ 3 + 1;
g[k_] := Mod[k + 1, m - 2];
hash[k_] := Mod[k + num g[k], m];
social = 344401659;

Wolfram Language code: hash[social]

その他のアプリケーション (2)

非整合ボックス内で跳ねる粒子のシミュレーションを行う：

Wolfram Language code: Graphics[Line[Table[Mod[t, {Sqrt[2], 1}], {t, 0, 15, .001}]]]

12音の平均律の系：

Wolfram Language code: Needs["Music`"]

Wolfram Language code: Sound[SoundNote[{"CSharp", "DFlat"}, 1, "Piano"]]

1200セントの差がある音は同じ合同クラスの音であるとみなされる：

Wolfram Language code: Mod[HertzToCents[{Csharp1, Csharp2}], 1200]

特性と関係 (7)

Modは周期関数である：

Wolfram Language code: FunctionPeriod[Mod[n, 3], n]

Modはすべての複素数上で定義される：

Wolfram Language code: FunctionDomain[Mod[n, 3], n]

値域：

Wolfram Language code: FunctionRange[Mod[n, 3], n, m]

Modは推移的である．もしかつならである：

Wolfram Language code: Mod[5, 3] == Mod[2, 3]

Wolfram Language code: Mod[2, 3] == Mod[8, 3]

Wolfram Language code: Mod[8, 3] == Mod[5, 3]

がで割れるならである：

Wolfram Language code: Divisible[8, 2]

Wolfram Language code: Mod[8, 2]

QuotientRemainder[a,n]はMod[a,n]と同じである：

Wolfram Language code: QuotientRemainder[17, 6]//Last

Wolfram Language code: Mod[17, 6]

PowerModを使って逆モジュロを計算する：

Wolfram Language code: PowerMod[3, -1, 7]

結果を確かめる：

Wolfram Language code: Mod[3 5, 7]

結果は法と同じ符号を持つ：

Wolfram Language code: Mod[{5, -5}, 3]

Wolfram Language code: Mod[{5, -5}, -3]

正の実数 x について，Mod[x,1]は x の小数部分を与える：

Wolfram Language code: Mod[3.14, 1]

Wolfram Language code: FractionalPart[3.14]

考えられる問題 (1)

計算によってはデフォルトよりも高い内部精度を要求するものがある：

Wolfram Language code: Mod[GoldenRatio ^ 1000, 1]

$MaxExtraPrecisionの値をリセットする：

Wolfram Language code: Block[{$MaxExtraPrecision = Infinity}, Mod[GoldenRatio ^ 1000, 1]]

おもしろい例題 (4)

2を法とする二項係数：

Wolfram Language code: ArrayPlot[Table[Mod[Binomial[i, j], 2], {i, 0, 63}, {j, 0, 63}]]

加法的セルオートマトン：

Wolfram Language code: ArrayPlot[CellularAutomaton[{Mod[Total[#], 4]&, {}, 1}, {{1}, 0}, 50]]

49を法として合同に基づいて彩色された数でウラム(Ulam)の螺線をプロットする：

Wolfram Language code:

ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table
	[(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n]

Wolfram Language code: ArrayPlot[Mod[ulam[109], 109], ColorFunction -> "TemperatureMap"]

モジュロ加算表：

Wolfram Language code: ArrayPlot[Table[Mod[a + b, 4], {a, 0, 8}, {b, 0, 8}], ColorFunction -> "Rainbow"]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

Mod

詳細

例題

例 (4)

スコープ (13)

数値評価 (6)

記号演算 (7)

アプリケーション (19)

基本的なアプリケーション (3)

数値識別子 (1)

暗号 (2)

整数論 (6)

コンピュータサイエンス (3)

政治学，経済学，社会学 (2)

その他のアプリケーション (2)

特性と関係 (7)

考えられる問題 (1)

おもしろい例題 (4)

テキスト

CMS

APA

BibTeX

BibLaTeX

Mod

詳細

例題

例 (4)

スコープ (13)

数値評価 (6)

記号演算 (7)

アプリケーション (19)

基本的なアプリケーション (3)

数値識別子 (1)

暗号 (2)

整数論 (6)

コンピュータサイエンス (3)

政治学，経済学，社会学 (2)

その他のアプリケーション (2)

特性と関係 (7)

考えられる問題 (1)

おもしろい例題 (4)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX