WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

SystemModelSimulateSensitivity[model,{p1,p2,…}]

エクスペリメント設定に基づいて，model とパラメータ piに対する感度のシミュレーションを行う．

SystemModelSimulateSensitivity[model,tmax,{p1,p2,…}]

0から tmaxまでシミュレーションを行う．

SystemModelSimulateSensitivity[model,{tmin,tmax},{p1,p2,…}]

tminから tmaxまでシミュレーションを行う．

SystemModelSimulateSensitivity[model,vars,{tmin,tmax},{p1,p2,…}]

変数 vars についてのシミュレーションデータのみを保存する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
モデル  
シミュレーション時間  
感度結果  
変数，パラメータ，入力  
結果の保存  
一般化と拡張  
オプション  
InterpolationOrder  
Method  
ProgressReporting  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

SystemModelSimulateSensitivity

SystemModelSimulateSensitivity[model,{p1,p2,…}]

エクスペリメント設定に基づいて，model とパラメータ piに対する感度のシミュレーションを行う．

SystemModelSimulateSensitivity[model,tmax,{p1,p2,…}]

0から tmaxまでシミュレーションを行う．

SystemModelSimulateSensitivity[model,{tmin,tmax},{p1,p2,…}]

tminから tmaxまでシミュレーションを行う．

SystemModelSimulateSensitivity[model,vars,{tmin,tmax},{p1,p2,…}]

変数 vars についてのシミュレーションデータのみを保存する．

詳細とオプション

  • SystemModelSimulateSensitivityは，システムモデルのパラメータ値を変更した場合のシミュレーション結果の変動の推定に使われる．
  • model は以下の形にできる．
  • SystemModel[…]一般的なシステムモデル
    StateSpaceModel[…]状態空間モデル
    TransferFunctionModel[…]伝達関数モデル
    AffineStateSpaceModel[…]アフィン状態空間モデル
    NonlinearStateSpaceModel[…]非線形状態空間モデル
    DiscreteInputOutputModel[…]離散入出力モデル
  • SystemModelSimulateSensitivityはSystemModelSimulationDataオブジェクトを返す．
  • SystemModelSimulateSensitivityは，すべての実変数 について解 と，のときの微分係数, , …を生成する．
  • 感度は，sd["SensitivityNames"]を使ってSystemModelSimulationDataオブジェクト sd にリストすることができる．
  • 保存されたシミュレーション変数 vars は次の値を持つことができる．
  • Automatic何を保存するか自動的に選択する
    {v1,v2,…}変数 viのみを保存する
    All全変数を保存する
  • SystemModelSimulateSensitivity[…,spec]は初期値，パラメータ，入力にAssociation specを使う．
  • "ParameterValues"{p1val1,…}パラメータ piは値 valiを持つ
    "InitialValues"{v1val1,…}変数 viは初期値 valiを持つ
    "Inputs"{in1fun1,…}入力 iniは時点 t で値 funi[t]を持つ
  • "ParameterValues"または"InitialValues"を{pi{c1,c2,…},…}に設定すると，pi が cjの値を取って，シミュレーションが並列で実行される．
  • "InitialValues"はModelicaモデルの start プロパティに相当する．
  • 次は，使用可能なオプションである．
  • InterpolationOrder Automaticイベント間の出力の連続次数
    Method Automatic使用するシミュレーションメソッド
    ProgressReporting $ProgressReporting進捗表示を制御する
  • 通常，オプション設定をAutomaticは，設定値が model あるいはそのエクスペリメント設定から取られることを意味する．
  • Method{"Sensitivity""WSM"}を用いると，状態変数に対する感度は，SystemModel model についてCVODESソルバを用いて計算される．
  • その他のMethodシミュレーション部分オプションは，SystemModelSimulateに示されている通りである．

例題

すべて開く すべて閉じる

例  (3)

モデルのエクスペリメント設定の時間間隔でのパラメータ感度を調べる：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"a"}]

感度名を抽出してプロットする：

Wolfram Language code: sim["SensitivityNames"]
Wolfram Language code: SystemModelPlot[sim, {{"y", "a"}, {"z", "a"}}]

パラメータの相対的変動に対する信号の感度を示す：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"y", "z"}, 5, {"a"}]

aが10%変化する際のyとzの境界をプロットする：

Wolfram Language code: SystemModelPlot[sim, {{"y", "a", 0.1}, {"z", "a", 0.1}}]

モデルの図表示を入力として使う：

Wolfram Language code: SystemModel["IntroductoryExamples.ComponentBased.ElectricCircuit"]

上の出力をコピーペーストする：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"capacitor1.v"}, 5, {"sineVoltage1.f"}]

スコープ  (17)

モデル  (3)

NonlinearStateSpaceModelのシミュレーションの際に変数と感度を計算する：

Wolfram Language code: sim = SystemModelSimulateSensitivity[NonlinearStateSpaceModel[{{Cos[x] + 4*a*Sin[x/2]}, {x + Sin[x]}}, {x}, {}, {Automatic}, Automatic, SamplingPeriod -> None], 10, {a}, <|"ParameterValues" -> {a -> 1}|>]

感度名を抽出してプロットする：

Wolfram Language code: sim["SensitivityNames"]
Wolfram Language code: SystemModelPlot[sim, {{x, a}, {Subscript[, 1], a}}, PlotRange -> All]

aを40%変化させる際の状態の帯をプロットする：

Wolfram Language code: SystemModelPlot[sim, {{x, a, 0.4}}, PlotRange -> All]

AffineStateSpaceModelについてパラメータスイープにおける感度を計算する：

Wolfram Language code: sims = SystemModelSimulateSensitivity[AffineStateSpaceModel[{{Cos[x2], (-1 - a)*x2 + Cos[x1^2]}, {{0}, {1}}, {x2}, {{0}}}, {x1, x2}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None], 5, {a}, <|"ParameterValues" -> {a -> {1, 10}}|>]

aを50%変化させる際の状態の帯をプロットする：

Wolfram Language code: SystemModelPlot[sims, {{x2, a, 0.5}}]

DiscreteInputOutputModelについて感度を計算する：

Wolfram Language code: diom = DiscreteInputOutputModel[{u[0] + y[-1] + a y[-2], u[1] + u[0] + u[-1]}, {{u, {-2, -1, 1}}}, {{y, {-1, -1, -1}}}]
Wolfram Language code: sim = SystemModelSimulateSensitivity[diom, {a}, <|"Inputs" -> {1 -> Range[-20, 20]}, "ParameterValues" -> {a -> 1}|>]

aを5%変化させたときの出力の帯をプロットする：

Wolfram Language code: SystemModelPlot[sim, {{y, a, 0.05}}]

シミュレーション時間  (3)

モデルからの設定を使ってシミュレーションを行う：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"a"}]
Wolfram Language code: sim["SimulationInterval"]

時点0から5までシミュレーションを行う：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 5, {"a"}]
Wolfram Language code: sim["SimulationInterval"]

明示的な時間間隔でシミュレーションを行う：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {2, 10}, {"a"}]
Wolfram Language code: sim["SimulationInterval"]

感度結果  (6)

1つのパラメータの感度を調べる：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 50, {"a"}]
Wolfram Language code: sim["SensitivityNames"]
Wolfram Language code: SystemModelPlot[sim, {{"y", "a"}}]

パラメータaに対する感度のシミュレーションを行う：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 5, {"a"}];

感度の名前を得る：

Wolfram Language code: sim["SensitivityNames"]

aの変化に対するyの感度を得る：

Wolfram Language code: {ySensA} = sim[{{"y", "a"}}]

1つのパラメータからの感度を調べる：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 5, {"sineVoltage1.f"}];
Wolfram Language code: sim["SensitivityNames"]//Short

感度の1つをプロットする：

Wolfram Language code: SystemModelPlot[sim, {{"capacitor1.v", "sineVoltage1.f"}}]

信号のパラメータaに対する感度を示す：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 50, {"a"}]

感度の名前を得る：

Wolfram Language code: sim["SensitivityNames"]

aにおける変化に対するyの感度を，yについての名目軌跡とともに得る：

Wolfram Language code: {ySensA, y} = sim[{{"y", "a"}, "y"}, t]

もとのパラメータaとパラメータaを0.05大きくしたものでyをプロットする：

Wolfram Language code: Plot[{Tooltip[y, "Nominal"], Tooltip[y + 0.05 ySensA, "Perturbed"]}, {t, 0, 50}]

パラメータの相対的な変化に対する信号の感度を示す：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 5, {"a"}];

感度の名前を得る：

Wolfram Language code: sim["SensitivityNames"]

aにおける変化に対するyおよびzの感度を，名目軌跡および値とともに得る：

Wolfram Language code: {ySensA, zSensA, y, z, a0} = sim[{{"y", "a"}, {"z", "a"}, "y", "z", "a"}, t];

aの感度を10%変化させた場合の，yおよびzの境界をプロットする：

Wolfram Language code: {dY, dZ} = {a0 0.1ySensA, a0 0.1zSensA};
Wolfram Language code: Plot[{Tooltip[y, "y"], y + dY, y - dY, Tooltip[z, "z"], z + dZ, z - dZ}, {t, 0, 5}, Filling -> {2 -> {3}, 5 -> {6}}]

パラメータ aの絶対的な変化に対する信号の感度を示す：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 50, {"a"}]

aの変化に対するyの感度を，yの軌跡とともに得る：

Wolfram Language code: {ySensA, y} = sim[{{"y", "a"}, "y"}, t];

パラメータaが絶対値0.1で変化する際のyにおける変化を計算する：

Wolfram Language code: dY = 0.1 ySensA;

パラメータaが±0.1変化する際のyの変動をプロットする：

Wolfram Language code: Plot[{Tooltip[y, "y"], y + dY, y - dY}, {t, 0, 50}, Filling -> {2 -> {3}}]

変数，パラメータ，入力  (3)

シミュレーションの初期値を変更する：

Wolfram Language code: Subscript[sim, 1] = SystemModelSimulateSensitivity[[image], 50, {"a"}];
Wolfram Language code: Subscript[sim, 2] = SystemModelSimulateSensitivity[[image], 50, {"a"}, <|"InitialValues" -> {"y" -> 2.85}|>];

プロットの変化を比較する：

Wolfram Language code: SystemModelPlot[{Subscript[sim, 1], Subscript[sim, 2]}, {{"y", "a"}}]

シミュレーションのパラメータ値を変更する：

Wolfram Language code: Subscript[sim, 1] = SystemModelSimulateSensitivity[[image], 50, {"a"}];
Wolfram Language code: Subscript[sim, 2] = SystemModelSimulateSensitivity[[image], 50, {"a"}, <|"ParameterValues" -> {"a" -> 2.95}|>];

両者を1つのプロットで比較する：

Wolfram Language code: SystemModelPlot[{Subscript[sim, 1], Subscript[sim, 2]}, {{"y", "a"}}]

変数についての入力関数を与え，ゲインパラメータに対する出力の感度を調べる：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 10, {"gain.k"}, <|"Inputs" -> {"u" -> Sin}|>]

ゲインパラメータに対する出力の感度をプロットする：

Wolfram Language code: SystemModelPlot[sim, {{"integrator.y", "gain.k", 0.1}}]

結果の保存  (2)

選択した変数のみを保存する：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"y", "a"}, {"a"}]

指定された変数とパラメータのみが保存される：

Wolfram Language code: {sim["VariableNames"], sim["ParameterNames"]}

選択した変数のみを保存し，指定されたシミュレーション間隔でシミュレーションを行う：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"TR", "lambda"}, {0, 50}, {"lambda"}]

lambdaを20%変化させてTRの境界をプロットする：

Wolfram Language code: SystemModelPlot[sim, {{"TR", "lambda", 0.2}}]

一般化と拡張  (1)

デバッグメッセージはメッセージグループの"WSMDebug"に集められる：

Wolfram Language code: Hold["WSMDebug"] /. $MessageGroups

初期化のデバッグメッセージが出るようにする：

Wolfram Language code: On[SystemModelSimulateSensitivity::dinit]
Wolfram Language code: SystemModelSimulateSensitivity["DocumentationExamples.Basic.OneParameter", {0, 1}, {"a"}, Method -> {"Sensitivity" -> "WSM"}]

"WSMDebug"に関するすべてのデバッグメッセージが出ないようにする：

Wolfram Language code: Off["WSMDebug"]

オプション  (4)

InterpolationOrder  (1)

補間次数1と3，補間点3つでシミュレーションを行う：

Wolfram Language code: {Subscript[sim, 1], Subscript[sim, 2]} = Table[SystemModelSimulateSensitivity[[image], 7, {"a"}, Method -> {Automatic, "InterpolationPoints" -> 3}, InterpolationOrder -> intOrder], {intOrder, {1, 3}}];

感度変数を示す：

Wolfram Language code: SystemModelPlot[{Subscript[sim, 1], Subscript[sim, 2]}, {{"y", "a"}}]

Method  (2)

Method{"Sensitivity""WSM"}のとき，SystemModelに対する状態変数の感度はCVODESソルバを用いて計算される：

Wolfram Language code: simWSM = SystemModelSimulateSensitivity[[image], 5, {"a"}, Method -> {"Sensitivity" -> "WSM"}]
Wolfram Language code: simWSM["SensitivityNames"]

デフォルトメソッドを用いてすべての実変数に対する感度を計算する：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 5, {"a"}]
Wolfram Language code: sim["SensitivityNames"]

モデルが設定した数の補間点でSystemModelのシミュレーションを行い，感度を計算する：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 5, {"a"}]; SystemModelPlot[sim, {{"y", "a"}, {"z", "a"}, {Derivative[1]["z"], "a"}}]

カスタム数の補間点でシミュレーションを行い，感度を計算する：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 5, {"a"}, Method -> {"InterpolationPoints" -> 5}]; SystemModelPlot[sim, {{"y", "a"}, {"z", "a"}, {Derivative[1]["z"], "a"}}]

補間点数をカスタム指定して，状態変数に対する感度をシミュレートおよび計算する：

Wolfram Language code: simWSM = SystemModelSimulateSensitivity[[image], 5, {"a"}, Method -> {"Sensitivity" -> "WSM", "InterpolationPoints" -> 5}]; SystemModelPlot[simWSM, {{"y", "a"}, {"z", "a"}}]

ProgressReporting  (1)

ProgressReportingで進捗状況のレポートを制御する：

Wolfram Language code: SystemModelSimulateSensitivity[[image], {"a"}, ProgressReporting -> False]

アプリケーション  (5)

モデルの感度を調べる：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"y"}, 40, {"a"}];
Wolfram Language code: {y, ysensa} = sim[{"y", {"y", "a"}}, t];

パラメータの値を得る：

Wolfram Language code: a0 = First[sim[{"a"}]]

パラメータを変化させたときの偏差のピークを求める：

Wolfram Language code: {peakVal, {peakTime}} = NMaximize[{0.05 a0 ysensa, 0 < t < 40}, {t}]

5%感度境界と偏差がピークとなる時間を示す：

Wolfram Language code: Plot[Evaluate[{y, y + 0.05 a0 ysensa, y - 0.05 a0 ysensa}], {t, 0, 40}, Filling -> {2 -> {3}}, GridLines -> {{peakTime[[2]]}, None}]

どの変数が周波数パラメータに最も敏感かを求める：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"integrator1.y", "integrator2.y", "integrator3.y"}, 1, {"sine.f"}];

10%感度境界は"integrator3.y"がパラメータに最も敏感であることを示している：

Wolfram Language code: SystemModelPlot[sim, Table[{v, "sine.f", 0.1}, {v, {"integrator1.y", "integrator2.y", "integrator3.y"}}]]

回転する輪のシミュレーションを行う：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"wheel1.x", "wheel1.y"}, 10, {"wheel1.radius", "wheel1.m"}]

輪の位置と輪の異なるパラメータに対する感度を選ぶ：

Wolfram Language code: {x, y, xsensrad, ysensrad, xsensmass, ysensmass} = sim[{"wheel1.x", "wheel1.y", {"wheel1.x", "wheel1.radius"}, {"wheel1.y", "wheel1.radius"}, {"wheel1.x", "wheel1.m"}, {"wheel1.y", "wheel1.m"}}, t];
Wolfram Language code: {r0, m0} = sim[{"wheel1.radius", "wheel1.m"}]

輪の半径と質量を4%変化させた場合の輪の経路をそれぞれ示す：

Wolfram Language code: d = 0.04; ParametricPlot[{{x, y}, {x + v d #[[1]], y + v d #[[2]]}}, {v, -1, 1}, {t, 0, 10}, PlotPoints -> 40, Mesh -> None, Axes -> None, PlotLabel -> #[[3]], FrameTicks -> {{Automatic, None}, {None, None}}]& /@ {{xsensrad r0, ysensrad r0, "Wheel radius"}, {xsensmass m0, ysensmass m0, "Wheel mass"}}

測定データを比較することで，モデルのパラメータを調整する：

Wolfram Language code: model = \!\(\*GraphicsBox[«8»]\);
Wolfram Language code: data = Import["ExampleData/inertiaTestData.dat"];
Wolfram Language code: {p1, p2, var} = {"Resistor1.R", "SpringDamper1.d", "Inertia2.w"};

シミュレーションのキャッシュを設定し，SystemModelSimulateSensitivityを使って勾配を得る：

Wolfram Language code: g[p_ ? NumericQ, q_ ? NumericQ] := g[p, q] = Quiet[AssociationThread[{var, {var, p1}, {var, p2}}, SystemModelSimulateSensitivity[model, {var}, 40, {p1, p2}, <|"ParameterValues" -> {p1 -> p, p2 -> q}|>, ProgressReporting -> False][{var, {var, p1}, {var, p2}}]], {SystemModelSimulateSensitivity::gen}]

特定のパラメータ値についてのシミュレーションの結果をプロットする：

Wolfram Language code: Plot[g[0.1, 0.25][var][t], {t, 0, 40}]

勾配を使わずに，パラメータを測定データにフィットする：

Wolfram Language code: AbsoluteTiming[FindFit[data, g[p, q][var][t], {{p, 0.1}, {q, 0.25}}, t, Gradient -> "FiniteDifference"]]

感度情報を使ってフィットする：

Wolfram Language code: AbsoluteTiming[pars = FindFit[data, g[p, q][var][t], {{p, 0.1}, {q, 0.25}}, t, Gradient :> Comap[Lookup[g[p, q], {{var, p1}, {var, p2}}], t]]]

フィットされたパラメータでシミュレーションを行う：

Wolfram Language code: sim = SystemModelSimulate[model, {0, 40}, <|"ParameterValues" -> ({p1 -> p, p2 -> q} /. pars)|>];

テストデータと調整されたモデルを一緒に示す：

Wolfram Language code: Show[SystemModelPlot[sim, {var}, PlotStyle -> Orange], ListPlot[data]]

解をその感度境界とともに示す：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 30, {"a"}]
Wolfram Language code: sim["SensitivityNames"]
Wolfram Language code: {y, ysensa} = sim[{"y", {"y", "a"} }, t];

パラメータの名目値を得る：

Wolfram Language code: a0 = First[sim[{"a"}]]

5%感度境界を示す：

Wolfram Language code: dY = 0.05 * a0 ysensa;
Wolfram Language code: Plot[Evaluate[{y, y + dY, y - dY}], {t, 0, 30}, Filling -> {2 -> {3}}]

5%の最大変化でシミュレーションを行う：

Wolfram Language code: simv = SystemModelSimulate[[image], 30, <|"ParameterValues" -> {"a" -> a0 Range[0.95, 1.05, 0.02]}|>];

軌跡を得る：

Wolfram Language code: yV = Table[sd[{"y"}, t][[1]], {sd, simv}];

軌跡のほとんどが近似された感度境界に含まれていることを示す：

Wolfram Language code: Plot[Evaluate[{y, y + dY, y - dY, yV}], {t, 0, 30}, Filling -> {2 -> {3}}]

特性と関係  (4)

感度のシミュレーションを対応する微分方程式の感度と比較する：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 50, {"a"}];
Wolfram Language code: SystemModelPlot[sim, {"y", {"y", "a"}}]
Wolfram Language code: y = DSolve[{f'[t] + Sin[a]f[t] == 0, f[0] == b}, f[t], t][[1, 1, 2]];
Wolfram Language code: ySensA = D[y, a]
Wolfram Language code: Plot[Evaluate[{y, ySensA} /. {a -> 3, b -> 1}], {t, 0, 50}, PlotRange -> All]

相対的なパラメータの変化についての境界をプロットする：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 5, {"a"}];

aの変化に対するyの感度を，yとaの値とともに得る：

Wolfram Language code: {ySensA, y, a0} = sim[{{"y", "a"}, "y", "a"}, t];

aの感度を10%変化させたときのyの境界をプロットする：

Wolfram Language code: dY = a0 0.1ySensA;
Wolfram Language code: Plot[{Tooltip[y, "y"], y + dY, y - dY}, {t, 0, 5}, Filling -> {2 -> {3}}, AxesLabel -> {"t", None}]

代りにSystemModelPlotを使う：

Wolfram Language code: SystemModelPlot[sim, {{"y", "a", 0.1}}]

感度はパラメータ内の小さい変化に対して有効である：

Wolfram Language code: {par, var} = {"sineVoltage1.f", "capacitor1.v"};

パラメータに対する感度を得る：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {var}, 5, {par}];

パラメータを変化させてシミュレーションを行う：

Wolfram Language code: {p0} = sim[{par}];
Wolfram Language code: sim2 = SystemModelSimulate[[image], {var}, 5, <|"ParameterValues" -> {par -> {0.9p0, 1.1p0}}|>];

プロット内で比較すると，10%の変動で軌跡が計算限界の外に出ることが分かる：

Wolfram Language code: Show[SystemModelPlot[sim, {{var, par, 0.1}}, {2.5, 3.5}], SystemModelPlot[sim2, {var}]]

SystemModelParametricSimulateをさまざまな値について評価可能な関数に使う：

Wolfram Language code: sols = SystemModelParametricSimulate[[image], "capacitor1.v", {"sineVoltage1.f"}]

周波数パラメータのさまざまな値について解を計算する：

Wolfram Language code: fns = Table[sols[hz], {hz, 1, 5}]

解を時間上にプロットする：

Wolfram Language code: Table[Plot[fn[t], {t, 0, 10}], {fn, fns}]

おもしろい例題  (1)

Rabinovich–Fabrikant方程式における 軸と 軸についての感度境界を示す：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"x", "y", "z"}, 100, {"a", "g"}, <|"ParameterValues" -> {"a" -> 0.01, "g" -> 0.05}|>];
Wolfram Language code: {x, y, z, dx, dy, dz} = sim[{"x", "y", "z", {"x", "a"}, {"y", "a"}, {"z", "a"}}, t];
Wolfram Language code: d = 0.04; ParametricPlot[{x + v d dx, y + v d dy}, {v, 0, 1}, {t, 0, 19}, PlotPoints -> 40, Axes -> None, ColorFunction -> ColorData["HypsometricTints"], Mesh -> False]

感度限界を三次元で示す：

Wolfram Language code: Graphics3D[Tube@@Transpose@Table[{{x, y, z}, 0.0005Norm[{dx, dy, dz}]}, {t, 10, 55, 0.05}], Axes -> True]
Wolfram Research (2018), SystemModelSimulateSensitivity, Wolfram言語関数， https://reference.wolfram.com/language/ref/SystemModelSimulateSensitivity.html.

テキスト

Wolfram Research (2018), SystemModelSimulateSensitivity, Wolfram言語関数， https://reference.wolfram.com/language/ref/SystemModelSimulateSensitivity.html.

CMS

Wolfram Language. 2018. "SystemModelSimulateSensitivity." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/SystemModelSimulateSensitivity.html.

APA

Wolfram Language. (2018). SystemModelSimulateSensitivity. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SystemModelSimulateSensitivity.html

BibTeX

@misc{reference.wolfram_2026_systemmodelsimulatesensitivity, author="Wolfram Research", title="{SystemModelSimulateSensitivity}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/SystemModelSimulateSensitivity.html}", note=[Accessed: 03-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_systemmodelsimulatesensitivity, organization={Wolfram Research}, title={SystemModelSimulateSensitivity}, year={2018}, url={https://reference.wolfram.com/language/ref/SystemModelSimulateSensitivity.html}, note=[Accessed: 03-August-2026]}