WOLFRAM

Wolfram 语言与系统参考资料中心

Module[{x,y,…},expr]

指定在 expr 中出现的符号 x、y、… 应被当作局部值.

Module[{x=x0,…},expr]

用来定义 x, … 的初始值.

更多信息
Details and Options Details and Options
范例  
基本范例  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Module

Module[{x,y,…},expr]

指定在 expr 中出现的符号 x、y、… 应被当作局部值.

Module[{x=x0,…},expr]

用来定义 x, … 的初始值.

更多信息

  • Module允许用户创建局部变量，该局部变量的名称相对于模块是局部的.
  • 在每次被调用时，Module 创建新的符号来表示它的每个局部变量.
  • Module 创建名称为 xxx$nnn 的符号来表示名称为 xxx的局部变量. nnn 是 $ModuleNumber 当前的值.
  • 每次任何模块被使用时，$ModuleNumber 的值都会增加.
  • 在计算 expr 之前，Module 使用新符号来替换出现在 expr 中任意位置除作为作用域结构（scoping construct）中的局部变量外的每一个局部变量.
  • 使用 Module 创建的符号具有 Temporary 属性.
  • 使用 Module 创建的符号可以从模块返回.
  • 你使用 Module[{vars},body/;cond] 作为带有一个条件的变换法则的右式.
  • Module 具有 HoldAll 属性.
  • Module 结构可以以任何方式嵌套，如有必要内变量会被改名.
  • Module 是一个实现词典式作用域的作用域结构.

范例

打开所有单元 关闭所有单元

基本范例  (1)

Wolfram Language code: f[x0_] := Module[{x = x0}, While[x > 0, x = Log[x]]; x ]
Wolfram Language code: f[2.0]

应用  (2)

局部函数的动态编程：

Wolfram Language code: fib[n_] := Module[{f}, f[1] = f[2] = 1; f[i_] := f[i] = f[i - 1] + f[i - 2]; f[n] ]
Wolfram Language code: fib[5]

对最大公约数（GCD）使用初始化局部变量的欧几里德（Euclid）算法：

Wolfram Language code: gcd[m0_, n0_] := Module[{m = m0, n = n0}, While[n ≠ 0, {m, n} = {n, Mod[m, n]}]; m ]
Wolfram Language code: gcd[18, 21]

属性和关系  (8)

每次运算模块会产生一个临时的代码：

Wolfram Language code: {Module[{x}, x], Module[{x}, x]}

Module 的符号是临时的，如果它们不再被引用就会被删除：

Wolfram Language code: Module[{x}, Print[x];Attributes[x]]
Wolfram Language code: Names["x$*"]

每次使用 Module 会增加 $ModuleNumber：

Wolfram Language code: {$ModuleNumber, Module[{x}, x], $ModuleNumber}

如果没有必要赋值给一个局部变量的话, 那么就应该使用常量：

Wolfram Language code: With[{x = 2.0}, Sqrt[x] + 1]

With 比 Module 快：

Wolfram Language code: Timing[Do[Module[{x = 5}, x;], {10 ^ 5}]]
Wolfram Language code: Timing[Do[With[{x = 5}, x;], {10 ^ 5}]]

Block 只作用于局部变量； 它不创造新的符号：

Wolfram Language code: x = 7; Block[{x = 5}, Print[x]];x

Unique 类似与 Module，产生新的变量：

Wolfram Language code: {Unique[x], Module[{x}, x]}

局部变量不会受全局变量的影响，反之亦然：

Wolfram Language code: x = 17; Module[{x = x}, x = x + 1;x]
Wolfram Language code: x

Module 中的符号不会受到命名冲突：

Wolfram Language code: y = x ^ 2;
Wolfram Language code: Module[{x = 5}, x + y]

可能存在的问题  (3)

Module 是作用域结构，内局部变量屏蔽外部的：

Wolfram Language code: Module[{x}, Print[x];Module[{x}, Print[x]]]

在嵌套作用域中，变量会被改名：

Wolfram Language code: Module[{e = Expand[(1 + x) ^ 5]}, Function[x, e]]
Wolfram Language code: %[10]

从其内部建立函数，以避免重新命名：

Wolfram Language code: Module[{e = Expand[(1 + x) ^ 5]}, Function@@{x, e}]
Wolfram Language code: %[10]

并行赋值不适用于 Module 变量：

Wolfram Language code: v = {a, b};
Wolfram Language code: Module[{{x, y} = v}, x ^ 2 + y ^ 2]
Wolfram Language code: Module[{x = v[[1]], y = v[[2]]}, x ^ 2 + y ^ 2]
Wolfram Research (1991)，Module，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Module.html.

文本

Wolfram Research (1991)，Module，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Module.html.

CMS

Wolfram 语言. 1991. "Module." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Module.html.

APA

Wolfram 语言. (1991). Module. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Module.html 年

BibTeX

@misc{reference.wolfram_2026_module, author="Wolfram Research", title="{Module}", year="1991", howpublished="\url{https://reference.wolfram.com/language/ref/Module.html}", note=[Accessed: 23-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_module, organization={Wolfram Research}, title={Module}, year={1991}, url={https://reference.wolfram.com/language/ref/Module.html}, note=[Accessed: 23-July-2026]}