WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ProgressIndicator[x]

0から1の間の設定値 x を持つ進捗表示器を表す．

ProgressIndicator[Dynamic[x]]

動的に更新された x の現行値を取るように設定できる．

ProgressIndicator[x,{xmin,xmax}]

xmin から xmax までの範囲の進捗表示器を表す．

ProgressIndicator[x,Indeterminate]

範囲が不定の進捗表示器を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Appearance  
BaselinePosition  
ImageMargins  
ImageSize  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連するワークフロー
履歴
引用書式

ProgressIndicator

ProgressIndicator[x]

0から1の間の設定値 x を持つ進捗表示器を表す．

ProgressIndicator[Dynamic[x]]

動的に更新された x の現行値を取るように設定できる．

ProgressIndicator[x,{xmin,xmax}]

xmin から xmax までの範囲の進捗表示器を表す．

ProgressIndicator[x,Indeterminate]

範囲が不定の進捗表示器を表す．

詳細とオプション

  • ProgressIndicator[…]は，ノートブックに左から右に進む進捗表示器として表示される．インタラクティブな変更を加えることはできない．
  • ProgressIndicator[x,Indeterminate]は，x が変化するたびに変化するオブジェクトとして表示される． »
  • 以下のオプションが使用できる．
  • Appearance Automatic進捗表示器の全体的な外観
    BaselinePosition Automatic周囲のテキストと相対的な並べ方
    BaseStyle{}進捗表示器のベーススタイル
    ImageMargins 0進捗表示器の画像の周囲の余白
    ImageSize Automatic進捗表示器の全体的な画像の大きさ
  • ProgressIndicator[]はProgressIndicator[0]と等価である．
  • ProgressIndicator[Appearance->val]は，連続的に進行する不定の進捗表示器を作ることができる．そのような表示器を作る val の値には，次のようなものがある．
  • "Indeterminate"
    "Necklace"{}[[3]]
    "ArcUp"{}[[3]]
    "ArcDown"{}[[3]]
    "ArcUpFill"{}[[3]]
    "Percolate"{}[[3]]
    "Ellipsis"{}[[3]]
  • BaseStyleの設定値は，一般に現行スタイルシートの"ProgressIndicator"スタイルで与えられるデフォルトスタイルに加えられる．

例題

すべて開く すべて閉じる

例  (1)

デフォルト範囲0から1までの0.8に設定された進捗表示器を作る：

Wolfram Language code: ProgressIndicator[0.8]

スコープ  (3)

デフォルト範囲の0から1までを使う：

Wolfram Language code: {ProgressIndicator[Dynamic[x]], Slider[Dynamic[x]]}

固定範囲の0から10までを使う：

Wolfram Language code: {ProgressIndicator[Dynamic[x], {0, 10}], Slider[Dynamic[x], {0, 10}]}

未知の範囲を使い，変化を進捗変数で示す：

Wolfram Language code: {ProgressIndicator[Dynamic[x], Indeterminate], Slider[Dynamic[x], {0, 10}]}

オプション  (4)

Appearance  (1)

定義済みの進捗表示器の外観：

Wolfram Language code: Table[ProgressIndicator[Appearance -> a], {a, {"Indeterminate", "Necklace", "ArcUp", "ArcDown", "ArcUpFill", "Percolate", "Ellipsis"}}]

BaselinePosition  (1)

周囲のテキストと揃える：

Wolfram Language code: Row[Table[ProgressIndicator[0.5, ImageSize -> 100, BaselinePosition -> p], {p, {Top, Center, Bottom}}], "xxx"]

ImageMargins  (1)

進捗表示器に余白を追加する：

Wolfram Language code: Table[Framed@ProgressIndicator[0.5, ImageMargins -> m], {m, {0, 5, 10, 15}}]

ImageSize  (1)

全体的な画像サイズを指定する：

Wolfram Language code: Grid[Table[ProgressIndicator[0.7, Background -> Gray, ImageSize -> {w, h}], {h, {10, 30, 50}}, {w, {30, 50, 80, 220}}]]

アプリケーション  (3)

計算の進捗状況を表示する：

Wolfram Language code: ProgressIndicator[Dynamic[n], {100, 140}]
Wolfram Language code: Table[(n = k;FactorInteger[2 ^ k - 1]), {k, 100, 140}];

Indeterminateを使って持続時間が未知のアクティビティを示す：

Wolfram Language code: k = 0;ProgressIndicator[Dynamic[k], Indeterminate]
Wolfram Language code: L = 4; eqs = {D[u[t, x, y], t, t] == D[u[t, x, y], x, x] + D[u[t, x, y], y, y] + Sin[u[t, x, y]], u[t, -L, y] == u[t, L, y], u[t, x, -L] == u[t, x, L], u[0, x, y] == Exp[-(x ^ 2 + y ^ 2)], Derivative[1, 0, 0][u][0, x, y] == 0};

EvaluationMonitorを使って数値関数の求解を追跡する：

Wolfram Language code: NDSolve[eqs, u, {t, 0, L / 2}, {x, -L, L}, {y, -L, L}, EvaluationMonitor :> k++]

アクティビティを無限に表示する：

Wolfram Language code: ProgressIndicator[Dynamic[Clock[Infinity]], Indeterminate]

特性と関係  (2)

引数が零個の場合は進捗がないことに等しい：

Wolfram Language code: {ProgressIndicator[], ProgressIndicator[0]}

PrintTemporaryを使ってセルの評価中に進捗表示器を表示する：

Wolfram Language code: PrintTemporary[ProgressIndicator[Appearance -> "Percolate"]]; Pause[5];
Wolfram Research (2007), ProgressIndicator, Wolfram言語関数， https://reference.wolfram.com/language/ref/ProgressIndicator.html.

テキスト

Wolfram Research (2007), ProgressIndicator, Wolfram言語関数， https://reference.wolfram.com/language/ref/ProgressIndicator.html.

CMS

Wolfram Language. 2007. "ProgressIndicator." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ProgressIndicator.html.

APA

Wolfram Language. (2007). ProgressIndicator. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ProgressIndicator.html

BibTeX

@misc{reference.wolfram_2026_progressindicator, author="Wolfram Research", title="{ProgressIndicator}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/ProgressIndicator.html}", note=[Accessed: 31-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_progressindicator, organization={Wolfram Research}, title={ProgressIndicator}, year={2007}, url={https://reference.wolfram.com/language/ref/ProgressIndicator.html}, note=[Accessed: 31-October-2026]}