WOLFRAM

Wolfram 语言与系统参考资料中心

SpatialPointSelect[spdata,crit]

根据 crit 选择 SpatialPointData spdata 的子集.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
根据点的条件  
根据注释  
应用  
参见
相关指南
历史
按以下格式引用：

SpatialPointSelect

SpatialPointSelect[spdata,crit]

根据 crit 选择 SpatialPointData spdata 的子集.

更多信息

  • SpatialPointSelect 通常用于从 SpatialPointData 选取一部分数据，从而获得较小的 SpatialPointData.
  • 从概念上讲，SpatialPointSelect 相当于对 {{point1,ann1},{point2,ann2},…} 形式的点和注释应用以获取一个子集.
  • 标准函数 crit 通常是一个布尔表达式，含有对点和注释的条件，如 (Norm[#Point]<1&& #species"Birch")&，其中，species 是注释键之一.
  • 可在 crit 中使用以下参数：
  • #Point关于点的条件
    #key针对与注释 "key" 关联的值的条件

范例

打开所有单元 关闭所有单元

基本范例  (2)

选择子区域中的点：

Wolfram Language code: spd = SpatialPointData[RandomReal[1, {100, 2}], Rectangle[{0, 0}, {1, 1}]]

绘制观察区域中的点：

Wolfram Language code: Show[RegionPlot[spd["ObservationRegion"]], ListPlot[spd["Points"]]]

选择较小矩形中的点：

Wolfram Language code: sub = SpatialPointSelect[spd, Element[#Point, Rectangle[{0, 0}, {1 / 2, 1}]]&]

绘制子集中的点：

Wolfram Language code: Show[RegionPlot[spd["ObservationRegion"]], ListPlot[sub["Points"]]]

根据纬度条件选择点：

Wolfram Language code: spd = SpatialPointData[RandomGeoPosition[GeoBoundsRegion[{{-23.43, 23.43}, {-180, 180}}], 100]]

选择赤道上或赤道上方的点：

Wolfram Language code: sub = SpatialPointSelect[spd, #Point["Latitude"] ≥ 0&]

绘制两个数据集：

Wolfram Language code: GeoListPlot /@ {spd["Points"], sub["Points"]}

范围  (7)

根据点的条件  (5)

选择给定区域内的点：

Wolfram Language code: spd = SpatialPointData[RandomReal[1, {100, 2}], Rectangle[]];
Wolfram Language code: Show[RegionPlot[{spd["ObservationRegion"]}], ListPlot[spd["Points"]]]

创建一个子集：

Wolfram Language code: reg = Disk[{0, 0}, .5]; sub = SpatialPointSelect[spd, Element[#Point, reg]&]
Wolfram Language code: Show[RegionPlot[{sub["ObservationRegion"], reg}], ListPlot[sub["Points"]]]

选取 norm 小于 1/2 的点：

Wolfram Language code: spd = SpatialPointData[RandomReal[1, {5000, 2}]]
Wolfram Language code: pts1 = ListPlot[spd["Points"], AspectRatio -> 1]

定义选择标准：

Wolfram Language code: crit = Norm[#Point] < 1 / 2&;

选择点：

Wolfram Language code: sub = SpatialPointSelect[spd, crit]

绘制原始数据及所选的子集：

Wolfram Language code: Show[pts1, ListPlot[sub["Points"], PlotStyle -> Orange]]

选取第一个坐标大于 1/3 的所有点：

Wolfram Language code: spd = SpatialPointData[RandomReal[1, {100, 2}]]

定义选择条件：

Wolfram Language code: cond = First[#Point] > 1 / 3&;

选择点：

Wolfram Language code: sub = SpatialPointSelect[spd, cond]

绘制原始数据及所选的子集：

Wolfram Language code: Show[ListPlot[spd["Points"], PlotStyle -> PointSize[0.03]], ListPlot[sub["Points"], PlotStyle -> {Orange, PointSize[0.015]}], AspectRatio -> 1]

根据地理位置选择点：

Wolfram Language code: spd = SpatialPointData[RandomGeoPosition[GeoBoundsRegion[{{0, 90}, {-180, 0}}], 100]];
Wolfram Language code: GeoListPlot[spd["Points"]]

选择芝加哥 2000 公里内的位置：

Wolfram Language code: sub = SpatialPointSelect[spd, GeoDistance[#Point, Entity["City", {"Chicago", "Illinois", "UnitedStates"}]["Position"]] < Quantity[2000, "km"]&]
Wolfram Language code: GeoListPlot[sub["Points"]]

提取数据中靠近某个区域的子集：

Wolfram Language code: data = RandomReal[1, {500, 2}]; reg = Rectangle[];
Wolfram Language code: spd = SpatialPointData[data, reg]
Wolfram Language code: areaOfInterest = Rectangle[{1, .3}, {1.5, .5}];
Wolfram Language code: sub = SpatialPointSelect[spd, (0 < RegionDistance[areaOfInterest, #Point] < .2)&]

可视化所选数据：

Wolfram Language code: Graphics[{{Opacity[.1], spd["ObservationRegion"]}, {Opacity[.3], areaOfInterest}, {ColorData[97, 1], Point[spd["Points"]]}, {ColorData[97, 2], Point[sub["Points"]]}, Inset[Style["reg", Bold], {0.05, 0.05}], Inset[Style["Area of Interest", Bold], {1.25, 0.4}]}]

根据注释  (2)

根据注释值保留选定的点：

Wolfram Language code: pts = RandomReal[1, {10, 2}]; reg = Rectangle[{0, 0}, {1, 1}];
Wolfram Language code: colors = RandomChoice[ColorData[97, "ColorList"], 10]; diameters = RandomReal[{0, 1 / 3}, 10];
Wolfram Language code: spd = SpatialPointData[pts -> {"color" -> colors, "diameter" -> diameters}, reg]

显示数据的注释：

Wolfram Language code: spd["Annotations"]

选择其“颜色”注释值接近 Red 的点：

Wolfram Language code: sub = SpatialPointSelect[spd, (ColorDistance[#color, Red] < .7)&]

显示剩下的点的注释：

Wolfram Language code: sub["Annotations"]

根据选定的注释值选择点：

Wolfram Language code: pts = RandomReal[1, {10, 2}]; reg = Rectangle[{0, 0}, {1, 1}];
Wolfram Language code: colors = RandomChoice[ColorData[97, "ColorList"], 10]; diameters = RandomReal[{0, 1 / 3}, 10];
Wolfram Language code: spd = SpatialPointData[pts -> {"color" -> colors, "diameter" -> diameters}, reg]

显示数据的注释：

Wolfram Language code: spd["Annotations"]
Wolfram Language code: sub = SpatialPointSelect[spd, #diameter ≥ .1&]

显示子集的注释：

Wolfram Language code: sub["Annotations"]

应用  (1)

美国酿酒厂的位置：

Wolfram Language code: data = SpatialPointData[«2»];

观测区域是根据位置推断出来的：

Wolfram Language code: GeoGraphics[data["ObservationRegion"]]

查找美国本土（contiguous US）的经纬度边界：

Wolfram Language code: reg = EntityValue[GeoVariant[Entity["Country", "UnitedStates"], "DefaultMapArea"], "Polygon"];
Wolfram Language code: {{minLat, maxLat}, {minLon, maxLon}} = GeoBounds[reg]

选择酿酒厂：

Wolfram Language code: selected = SpatialPointSelect[data, And[minLat <= (#Point["Latitude"]) <= maxLat&, minLon <= (#Point["Longitude"]) <= maxLon&]]

SpatialPointSelect 保留了原始观测区域：

Wolfram Language code: selected["ObservationRegion"] == data["ObservationRegion"]

用选定的点和较小的观测区域创建新的空间点数据：

Wolfram Language code: breweries = SpatialPointData[selected["Points"], reg]
Wolfram Language code: GeoGraphics[{Point[breweries["Points"]], Red, breweries["ObservationRegion"]}]
Wolfram Research (2020)，SpatialPointSelect，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SpatialPointSelect.html.

文本

Wolfram Research (2020)，SpatialPointSelect，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SpatialPointSelect.html.

CMS

Wolfram 语言. 2020. "SpatialPointSelect." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/SpatialPointSelect.html.

APA

Wolfram 语言. (2020). SpatialPointSelect. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/SpatialPointSelect.html 年

BibTeX

@misc{reference.wolfram_2026_spatialpointselect, author="Wolfram Research", title="{SpatialPointSelect}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/SpatialPointSelect.html}", note=[Accessed: 16-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_spatialpointselect, organization={Wolfram Research}, title={SpatialPointSelect}, year={2020}, url={https://reference.wolfram.com/language/ref/SpatialPointSelect.html}, note=[Accessed: 16-June-2026]}