WOLFRAM

Wolfram 语言与系统参考资料中心

SystemModelSimulateSensitivity[model,{p1,p2,…}]

仿真 model 及其在实验条件设置下对参数 pi 的敏感度.

SystemModelSimulateSensitivity[model,tmax,{p1,p2,…}]

从 0 到 tmax 进行仿真.

SystemModelSimulateSensitivity[model,{tmin,tmax},{p1,p2,…}]

从 tmin 到 tmax 进行仿真.

SystemModelSimulateSensitivity[model,vars,{tmin,tmax},{p1,p2,…}]

只保存变量 vars 的仿真数据.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
模型  
仿真时间  
敏感度结果  
变量、参数和输入  
存储结果  
推广和延伸  
选项  
InterpolationOrder  
Method  
ProgressReporting  
应用  
属性和关系  
巧妙范例  
参见
相关指南
相关链接
历史
按以下格式引用：

SystemModelSimulateSensitivity

SystemModelSimulateSensitivity[model,{p1,p2,…}]

仿真 model 及其在实验条件设置下对参数 pi 的敏感度.

SystemModelSimulateSensitivity[model,tmax,{p1,p2,…}]

从 0 到 tmax 进行仿真.

SystemModelSimulateSensitivity[model,{tmin,tmax},{p1,p2,…}]

从 tmin 到 tmax 进行仿真.

SystemModelSimulateSensitivity[model,vars,{tmin,tmax},{p1,p2,…}]

只保存变量 vars 的仿真数据.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (3)

使用实验中设置的时间间隔研究参数的敏感度：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"a"}]

提取敏感度的名称并绘制：

Wolfram Language code: sim["SensitivityNames"]
Wolfram Language code: SystemModelPlot[sim, {{"y", "a"}, {"z", "a"}}]

显示信号对参数相对变化的敏感度：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"y", "z"}, 5, {"a"}]

在 a 改变 10% 的情况下绘制 y 和 z 的变化范围：

Wolfram Language code: SystemModelPlot[sim, {{"y", "a", 0.1}, {"z", "a", 0.1}}]

用模型的框图表示作为输入：

Wolfram Language code: SystemModel["IntroductoryExamples.ComponentBased.ElectricCircuit"]

复制并粘贴上述输出：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"capacitor1.v"}, 5, {"sineVoltage1.f"}]

范围  (17)

模型  (3)

仿真 NonlinearStateSpaceModel 时对变量和敏感度进行计算：

Wolfram Language code: sim = SystemModelSimulateSensitivity[NonlinearStateSpaceModel[{{Cos[x] + 4*a*Sin[x/2]}, {x + Sin[x]}}, {x}, {}, {Automatic}, Automatic, SamplingPeriod -> None], 10, {a}, <|"ParameterValues" -> {a -> 1}|>]

提取敏感度的名称并绘制：

Wolfram Language code: sim["SensitivityNames"]
Wolfram Language code: SystemModelPlot[sim, {{x, a}, {Subscript[, 1], a}}, PlotRange -> All]

绘制 a 变化 40% 时状态的变化范围：

Wolfram Language code: SystemModelPlot[sim, {{x, a, 0.4}}, PlotRange -> All]

计算 AffineStateSpaceModel 参数扫描的敏感度：

Wolfram Language code: sims = SystemModelSimulateSensitivity[AffineStateSpaceModel[{{Cos[x2], (-1 - a)*x2 + Cos[x1^2]}, {{0}, {1}}, {x2}, {{0}}}, {x1, x2}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None], 5, {a}, <|"ParameterValues" -> {a -> {1, 10}}|>]

绘制 a 变化 50% 时状态的变化范围：

Wolfram Language code: SystemModelPlot[sims, {{x2, a, 0.5}}]

计算 DiscreteInputOutputModel 的敏感度：

Wolfram Language code: diom = DiscreteInputOutputModel[{u[0] + y[-1] + a y[-2], u[1] + u[0] + u[-1]}, {{u, {-2, -1, 1}}}, {{y, {-1, -1, -1}}}]
Wolfram Language code: sim = SystemModelSimulateSensitivity[diom, {a}, <|"Inputs" -> {1 -> Range[-20, 20]}, "ParameterValues" -> {a -> 1}|>]

绘制 a 变化 5% 时输出的变化范围：

Wolfram Language code: SystemModelPlot[sim, {{y, a, 0.05}}]

仿真时间  (3)

用模型的设置进行仿真：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"a"}]
Wolfram Language code: sim["SimulationInterval"]

从时间点 0 到 5 进行仿真：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 5, {"a"}]
Wolfram Language code: sim["SimulationInterval"]

设置明确的时间间隔，进行仿真：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {2, 10}, {"a"}]
Wolfram Language code: sim["SimulationInterval"]

敏感度结果  (6)

研究参数的敏感度：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 50, {"a"}]
Wolfram Language code: sim["SensitivityNames"]
Wolfram Language code: SystemModelPlot[sim, {{"y", "a"}}]

仿真对参数 a 的敏感度：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 5, {"a"}];

获取敏感度名称：

Wolfram Language code: sim["SensitivityNames"]

获取 a 变化时 y 的敏感度：

Wolfram Language code: {ySensA} = sim[{{"y", "a"}}]

研究一个参数的敏感度：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 5, {"sineVoltage1.f"}];
Wolfram Language code: sim["SensitivityNames"]//Short

绘制其中一个敏感度：

Wolfram Language code: SystemModelPlot[sim, {{"capacitor1.v", "sineVoltage1.f"}}]

显示信号对参数 a 的敏感度：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 50, {"a"}]

获取敏感度名称：

Wolfram Language code: sim["SensitivityNames"]

获取 a 变化时 y 的敏感度及 y 的标称轨迹：

Wolfram Language code: {ySensA, y} = sim[{{"y", "a"}, "y"}, t]

绘制 a 未改变时 y 的曲线，以及参数 a 增加 0.05 倍时的曲线：

Wolfram Language code: Plot[{Tooltip[y, "Nominal"], Tooltip[y + 0.05 ySensA, "Perturbed"]}, {t, 0, 50}]

显示信号对参数发生相对变化的敏感度：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 5, {"a"}];

获取敏感度名称：

Wolfram Language code: sim["SensitivityNames"]

获取 a 变化时 y 和 z 的敏感度及标称轨迹和值：

Wolfram Language code: {ySensA, zSensA, y, z, a0} = sim[{{"y", "a"}, {"z", "a"}, "y", "z", "a"}, t];

绘制当 a 改变 10% 的敏感度时 y 和 z 的变化范围：

Wolfram Language code: {dY, dZ} = {a0 0.1ySensA, a0 0.1zSensA};
Wolfram Language code: Plot[{Tooltip[y, "y"], y + dY, y - dY, Tooltip[z, "z"], z + dZ, z - dZ}, {t, 0, 5}, Filling -> {2 -> {3}, 5 -> {6}}]

显示信号对参数 a 的绝对变化的敏感度：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 50, {"a"}]

获取 a 变化时 y 的敏感度和 y 的轨迹：

Wolfram Language code: {ySensA, y} = sim[{{"y", "a"}, "y"}, t];

当参数 a 的绝对值变化 0.1 倍时计算 y 的变化：

Wolfram Language code: dY = 0.1 ySensA;

绘制参数 a 改变 ±0.1 倍时 y 的变化：

Wolfram Language code: Plot[{Tooltip[y, "y"], y + dY, y - dY}, {t, 0, 50}, Filling -> {2 -> {3}}]

变量、参数和输入  (3)

改变仿真的初值：

Wolfram Language code: Subscript[sim, 1] = SystemModelSimulateSensitivity[[image], 50, {"a"}];
Wolfram Language code: Subscript[sim, 2] = SystemModelSimulateSensitivity[[image], 50, {"a"}, <|"InitialValues" -> {"y" -> 2.85}|>];

比较曲线的变化：

Wolfram Language code: SystemModelPlot[{Subscript[sim, 1], Subscript[sim, 2]}, {{"y", "a"}}]

改变仿真的参数值：

Wolfram Language code: Subscript[sim, 1] = SystemModelSimulateSensitivity[[image], 50, {"a"}];
Wolfram Language code: Subscript[sim, 2] = SystemModelSimulateSensitivity[[image], 50, {"a"}, <|"ParameterValues" -> {"a" -> 2.95}|>];

比较两条曲线：

Wolfram Language code: SystemModelPlot[{Subscript[sim, 1], Subscript[sim, 2]}, {{"y", "a"}}]

为变量提供输入函数并研究输出对增益参数的敏感度：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 10, {"gain.k"}, <|"Inputs" -> {"u" -> Sin}|>]

绘制输出对增益参数的敏感度：

Wolfram Language code: SystemModelPlot[sim, {{"integrator.y", "gain.k", 0.1}}]

存储结果  (2)

只保存选择的变量：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"y", "a"}, {"a"}]

只有给定的变量和参数被保存起来：

Wolfram Language code: {sim["VariableNames"], sim["ParameterNames"]}

只保存选定的变量，并在给定的仿真区间内进行仿真：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"TR", "lambda"}, {0, 50}, {"lambda"}]

绘制 lambda 变化 20% 时 TR 的变化界限：

Wolfram Language code: SystemModelPlot[sim, {{"TR", "lambda", 0.2}}]

推广和延伸  (1)

调试消息被收集在消息组 "WSMDebug" 中：

Wolfram Language code: Hold["WSMDebug"] /. $MessageGroups

开始发送初始化调试消息：

Wolfram Language code: On[SystemModelSimulateSensitivity::dinit]
Wolfram Language code: SystemModelSimulateSensitivity["DocumentationExamples.Basic.OneParameter", {0, 1}, {"a"}, Method -> {"Sensitivity" -> "WSM"}]

关闭 "WSMDebug" 调试消息：

Wolfram Language code: Off["WSMDebug"]

选项  (4)

InterpolationOrder  (1)

对插值阶数为 1 和 3、有 3 个插值点的情况进行仿真：

Wolfram Language code: {Subscript[sim, 1], Subscript[sim, 2]} = Table[SystemModelSimulateSensitivity[[image], 7, {"a"}, Method -> {Automatic, "InterpolationPoints" -> 3}, InterpolationOrder -> intOrder], {intOrder, {1, 3}}];

显示敏感度变量：

Wolfram Language code: SystemModelPlot[{Subscript[sim, 1], Subscript[sim, 2]}, {{"y", "a"}}]

Method  (2)

采用 Method{"Sensitivity""WSM"} 时，对于SystemModel，会使用 CVODES 求解器计算状态变量的灵敏度：

Wolfram Language code: simWSM = SystemModelSimulateSensitivity[[image], 5, {"a"}, Method -> {"Sensitivity" -> "WSM"}]
Wolfram Language code: simWSM["SensitivityNames"]

使用自定义数量的插值点仿真并计算灵敏度：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 5, {"a"}]
Wolfram Language code: sim["SensitivityNames"]

仿真一个 SystemModel，使用模型设置的插值点数量计算灵敏度：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 5, {"a"}]; SystemModelPlot[sim, {{"y", "a"}, {"z", "a"}, {Derivative[1]["z"], "a"}}]

用自定义数量的插值点进行仿真并计算灵敏度：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 5, {"a"}, Method -> {"InterpolationPoints" -> 5}]; SystemModelPlot[sim, {{"y", "a"}, {"z", "a"}, {Derivative[1]["z"], "a"}}]

用自定义数量的插值点对状态变量进行仿真并计算灵敏度：

Wolfram Language code: simWSM = SystemModelSimulateSensitivity[[image], 5, {"a"}, Method -> {"Sensitivity" -> "WSM", "InterpolationPoints" -> 5}]; SystemModelPlot[simWSM, {{"y", "a"}, {"z", "a"}}]

ProgressReporting  (1)

用 ProgressReporting 控制进度报告：

Wolfram Language code: SystemModelSimulateSensitivity[[image], {"a"}, ProgressReporting -> False]

应用  (5)

研究一个模型的敏感度：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"y"}, 40, {"a"}];
Wolfram Language code: {y, ysensa} = sim[{"y", {"y", "a"}}, t];

获取参数值：

Wolfram Language code: a0 = First[sim[{"a"}]]

找到改变参数时峰值的偏移量：

Wolfram Language code: {peakVal, {peakTime}} = NMaximize[{0.05 a0 ysensa, 0 < t < 40}, {t}]

显示 5% 的敏感度范围和峰值偏移时间：

Wolfram Language code: Plot[Evaluate[{y, y + 0.05 a0 ysensa, y - 0.05 a0 ysensa}], {t, 0, 40}, Filling -> {2 -> {3}}, GridLines -> {{peakTime[[2]]}, None}]

找出哪个变量对频率参数最敏感：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"integrator1.y", "integrator2.y", "integrator3.y"}, 1, {"sine.f"}];

10% 敏感度范围显示 "integrator3.y" 对频率参数最敏感：

Wolfram Language code: SystemModelPlot[sim, Table[{v, "sine.f", 0.1}, {v, {"integrator1.y", "integrator2.y", "integrator3.y"}}]]

对滚动的车轮进行仿真：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"wheel1.x", "wheel1.y"}, 10, {"wheel1.radius", "wheel1.m"}]

选择车轮的位置及其对不同参数的敏感度：

Wolfram Language code: {x, y, xsensrad, ysensrad, xsensmass, ysensmass} = sim[{"wheel1.x", "wheel1.y", {"wheel1.x", "wheel1.radius"}, {"wheel1.y", "wheel1.radius"}, {"wheel1.x", "wheel1.m"}, {"wheel1.y", "wheel1.m"}}, t];
Wolfram Language code: {r0, m0} = sim[{"wheel1.radius", "wheel1.m"}]

分别显示车轮半径和质量变化 4％ 时车轮的轨迹：

Wolfram Language code: d = 0.04; ParametricPlot[{{x, y}, {x + v d #[[1]], y + v d #[[2]]}}, {v, -1, 1}, {t, 0, 10}, PlotPoints -> 40, Mesh -> None, Axes -> None, PlotLabel -> #[[3]], FrameTicks -> {{Automatic, None}, {None, None}}]& /@ {{xsensrad r0, ysensrad r0, "Wheel radius"}, {xsensmass m0, ysensmass m0, "Wheel mass"}}

通过与测量数据进行比较来校准模型中的参数：

Wolfram Language code: model = \!\(\*GraphicsBox[«8»]\);
Wolfram Language code: data = Import["ExampleData/inertiaTestData.dat"];
Wolfram Language code: {p1, p2, var} = {"Resistor1.R", "SpringDamper1.d", "Inertia2.w"};

用 SystemModelSimulateSensitivity 获取梯度：

Wolfram Language code: g[p_ ? NumericQ, q_ ? NumericQ] := g[p, q] = Quiet[AssociationThread[{var, {var, p1}, {var, p2}}, SystemModelSimulateSensitivity[model, {var}, 40, {p1, p2}, <|"ParameterValues" -> {p1 -> p, p2 -> q}|>, ProgressReporting -> False][{var, {var, p1}, {var, p2}}]], {SystemModelSimulateSensitivity::gen}]

绘制参数取特定值时的仿真结果：

Wolfram Language code: Plot[g[0.1, 0.25][var][t], {t, 0, 40}]

用测试数据进行参数拟合：

Wolfram Language code: AbsoluteTiming[FindFit[data, g[p, q][var][t], {{p, 0.1}, {q, 0.25}}, t, Gradient -> "FiniteDifference"]]

不使用梯度的情况下将花费更多的时间：

Wolfram Language code: AbsoluteTiming[pars = FindFit[data, g[p, q][var][t], {{p, 0.1}, {q, 0.25}}, t, Gradient :> Comap[Lookup[g[p, q], {{var, p1}, {var, p2}}], t]]]

用拟合参数进行仿真：

Wolfram Language code: sim = SystemModelSimulate[model, {0, 40}, <|"ParameterValues" -> ({p1 -> p, p2 -> q} /. pars)|>];

同时显示测试数据和校准过的模型：

Wolfram Language code: Show[SystemModelPlot[sim, {var}, PlotStyle -> Orange], ListPlot[data]]

绘制解及其敏感度范围：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 30, {"a"}]
Wolfram Language code: sim["SensitivityNames"]
Wolfram Language code: {y, ysensa} = sim[{"y", {"y", "a"} }, t];

获取参数的标称值：

Wolfram Language code: a0 = First[sim[{"a"}]]

显示 5% 敏感度范围：

Wolfram Language code: dY = 0.05 * a0 ysensa;
Wolfram Language code: Plot[Evaluate[{y, y + dY, y - dY}], {t, 0, 30}, Filling -> {2 -> {3}}]

将最大变化范围设为 5%，进行仿真：

Wolfram Language code: simv = SystemModelSimulate[[image], 30, <|"ParameterValues" -> {"a" -> a0 Range[0.95, 1.05, 0.02]}|>];

获取轨迹：

Wolfram Language code: yV = Table[sd[{"y"}, t][[1]], {sd, simv}];

显示大部分轨迹被包含在近似的灵敏度范围内：

Wolfram Language code: Plot[Evaluate[{y, y + dY, y - dY, yV}], {t, 0, 30}, Filling -> {2 -> {3}}]

属性和关系  (4)

将敏感度仿真与相应的微分方程的敏感度进行比较：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 50, {"a"}];
Wolfram Language code: SystemModelPlot[sim, {"y", {"y", "a"}}]
Wolfram Language code: y = DSolve[{f'[t] + Sin[a]f[t] == 0, f[0] == b}, f[t], t][[1, 1, 2]];
Wolfram Language code: ySensA = D[y, a]
Wolfram Language code: Plot[Evaluate[{y, ySensA} /. {a -> 3, b -> 1}], {t, 0, 50}, PlotRange -> All]

绘制参数发生相对变化时的范围：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], 5, {"a"}];

获取 a 变化时 y 的敏感度及 y 和 a 的值：

Wolfram Language code: {ySensA, y, a0} = sim[{{"y", "a"}, "y", "a"}, t];

绘制当 a 改变 10% 的敏感度时 y 的变化范围：

Wolfram Language code: dY = a0 0.1ySensA;
Wolfram Language code: Plot[{Tooltip[y, "y"], y + dY, y - dY}, {t, 0, 5}, Filling -> {2 -> {3}}, AxesLabel -> {"t", None}]

使用 SystemModelPlot：

Wolfram Language code: SystemModelPlot[sim, {{"y", "a", 0.1}}]

敏感度对参数的小变化也有效：

Wolfram Language code: {par, var} = {"sineVoltage1.f", "capacitor1.v"};

获取对参数的敏感度：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {var}, 5, {par}];

将参数的变化范围设为 ，进行仿真：

Wolfram Language code: {p0} = sim[{par}];
Wolfram Language code: sim2 = SystemModelSimulate[[image], {var}, 5, <|"ParameterValues" -> {par -> {0.9p0, 1.1p0}}|>];

在图中进行比较，10% 的变化给出的轨迹位于计算所得界限范围之外：

Wolfram Language code: Show[SystemModelPlot[sim, {{var, par, 0.1}}, {2.5, 3.5}], SystemModelPlot[sim2, {var}]]

将 SystemModelParametricSimulate 应用于一个可对不同的值进行计算的函数：

Wolfram Language code: sols = SystemModelParametricSimulate[[image], "capacitor1.v", {"sineVoltage1.f"}]

针对不同的频率参数值计算解：

Wolfram Language code: fns = Table[sols[hz], {hz, 1, 5}]

绘制解随时间变化的情况：

Wolfram Language code: Table[Plot[fn[t], {t, 0, 10}], {fn, fns}]

巧妙范例  (1)

显示 Rabinovich–Fabrikant 方程中 和 轴的敏感度范围：

Wolfram Language code: sim = SystemModelSimulateSensitivity[[image], {"x", "y", "z"}, 100, {"a", "g"}, <|"ParameterValues" -> {"a" -> 0.01, "g" -> 0.05}|>];
Wolfram Language code: {x, y, z, dx, dy, dz} = sim[{"x", "y", "z", {"x", "a"}, {"y", "a"}, {"z", "a"}}, t];
Wolfram Language code: d = 0.04; ParametricPlot[{x + v d dx, y + v d dy}, {v, 0, 1}, {t, 0, 19}, PlotPoints -> 40, Axes -> None, ColorFunction -> ColorData["HypsometricTints"], Mesh -> False]

用三维图形显示敏感度范围：

Wolfram Language code: Graphics3D[Tube@@Transpose@Table[{{x, y, z}, 0.0005Norm[{dx, dy, dz}]}, {t, 10, 55, 0.05}], Axes -> True]
Wolfram Research (2018)，SystemModelSimulateSensitivity，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SystemModelSimulateSensitivity.html.

文本

Wolfram Research (2018)，SystemModelSimulateSensitivity，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SystemModelSimulateSensitivity.html.

CMS

Wolfram 语言. 2018. "SystemModelSimulateSensitivity." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/SystemModelSimulateSensitivity.html.

APA

Wolfram 语言. (2018). SystemModelSimulateSensitivity. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/SystemModelSimulateSensitivity.html 年

BibTeX

@misc{reference.wolfram_2026_systemmodelsimulatesensitivity, author="Wolfram Research", title="{SystemModelSimulateSensitivity}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/SystemModelSimulateSensitivity.html}", note=[Accessed: 07-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_systemmodelsimulatesensitivity, organization={Wolfram Research}, title={SystemModelSimulateSensitivity}, year={2018}, url={https://reference.wolfram.com/language/ref/SystemModelSimulateSensitivity.html}, note=[Accessed: 07-November-2026]}