WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

QuestionGenerator[<|"name1":>val1,"name2":>val2,…|>, genfunc]

"name1":>val1,"name1":>val2,…に genfunc を適用することで生成されたQuestionObjectを表す．

QuestionGenerator[CloudObject[…]]

クラウドに配備された質問生成器を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
関連項目
関連するガイド
履歴
引用書式

QuestionGenerator

QuestionGenerator[<|"name1":>val1,"name2":>val2,…|>, genfunc]

"name1":>val1,"name1":>val2,…に genfunc を適用することで生成されたQuestionObjectを表す．

QuestionGenerator[CloudObject[…]]

クラウドに配備された質問生成器を表す．

詳細とオプション

  • 生成関数 genfunc はパラメータの連想<|"name1":>val1,"name2":>val2|>に適用されたときにQuestionObjectを返す関数でなければならない．
  • QuestionGenerator[params,genfunc][]は，事実上，genfunc[params]を評価してQuestionObjectを生成する．
  • QuestionGenerator[params,genfunc][assessments]は genfunc[params,assessments]を評価し，AssessmentResultObject assessments およびパラメータ params に基づいてQuestionObjectを生成する．それまでの結果を assessments に含めることで，一連の質問をユーザのパフォーマンスに適応させることができる．
  • 通常，QuestionGeneratorは，CreateNotebook["QuestionNotebook"] あるいはファイル ▶ 新規作成 ▶ プログラマティックノートブック ▶ 質問フォームノートブックの作成の形で入手可能な質問ノートブックと一緒に使われる．
  • QuestionGeneratorは，ローカルに評価することもでき，配備された評価の場合はクラウドで評価することもできる．
  • クラウドに配備された質問生成器は，単一の生成器しか含まないクラウドオブジェクトの場合はQuestionGenerator[CloudObject[…]]，クラウドオブジェクトが複数の生成器，プール質問オブジェクト等を含む場合はQuestionGenerator[{CloudObject[…],"questionid"}]の形になる．
  • QuestionGenerator[genfunc]はQuestionGenerator[<||>,genfunc]に等しい．

例題

すべて開く すべて閉じる

例  (4)

生成器を使ってランダムな質問を作成する：

Wolfram Language code: primetest = QuestionGenerator[{"n" :> RandomInteger[1000]}, QuestionObject["True or False: " <> ToString[#n] <> " is Prime.", AssessmentFunction[PrimeQ[#n]]]&]
Wolfram Language code: primetest[]

RandomEntityを使って質問を作成する：

Wolfram Language code: gen = QuestionGenerator[{"p" :> RandomEntity["Person"]}, QuestionObject[QuestionInterface["ShortAnswer", <|"Prompt" -> Grid[ {{"In what year was this person born?"}, {#p["Image"]}, {CommonName[#p]}}]|>], AssessmentFunction[{DateValue[#p[EntityProperty["Person", "BirthDate"]], "Year"]}]]& ]
Wolfram Language code: gen[]

生成器を使ってランダムなアンケートの質問を作成する：

Wolfram Language code: gen = QuestionGenerator[{"food" :> RandomChoice[{"Hot dog", "Taco", "Poptart"}]}, QuestionObject[QuestionInterface["TrueFalse", "Is a " <> #food <> " a sandwich?"]]&]
Wolfram Language code: gen[]

毎回違う質問を与える生成器を作成する：

Wolfram Language code: gen = QuestionGenerator[ {"rand" :> RandomInteger[100]}, QuestionObject["What are the prime factors of " <> ToString[#rand], AssessmentFunction[ {(First /@ FactorInteger[#rand]) -> 1, (Prime /@ RandomInteger[{1, 10}, 3]) -> 0}]]&]

これを使う：

Wolfram Language code: gen[]

スコープ  (2)

ランダムな地理の質問を作成する：

Wolfram Language code: gen = QuestionGenerator[{"c" :> RandomEntity["Country"]}, QuestionObject["What is the capital of " <> CommonName[#c] <> "?", AssessmentFunction[Append[RandomSample[EntityList@EntityClass["City", "Country" -> #c], 3], #c[EntityProperty["Country", "CapitalCity"]] -> 1]]]&]
Wolfram Language code: gen[]

いくつかの質問例を作成する：

Wolfram Language code: gen[6]

質問生成器を作成してクラウドに配備する：

Wolfram Language code: deployed = ResourceFunction["QuestionDeploy"][QuestionGenerator[{"n" :> RandomInteger[1000]}, QuestionObject["True or False: " <> ToString[#n] <> " is Prime.", AssessmentFunction[PrimeQ[#n]]]&]]

配備された生成器を得る：

Wolfram Language code: gen = deployed["QuestionGenerator"]

これを使う：

Wolfram Language code: question = gen[]

質問の解は配備された生成器にも生成された質問にも含まれていない：

Wolfram Language code: FreeQ[{gen, question}, PrimeQ]

アプリケーション  (1)

プロットを含む微積分の問題を生成するQuestionGeneratorを作成する：

Wolfram Language code: qg = QuestionGenerator[{"trig" :> RandomChoice[{Sin, Cos}], "a" :> RandomInteger[{1, 4}]}, Module[{func, der, int}, func = #trig[x] ^ #a; der = D[func, x]; int = Integrate[func, x]; plot = Plot[Evaluate[{Legended[func, f[x] == func], Legended[der, D[f[x], x]], Legended[int, Integrate[f[x], x]]}], ...]; QuestionObject[QuestionInterface["TextCompletion", <|"Prompt" -> plot, "Template" -> TemplateObject[ {HoldForm[D[f, x]] == TemplateSlot[1], " ", HoldForm[Integrate[f, x]] == TemplateSlot[2]} ], "Interpreter" -> "HeldMathExpression"|>], AssessmentFunction[{{der, int}}, <|"ComparisonMethod" -> "CalculusResult", "ListAssessment" -> "AllElementsOrdered"|>]]]&]

ランダムな問題を生成する：

Wolfram Language code: qg[]
Wolfram Research (2022), QuestionGenerator, Wolfram言語関数， https://reference.wolfram.com/language/ref/QuestionGenerator.html.

テキスト

Wolfram Research (2022), QuestionGenerator, Wolfram言語関数， https://reference.wolfram.com/language/ref/QuestionGenerator.html.

CMS

Wolfram Language. 2022. "QuestionGenerator." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/QuestionGenerator.html.

APA

Wolfram Language. (2022). QuestionGenerator. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/QuestionGenerator.html

BibTeX

@misc{reference.wolfram_2026_questiongenerator, author="Wolfram Research", title="{QuestionGenerator}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/QuestionGenerator.html}", note=[Accessed: 01-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_questiongenerator, organization={Wolfram Research}, title={QuestionGenerator}, year={2022}, url={https://reference.wolfram.com/language/ref/QuestionGenerator.html}, note=[Accessed: 01-November-2026]}