WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

NeighborhoodGraph[g,v]

グラフ g の頂点 v のグラフ近傍を与える．

NeighborhoodGraph[g,{a1,a2,…}]

aiのグラフ近傍を与える．aiは g の頂点，辺，部分グラフのいずれでもよい．

NeighborhoodGraph[g,patt]

パターン patt にマッチする頂点と辺のグラフ近傍を与える．

NeighborhoodGraph[g,…,d]

距離 d までの近傍を与える．

NeighborhoodGraph[{vw,…},…]

規則 vw を使ってグラフ g を指定する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

NeighborhoodGraph

NeighborhoodGraph[g,v]

グラフ g の頂点 v のグラフ近傍を与える．

NeighborhoodGraph[g,{a1,a2,…}]

aiのグラフ近傍を与える．aiは g の頂点，辺，部分グラフのいずれでもよい．

NeighborhoodGraph[g,patt]

パターン patt にマッチする頂点と辺のグラフ近傍を与える．

NeighborhoodGraph[g,…,d]

距離 d までの近傍を与える．

NeighborhoodGraph[{vw,…},…]

規則 vw を使ってグラフ g を指定する．

詳細とオプション

  • 頂点 v の近傍グラフは v に隣接する頂点とそれに接合する辺によって与えられる．
  • 辺 e の近傍グラフは e の頂点の近傍グラフである．
  • 部分グラフ h の近傍グラフは h 内の頂点の近傍グラフである．
  • 距離 d の近傍グラフは距離 d-1にある近傍グラフの頂点の近傍グラフである．
  • d のデフォルト値は1である．
  • NeighborhoodGraphは，無向グラフ，有向グラフ，多重グラフ，混合グラフに使うことができる．

例題

すべて開く すべて閉じる

例  (2)

グラフの頂点1からの近傍を与える：

Wolfram Language code: g = PetersenGraph[5, 2]
Wolfram Language code: HighlightGraph[g, {NeighborhoodGraph[g, 1], Labeled[1, 1]}]

頂点集合からの近傍を与える：

Wolfram Language code: HighlightGraph[g, {NeighborhoodGraph[g, {1, 2}], Labeled[#, #]& /@ {1, 2}}]

頂点から距離 k までの近傍を与える：

Wolfram Language code: GridGraph[{4, 4}]
Wolfram Language code: Table[HighlightGraph[%, NeighborhoodGraph[%, 1, k]], {k, 4}]

スコープ  (8)

NeighborhoodGraphは無向グラフに使うことができる：

Wolfram Language code: GridGraph[{3, 4}, VertexSize -> {1 -> 0.2, 11 -> 0.2}]
Wolfram Language code: HighlightGraph[%, NeighborhoodGraph[%, {1, 11}]]

有向グラフ：

Wolfram Language code: g = [image];
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, {1, 11}]]

多重グラフ：

Wolfram Language code: g = [image];
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, {1, 11}]]

混合グラフ：

Wolfram Language code: g = [image];
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, {1, 11}]]

NeighborhoodGraphは頂点に使うことができる：

Wolfram Language code: g = GridGraph[{5, 5}]
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, 1]]

辺：

Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, 16]]

規則を使ってグラフを指定する：

Wolfram Language code: g = {1 -> 2, 1 -> 3, 2 -> 4, 3 -> 4, 3 -> 5, 4 -> 6, 5 -> 6};
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, 1]]

パターンを使って頂点集合を指定する：

Wolfram Language code: g = PetersenGraph[5, 2]
Wolfram Language code: NeighborhoodGraph[g, _ ? ((# < 3)&)]

NeighborhoodGraphは大きいグラフに使うことができる：

Wolfram Language code: g = GridGraph[{10, 10, 10, 10}];
Wolfram Language code: NeighborhoodGraph[g, 1];//Timing

アプリケーション  (2)

CompleteGraph中の頂点からの近傍をハイライトする：

Wolfram Language code: g = CompleteGraph[8, VertexSize -> {1 -> 0.2}];
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, 1]]

CycleGraph：

Wolfram Language code: g = CycleGraph[8, VertexSize -> {1 -> 0.2}];
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, 1]]

StarGraph：

Wolfram Language code: g = StarGraph[8, VertexSize -> {1 -> 0.2}];
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, 1]]

GridGraph：

Wolfram Language code: v = {1, 15, 18};g = GridGraph[{6, 6}, VertexSize -> 0.2];
Wolfram Language code: HighlightGraph[g, MapThread[Style[NeighborhoodGraph[g, #1], #2]&, {{1, 15, 18}, {Blue, Red, Green}}]]

CompleteKaryTree：

Wolfram Language code: g = CompleteKaryTree[3, 3, VertexSize -> {1 -> 0.2}];
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, 1]]

PathGraph：

Wolfram Language code: g = PathGraph[Range[20], VertexSize -> 0.2];
Wolfram Language code: HighlightGraph[g, MapThread[Style[NeighborhoodGraph[g, #1], #2]&, {{1, 6, 20}, {Blue, Red, Green}}]]

RandomGraph：

Wolfram Language code: g = RandomGraph[{10, 20}, VertexSize -> {1 -> 0.3}];
Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, 1]]

頂点の近傍を操作する：

Wolfram Language code: Manipulate[HighlightGraph[GridGraph[{5, 5}], NeighborhoodGraph[GridGraph[{5, 5}], i]], {i, 1, 25, 1}]

特性と関係  (2)

Subgraphを使って頂点集合の近傍グラフを求める：

Wolfram Language code: g = GridGraph[{8, 12}]
Wolfram Language code: v = {28, 36, 37, 43};
Wolfram Language code: nbg = Subgraph[g, Join[v, AdjacencyList[g, v]]];

部分グラフをハイライトする：

Wolfram Language code: HighlightGraph[g, nbg, GraphHighlightStyle -> "DehighlightGray"]

これは下記と等価である：

Wolfram Language code: NeighborhoodGraph[g, v]

完全グラフ内の頂点の近傍はグラフそれ自身である：

Wolfram Language code: CompleteGraph[8]
Wolfram Language code: NeighborhoodGraph[%, 1]

おもしろい例題  (2)

格子からランダムに近傍を拾う：

Wolfram Language code: g = GridGraph[{50, 75}];
Wolfram Language code: NeighborhoodGraph[g, RandomSample[VertexList[g], 35], 1]

格子からランダムに近傍を取り去る：

Wolfram Language code: g = GridGraph[{25, 50}];
Wolfram Language code: Subgraph[g, Complement[VertexList[g], VertexList[NeighborhoodGraph[g, RandomSample[VertexList[g], 25], 1]]]]
Wolfram Research (2010), NeighborhoodGraph, Wolfram言語関数， https://reference.wolfram.com/language/ref/NeighborhoodGraph.html （2015年に更新）.

テキスト

Wolfram Research (2010), NeighborhoodGraph, Wolfram言語関数， https://reference.wolfram.com/language/ref/NeighborhoodGraph.html （2015年に更新）.

CMS

Wolfram Language. 2010. "NeighborhoodGraph." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2015. https://reference.wolfram.com/language/ref/NeighborhoodGraph.html.

APA

Wolfram Language. (2010). NeighborhoodGraph. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/NeighborhoodGraph.html

BibTeX

@misc{reference.wolfram_2026_neighborhoodgraph, author="Wolfram Research", title="{NeighborhoodGraph}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/NeighborhoodGraph.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_neighborhoodgraph, organization={Wolfram Research}, title={NeighborhoodGraph}, year={2015}, url={https://reference.wolfram.com/language/ref/NeighborhoodGraph.html}, note=[Accessed: 03-November-2026]}