WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Sow[e]

囲み込んでいる最も近くのReapによって e が収集されるように指定する．

Sow[e,tag]

パターンが tag とマッチする，囲み込んでいる最も近くのReapによって e が収集されるように指定する．

Sow[e,{tag1,tag2,…}]

e が tagiにマッチする各パターンにつき1回ずつ収集されるように指定する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Sow

Sow[e]

囲み込んでいる最も近くのReapによって e が収集されるように指定する．

Sow[e,tag]

パターンが tag とマッチする，囲み込んでいる最も近くのReapによって e が収集されるように指定する．

Sow[e,{tag1,tag2,…}]

e が tagiにマッチする各パターンにつき1回ずつ収集されるように指定する．

詳細

  • Sow[e,…]は e を返す．
  • 複数の同じ tagiがあると，Reapが返したリストの中で単一の式を何度も表示することができる．
  • Sow[e]はSow[e,None]と等価である．
  • Sow[e,{{tag}}]は{tag}タグの付いた式を播く．

例題

すべて開く すべて閉じる

例  (4)

Reapが集めるように一部を「播いて」一連の式を評価する：

Wolfram Language code: Reap[Sow[a];b;Sow[c];Sow[d];e]

各ステップでi^2を「播いて」総和を計算する：

Wolfram Language code: Reap[Sum[Sow[i ^ 2] + 1, {i, 10}]]

異なるタグで「播かれた」式についてそれぞれリストを作る：

Wolfram Language code: Reap[Sow[1, x];Sow[2, y];Sow[3, x];Sow[4, y]]

タグxを付けて「播かれた」式だけを刈り取る：

Wolfram Language code: Reap[Sow[1, x];Sow[2, y];Sow[3, x];Sow[4, y], x]

スコープ  (5)

Sowは計算のどこで用いてもよい：

Wolfram Language code: Reap[MapAll[If[PrimeQ[#], Sow[#]]&, Integrate[1 / (x ^ 5 - 1), x]];]

関数の内側でも作用する：

Wolfram Language code: f[e_] := If[PrimeQ[e], Sow[e]]
Wolfram Language code: Reap[MapAll[f, Integrate[1 / (x ^ 5 - 1), x]];]

単一の式に複数のタグを付けて「播く」こともできる：

Wolfram Language code: Reap[Sow[1, x];Sow[2, {x, y}];Sow[3, y]]

単一のタグが繰り返されると，式は繰り返し播かれる：

Wolfram Language code: Reap[Sow[1, {x, x, x}];Sow[2, {x, y}];Sow[3, y]]

Reap中のパターンはどのタグを集めるかの指定に使うことができる：

Wolfram Language code: Reap[Sow[1, x];Sow[2, {x, y}];Sow[3, {y, z}];Sow[4, {x, y, z}], x | y]

デフォルトはパターン_なので，すべてが集められる：

Wolfram Language code: Reap[Sow[1, x];Sow[2, {x, y}];Sow[3, {y, z}];Sow[4, {x, y, z}]]

タグはのような形でもよく，次はTrueとFalseである：

Wolfram Language code: Reap[Sow[#, # > 0]& /@ {1, -1, 2, -3, 1, 4, 5};]
Wolfram Language code: Reap[Sow[#, # > 0]& /@ {1, -1, 2, -3, 1, 4, 5};, True]

アプリケーション  (3)

FindRootを評価するときに取られる全ステップのリストを作る：

Wolfram Language code: Reap[FindRoot[Cos[x] == x, {x, 1}, StepMonitor :> Sow[x]]]

1/100より下の反復はそのままにして，反復するマップを評価する：

Wolfram Language code: Reap[Nest[(If[# < 1 / 100, Sow[#]];4 #(1 - #))&, 0.2, 100]]

10を法とする の値の同値類を求める：

Wolfram Language code: Reap[Do[Sow[i, Mod[i ^ 2, 10]], {i, 20}]]

特性と関係  (2)

Sow[x]は x を副産物として「播いて」返す：

Wolfram Language code: Sow[x]

播かれた式は一番内側に囲み込まれているReapによって刈り取られる：

Wolfram Language code: Reap[Reap[Sow[2 ^ 20];Sow[2 ^ 30]]]
Wolfram Research (2003), Sow, Wolfram言語関数， https://reference.wolfram.com/language/ref/Sow.html.

テキスト

Wolfram Research (2003), Sow, Wolfram言語関数， https://reference.wolfram.com/language/ref/Sow.html.

CMS

Wolfram Language. 2003. "Sow." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Sow.html.

APA

Wolfram Language. (2003). Sow. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Sow.html

BibTeX

@misc{reference.wolfram_2026_sow, author="Wolfram Research", title="{Sow}", year="2003", howpublished="\url{https://reference.wolfram.com/language/ref/Sow.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_sow, organization={Wolfram Research}, title={Sow}, year={2003}, url={https://reference.wolfram.com/language/ref/Sow.html}, note=[Accessed: 03-November-2026]}