WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Slider2D[{x,y}]

設定値 x と y が0から1の範囲にある2Dスライダーを表す．

Slider2D[Dynamic[pt]]

pt の動的に更新された現行値をその設定値とする．スライダーが動かされると pt の値はリセットされる．

Slider2D[pt,{min,max}]

各方向に min から max の範囲にある2Dスライダーを表す．

Slider2D[pt,{min,max,d}]

各方向にステップ d でジャンプする2Dスライダーを表す．

Slider2D[pt,{{xmin,ymin},{xmax,ymax}}]

x 方向と y 方向で異なる範囲を指定する．

Slider2D[pt,{{xmin,ymin},{xmax,ymax},{dx,dy}}]

dx, dy のジャンプを使う．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Appearance  
AutoAction  
Background  
Show More Show More
BaselinePosition  
ContinuousAction  
Enabled  
ImageMargins  
ImageSize  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

Slider2D

Slider2D[{x,y}]

設定値 x と y が0から1の範囲にある2Dスライダーを表す．

Slider2D[Dynamic[pt]]

pt の動的に更新された現行値をその設定値とする．スライダーが動かされると pt の値はリセットされる．

Slider2D[pt,{min,max}]

各方向に min から max の範囲にある2Dスライダーを表す．

Slider2D[pt,{min,max,d}]

各方向にステップ d でジャンプする2Dスライダーを表す．

Slider2D[pt,{{xmin,ymin},{xmax,ymax}}]

x 方向と y 方向で異なる範囲を指定する．

Slider2D[pt,{{xmin,ymin},{xmax,ymax},{dx,dy}}]

dx, dy のジャンプを使う．

詳細とオプション

  • Slider2D[…]は，ノートブックにインタラクティブに操作でき，水平方向にも垂直方向にも動かすことができる2Dスライダーを表示する．
  • Slider2D[Dynamic[pt]]は，スライダーが動かされると pt の値をリセットする．Slider2D[pt]はリセットしない．
  • Slider2D[pt,{nmin,nmax,dn}]は，nmin と dn が整数のときは整数位置にジャンプする．
  • Slider2D[pt,{rmin,rmax,dr}]は，一般に，Range[rmin,rmax,dr]で与えられる位置にジャンプする．
  • Slider2D[pt,{{xmin,ymin},{xmax,ymax},{dx,dy}}]で，dx または dy は，対応する方向の設定が連続的であることを示す0でもよい．
  • Slider2D中の座標はGraphicsのデフォルトと同じ方向に，すなわち，x は左から右に，y は下から上に動く．
  • Slider2D[pt,{{xmin,ymax},{xmax,ymin}}]は，ymax > yminのときは，y が上から下に動くスライダーを表す．
  • 2Dスライダーの値が与えられた範囲外のとき，その値は辺のどれか1つに表される．
  • 以下のオプションを与えることができる．
  • Appearance Automatic2Dスライダーの全体的な外観
    AutoAction Falseマウスが上に来たときに2Dスライダーを自動的に動かすかどうか
    BaselinePosition Automatic周囲のテキストのベースラインとの並べ方
    BaseStyle{}2Dスライダーのベーススタイル指定
    ContinuousAction Trueスライダーが動かされるたびに継続的に更新するかどうか
    Enabled Automatic2Dスライダーを有効にするか，灰色（無効）にするか
    Exclusions{}除外すべき特定の点
    ImageMargins 0表示された2Dスライダー画像の周りの余白
    ImageSize Automatic表示された2Dスライダーの全体的な画像サイズ
  • Appearance->"Labeled"は，スライダーの現行値を編集可能なラベルとして表示する．
  • BaseStyleの設定値は，一般に現行スタイルシートの"Slider2D"スタイルで与えられるデフォルトスタイルに加えられる．
  • Slider2D[]はSlider2D[{0.5,0.5}]と等価である．

例題

すべて開く すべて閉じる

例  (2)

特定の2Dスライダー設定：

Wolfram Language code: Slider2D[{.7, .3}]

スライダーの設定を動的に更新する：

Wolfram Language code: {Slider2D[Dynamic[r]], Dynamic[r]}

スコープ  (3)

範囲を定義する：

Wolfram Language code: {Slider2D[Dynamic[x], {{-4, -1}, {4, 1}}], Dynamic[x]}

範囲と刻み幅を定義する：

Wolfram Language code: {Slider2D[Dynamic[y], {{-4, -1}, {4, 1}, {2, 0.25}}], Dynamic[y]}

「現在位置で評価」を使ってアクティブな2Dスライダーを得る：

Wolfram Language code: Setting[Slider2D[]]

次にSettingを評価して実際の値を得る：

Wolfram Language code: Setting[Slider2D[{0.99, 0.1}]]

オプション  (12)

Appearance  (2)

異なるサイズ：

Wolfram Language code: Table[Slider2D[{0.5, 0.5}, Appearance -> a], {a, {Tiny, Small, Medium, Large}}]

ラベルを加える：

Wolfram Language code: Slider2D[{0.5, 0.5}, Appearance -> "Labeled"]

AutoAction  (1)

カーソルがスライダー上を移動すると値が変化する：

Wolfram Language code: {Slider2D[Dynamic[x], AutoAction -> True], Dynamic[x]}

Background  (2)

背景色を設定する：

Wolfram Language code: Table[Slider2D[{0.5, 0.5}, ImageMargins -> 10, Background -> c], {c, {Pink, Green, Gray, Yellow}}]

背景色を動的に変更する：

Wolfram Language code: Slider2D[Dynamic[x], ImageMargins -> 10, Background -> Dynamic[Hue@@x]]

BaselinePosition  (1)

周囲のテキストと揃えるためのベースラインを設定する：

Wolfram Language code: Row[Table[Slider2D[{0.5, 0.5}, BaselinePosition -> p], {p, {Bottom, Center, Top}}], "xxx"]

ContinuousAction  (1)

デフォルトで，コントローラが影響されると設定が継続的に変化する：

Wolfram Language code: {Slider2D[Dynamic[x]], Dynamic[x]}

マウスが放されたときだけ設定値を更新するようにする：

Wolfram Language code: {Slider2D[Dynamic[y], ContinuousAction -> False], Dynamic[y]}

Enabled  (1)

デフォルトでSlider2Dは有効になっている：

Wolfram Language code: Slider2D[{0.5, 0.5}]

スライダーを無効とし，現行状態が可視で残るようにする：

Wolfram Language code: Slider2D[{0.3, 0.8}, Enabled -> False]

ImageMargins  (2)

画像の余白に記号値を使う：

Wolfram Language code: Table[Framed@Slider2D[ImageMargins -> m], {m, {Small, Medium, Large}}]

画像の余白を印刷用ポイント数で設定する：

Wolfram Language code: Table[Framed@Slider2D[ImageMargins -> m], {m, {0, 5, 10}}]

ImageSize  (2)

予め設定してある値を使う：

Wolfram Language code: Table[Slider2D[Dynamic[x], ImageSize -> s], {s, {Tiny, Small, Medium, Large}}]

数値を用いる：

Wolfram Language code: Table[Slider2D[Dynamic[x], ImageSize -> {s, s}], {s, {30, 50, 100}}]

アプリケーション  (2)

色選択装置：

Wolfram Language code: {Slider2D[Dynamic[c]], Dynamic@Graphics[{Hue@@c, Rectangle[]}, ImageSize -> 100]}

簡単なカメラのコントローラ：

Wolfram Language code: DynamicModule[{p = {2π, 0}}, {Slider2D[Dynamic[p], {{2Pi, 0}, {0, Pi}}], ParametricPlot3D[{Cos[u] Cos[v], Sin[u] Cos[v], Sin[v]}^3, {u, 0, 2Pi}, {v, -Pi / 2, Pi / 2}, Mesh -> None, PlotRange -> All, Ticks -> None, SphericalRegion -> True, ViewPoint -> Dynamic[4{Cos[p[[1]]]Sin[p[[2]]], Sin[p[[1]]]Sin[p[[2]]], Cos[p[[2]]]}]]}]

特性と関係  (1)

LocatorあるいはLocatorPaneはコントロールをグラフィックス中に入れなければならないときに使うことができる：

Wolfram Language code: {Slider2D[Dynamic[pt1]], Dynamic[pt1]}
Wolfram Language code: DynamicModule[{pt2 = {0, 0}}, {Framed[Graphics[{Locator[Dynamic[pt2]]}, PlotRange -> 1]], Dynamic[pt2]}]
Wolfram Language code: {LocatorPane[Dynamic[pt3], Framed[Graphics[{}, PlotRange -> 1]]], Dynamic[pt3]}

考えられる問題  (1)

Slider2Dの限界は，x と y の範囲ではなく角の座標を与えることで指定する：

Wolfram Language code: Slider2D[{1 / 2, 1 / 2}, {{0, 0}, {1, 1}}]

限界が同じなのでスライダーは動かせない：

Wolfram Language code: Slider2D[{1 / 2, 1 / 2}, {{0, 1}, {0, 1}}]

おもしろい例題  (1)

1対のスライダー：

Wolfram Language code: {Slider2D[Dynamic[r]], Slider2D[Dynamic[1 - r, (r = 1 - #)&]]}
Wolfram Research (2007), Slider2D, Wolfram言語関数， https://reference.wolfram.com/language/ref/Slider2D.html （2017年に更新）.

テキスト

Wolfram Research (2007), Slider2D, Wolfram言語関数， https://reference.wolfram.com/language/ref/Slider2D.html （2017年に更新）.

CMS

Wolfram Language. 2007. "Slider2D." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/Slider2D.html.

APA

Wolfram Language. (2007). Slider2D. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Slider2D.html

BibTeX

@misc{reference.wolfram_2026_slider2d, author="Wolfram Research", title="{Slider2D}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/Slider2D.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_slider2d, organization={Wolfram Research}, title={Slider2D}, year={2017}, url={https://reference.wolfram.com/language/ref/Slider2D.html}, note=[Accessed: 03-November-2026]}