WOLFRAM

Wolfram 语言与系统参考资料中心

MomentEvaluate[mexpr,dist]

计算分布 dist 上的矩表达式 mexpr 的形式矩.

MomentEvaluate[mexpr,list]

计算数据 list 上的 mexpr 的形式矩和形式样本矩.

MomentEvaluate[mexpr,dist,list]

计算分布 dist 上的形式矩，以及数据 list 上的形式样本矩.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
推广和延伸  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

MomentEvaluate

MomentEvaluate[mexpr,dist]

计算分布 dist 上的矩表达式 mexpr 的形式矩.

MomentEvaluate[mexpr,list]

计算数据 list 上的 mexpr 的形式矩和形式样本矩.

MomentEvaluate[mexpr,dist,list]

计算分布 dist 上的形式矩，以及数据 list 上的形式样本矩.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

计算一个单变量分布的形式矩：

Wolfram Language code: MomentEvaluate[Moment[1], NormalDistribution[μ, σ]]
Wolfram Language code: MomentEvaluate[Moment[2], NormalDistribution[μ, σ]]

计算一个多变量分布的形式矩：

Wolfram Language code: MomentEvaluate[Moment[{1, 0}], BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {Subscript[σ, 1], Subscript[σ, 2]}, ρ]]
Wolfram Language code: MomentEvaluate[Moment[{1, 1}], BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {Subscript[σ, 1], Subscript[σ, 2]}, ρ]]

计算数据的样本形式矩：

Wolfram Language code: MomentEvaluate[PowerSymmetricPolynomial[2], {a, b, c}]
Wolfram Language code: MomentEvaluate[AugmentedSymmetricPolynomial[{2, 1}], {a, b, c}]

计算数据的形式矩：

Wolfram Language code: MomentEvaluate[Cumulant[3], {a, b, c}]

范围  (6)

对一个分布，计算混合单变量形式矩多项式：

Wolfram Language code: MomentEvaluate[Cumulant[2] + Moment[1] ^ 2, BinomialDistribution[n, p]]

对一个分布，计算混合多变量形式矩多项式：

Wolfram Language code: MomentEvaluate[Moment[{2, 2}] ^ 2 + Moment[{3, 1}], BinormalDistribution[ρ]]

对数据，计算关于形式矩量的多项式：

Wolfram Language code: data = RandomVariate[BetaDistribution[2, 3], 10];
Wolfram Language code: MomentEvaluate[Cumulant[4] + Moment[2] ^ 2, data]

与直接计算进行比较：

Wolfram Language code: Cumulant[data, 4] + Moment[data, 2] ^ 2

对数据，计算形式样本多项式：

Wolfram Language code: MomentEvaluate[PowerSymmetricPolynomial[3], {a, b, c}]
Wolfram Language code: MomentEvaluate[AugmentedSymmetricPolynomial[{2, 1}], {a, b, c}]
Wolfram Language code: MomentEvaluate[PowerSymmetricPolynomial[{2, 3}], {{Subscript[x, 1], Subscript[x, 2]}, {Subscript[y, 1], Subscript[y, 2]}, {Subscript[z, 1], Subscript[z, 2]}}]
Wolfram Language code: MomentEvaluate[AugmentedSymmetricPolynomial[{{1, 2}, {3, 4}}], {{Subscript[x, 1], Subscript[x, 2]}, {Subscript[y, 1], Subscript[y, 2]}, {Subscript[z, 1], Subscript[z, 2]}}]

对数据计算形式样本多项式，其中 n 为样本大小：

Wolfram Language code: MomentEvaluate[(PowerSymmetricPolynomial[4]/n), {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, n]

计算一个包含形式矩和形式样本矩的表达式：

Wolfram Language code: se = MomentConvert[Moment[2], "SampleEstimator"] - Moment[2]
Wolfram Language code: data = RandomVariate[ExponentialDistribution[1], 10 ^ 5];
Wolfram Language code: MomentEvaluate[se, ExponentialDistribution[1], data]

或者：

Wolfram Language code: Moment[data, 2] - Moment[ExponentialDistribution[1], 2]

推广和延伸  (1)

计算均值、方差、偏度和峰度，并使用 Cumulant 表示：

Wolfram Language code: MomentEvaluate[{Cumulant[1], Cumulant[2], (Cumulant[3]/Cumulant[2]^3 / 2), 3 + (Cumulant[4]/Cumulant[2]^2)}, BinomialDistribution[n, p]]

与直接计算比较：

Wolfram Language code: Table[f[BinomialDistribution[n, p]], {f, {Mean, Variance, Skewness, Kurtosis}}]
Wolfram Language code: % == %%//Simplify

应用  (2)

从伯努利分布的样本上获取估计函数 的期望：

Wolfram Language code: sampleEst = (PowerSymmetricPolynomial[1]/PowerSymmetricPolynomial[0])(1 - (PowerSymmetricPolynomial[1]/PowerSymmetricPolynomial[0]));

以形式矩的形式表示估计函数的期望：

Wolfram Language code: formalExp = MomentConvert[sampleEst, {Moment, n}]

伯努利分布中的样本的估计函数的期望：

Wolfram Language code: estMean = MomentEvaluate[formalExp, BernoulliDistribution[p]]//Factor

样本估计函数的方差：

Wolfram Language code: estVar = MomentEvaluate[MomentConvert[(sampleEst - estMean) ^ 2, {Moment, n}], BernoulliDistribution[p]]//Factor

构建 的样本和无偏估计：

Wolfram Language code: (se = MomentConvert[Cumulant[4], "SampleEstimator"])//TraditionalForm
Wolfram Language code: (ue = MomentConvert[Cumulant[4], "UnbiasedEstimator", "PowerSymmetricPolynomial"])//TraditionalForm

在相同的数据上得到这些估计量的统计量：

Wolfram Language code: dist = ErlangDistribution[2, 3];
Wolfram Language code: data = RandomVariate[dist, {2500, 10 ^ 2}];
Wolfram Language code: ses = Table[MomentEvaluate[se, li], {li, data}];
Wolfram Language code: ues = Table[MomentEvaluate[ue, li], {li, data}];
Wolfram Language code: PairedHistogram[ses, ues, {0, 1, 0.05}, "PDF", ChartLabels -> {"Biased", "Unbiased"}]

将这些统计量与总体累积量相比较：

Wolfram Language code: {Mean[ses], Mean[ues], Cumulant[dist, 4]}//N

求分布 dist 的估计量的采样总体期望值：

Wolfram Language code: sem = MomentEvaluate[MomentConvert[se, {Cumulant, n}], dist]
Wolfram Language code: uem = MomentEvaluate[MomentConvert[ue, {Cumulant, n}], dist]

求分布 dist 的估计量的采样总体方差：

Wolfram Language code: sev = MomentEvaluate[MomentConvert[(se - sem) ^ 2, {Cumulant, n}], dist]
Wolfram Language code: uev = MomentEvaluate[MomentConvert[(ue - uem) ^ 2, {Cumulant, n}], dist]

对所使用的样本大小，数值计算期望方差：

Wolfram Language code: {sev, uev} /. n -> Last[Dimensions[data]]//N

与样本值比较：

Wolfram Language code: {Variance[ses], Variance[ues]}

属性和关系  (1)

MomentEvaluate 实际通过计算各组分来计算一个矩表达式：

Wolfram Language code: dist = BinomialDistribution[n, p];
Wolfram Language code: MomentEvaluate[Moment[2] + Moment[1] ^ 2, dist]
Wolfram Language code: Moment[dist, 2] + Moment[dist, 1] ^ 2
Wolfram Language code: % == %%//Simplify
Wolfram Research (2010)，MomentEvaluate，Wolfram 语言函数，https://reference.wolfram.com/language/ref/MomentEvaluate.html.

文本

Wolfram Research (2010)，MomentEvaluate，Wolfram 语言函数，https://reference.wolfram.com/language/ref/MomentEvaluate.html.

CMS

Wolfram 语言. 2010. "MomentEvaluate." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/MomentEvaluate.html.

APA

Wolfram 语言. (2010). MomentEvaluate. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/MomentEvaluate.html 年

BibTeX

@misc{reference.wolfram_2026_momentevaluate, author="Wolfram Research", title="{MomentEvaluate}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/MomentEvaluate.html}", note=[Accessed: 06-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_momentevaluate, organization={Wolfram Research}, title={MomentEvaluate}, year={2010}, url={https://reference.wolfram.com/language/ref/MomentEvaluate.html}, note=[Accessed: 06-November-2026]}