TimeSeriesMap[f,tes]
各時系列または事象系列のデータ tes の各ペア{t,x}に対して{t,f[x]}という時刻と値のペアを持つ新しい時系列を作成する.
TimeSeriesMap[{ncom1f1,ncom2f2,…},tes]
同一のタイムスタンプと成分 ncomiを持つ新しい時系列を構成する.各成分は tes の値に関数 fiを適用することによって得られる.
TimeSeriesMap
TimeSeriesMap[f,tes]
各時系列または事象系列のデータ tes の各ペア{t,x}に対して{t,f[x]}という時刻と値のペアを持つ新しい時系列を作成する.
TimeSeriesMap[{ncom1f1,ncom2f2,…},tes]
同一のタイムスタンプと成分 ncomiを持つ新しい時系列を構成する.各成分は tes の値に関数 fiを適用することによって得られる.
詳細
- TimeSeriesMapは,通常既存の成分から新たな成分を導出するために用いられる.例えば2つの成分を除算することによって率を得る場合等である.
- 次は,時系列データまたは事象系列データ tes の可能な形式である.
-
TimeSeries[…] 連続的で時間順に並んだサンプリングデータ EventSeries[…] 値を伴う時間的事象の集合 TemporalData[…] 時間と値のペアから構成される1本以上のパス {{t1,x1},{t2,x2},…} 時間と値のペアのリスト {x1,x2,…} 0から開始する暗黙の整数時間を伴う値のリスト - f[…,#com,…]&という構文で,時系列 tes の成分"com"をマッピングされた関数 f の引数として使うことができる. »
- 名前付きの成分を持たない単純な時系列では,f[…,#,…]&または f[…,#Value,…]&を使って値にアクセスできる. »
- 任意の時系列では,#Timestampを使ってタイムスタンプをマッピングされた関数 f の引数として渡すことができる.
- TimeSeriesMap[cspec,tes]は,事実上,Head[tes][ConstructColumns[Tabular[tes],cspec],{ tes["Times"]}]に等しい. »
- TimeSeriesMapは,複数の経路を有するTemporalDataについては,経路ごとに縫い込まれる.
例題
すべて開く すべて閉じる例 (2)
TimeSeries[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}, {1}]TimeSeriesMap[f, %]%//Normal多成分時系列において,関数引数として使用する値成分を指定する:
TimeSeries[{"a" -> {11, 17, 13}, "b" -> {"cat", "dog", "fox"}, "c" -> {.1, .5, .9}}, {0}]TimeSeriesMap[#a + #c&, %]%//Tabularスコープ (16)
基本的な用法 (6)
TimeSeries[{23, 34, 56}, {0}]TimeSeriesMap[f, %]//NormalTimeSeries[Array[x, {2, 3}], {0}]TimeSeriesMap[f, %]//Normalts = TimeSeries[{23, 34, 56}, {0}, ComponentKeys -> {"a"}]TimeSeriesMap[f, ts]//TabularTimeSeriesMap[f[#a]&, ts]//Tabularts = TimeSeries[{"a" -> {11, 17, 13}, "b" -> {"cat", "dog", "fox"}, "c" -> {.1, .5, .9}}, {0}]TimeSeriesMap[f[#]&, ts]//NormalTimeSeriesMap[f[#Timestamp]&, ts]//NormalTimeSeriesMap[f[#[[3]]]&, ts]//NormalTimeSeriesMap[f[#c]&, ts]//NormalTimeSeriesMap[f[#c, #b]&, ts]//NormalToTabular[<|"name" -> RandomWord[3], "integers" -> RandomInteger[10, {3, 2}], "reals" -> RandomReal[1, {3, 4}]|>, "Columns"]
| |
ts = TimeSeries[%]TimeSeriesMap[f, ts]//NormalTimeSeriesMap[f[#integers[[1]], #reals[[ ;; 2]]]&, ts]//TabularTimeSeriesMapを使ってベクトル値時系列の各値のノルムを求める:
α = {{.2, .1}, {-.3, .2}};
β = {{.2, .5}, {-.2, .9}};
Σ = {{1, 0}, {0, .3}};
sample = RandomFunction[ARMAProcess[{α}, {β}, Σ], {1, 10 ^ 2}];norms = TimeSeriesMap[Norm, sample]ListPlot[norms, Filling -> 0]データコンテナ (7)
v = RandomInteger[{-10, 10}, 10]TimeSeriesMap[f, v]時点と値のペアのリストについて,極値をMissingに設定する:
data = {{"2005", 1}, {"2006", -1}, {"2007", 3}, {"2008", 6}, {"2009", -2}, {"2010", 4}, {"2011", 5}, {"2012", 9999}, {"2013", 4}, {"2014", 2}};clip = TimeSeriesMap[If[# > 10, Missing[], #]&, data]DateListPlot[clip, GridLines -> {True, False}]TimeSeriesの値を2倍にする:
ts = TimeSeries[TimeEventSeries`TimestampData[Association["UniformlySpacedQ" -> True, "Count" -> 100,
"Endpoints" -> TabularColumn[Association["Data" -> {{0, 99}, {}, None},
"ElementType" -> "Integer64"]], "MinimumTimeIncrement" -> 1, "Caller ... 8, -5.864937981765857,
-6.27785271209235, -5.841962111797332}, {}, None}, "ElementType" -> "Real64"]],
Association["ResamplingMethod" -> {"Interpolation", InterpolationOrder -> 1},
"TimeWindow" -> Automatic, "MetaInformation" -> None]];TimeSeriesMap[2 * #&, ts]2 * tsListLinePlot[{ts, %}]2つの経路があるTemporalDataを構築する:
path1 = {{0, 12.1}, {1, 13.2}, {2, 15.0}};
path2 = {{.3, 12.3}, {1.1, 3.4}, {1.7, 4.5}};td = TemporalData[{path1, path2}]TimeSeriesMapは各経路に独立に作用する:
TimeSeriesMap[f, td]//NormalTimeSeriesMap[Round, td]//NormalTemporalData内の経路をシフトする:
td = TemporalData[Automatic, {{{0.8046670011447656, 0.6424816687160839, -0.3687580957637058,
0.4628481191016882, 0.6513760827865932, 0.19165543283623954, 0.30464311463325267,
-0.9822712429552825, -1.0167795954508363, -1.179808617121842, 0.7468 ... -15.95818965999289, -15.432785308593996, -16.456943797427243,
-17.39684387275391, -18.043191111487896, -17.87617876899845, -17.2137849514934,
-17.84832779928046}}, {{1, 100, 1}}, 3, {"Continuous", 3}, {"Discrete", 1}, 1, {}}, False, 10.];p1 = ListLinePlot[td, PlotStyle -> RGBColor[0.368417, 0.506779, 0.709798]]TimeSeriesMap[# + 20&, td]td + 20Show[ListLinePlot[%, PlotStyle -> RGBColor[0.880722, 0.611041, 0.142051]], p1, PlotRange -> All]彩色された円板を交互に配置することで,EventSeries内の事象を表す:
es = EventSeries[RandomChoice[{1, 5} -> {1, 0}, 50]]ListPlot[es, Filling -> Axis]rg[c_, e_] := If[e == 0, c, RGBColor[0, c[[3]], c[[2]]]]c = RGBColor[0, .5, 1];i = 0;
disks = TimeSeriesMap[{c = rg[c, #], Disk[{++i / 15, 0}]}&, es]Graphics[Normal[disks["Values"]]]Quantityを数量を含む時系列に加える:
ts = TimeSeries[Quantity[{0, 16, 9, 3, 7, 2, 17, 10, 6, 12}, "Meters"]];res = Quantity[10, "Meters"] + tsres//NormalListLinePlot[{ts, res}, PlotLegends -> {"ts", "shifted ts"}, Filling -> Axis, AxesLabel -> Automatic]関数の引数としての成分キー (3)
ts = TimeSeries[{"a" -> {11, 17, 13}, "b" -> {"cat", "dog", "fox"}, "c" -> {.1, .5, .9}}, {0}]TimeSeriesMap[Function[f[#c]], ts]TimeSeriesMap["new" -> Function[f[#c]], ts]TimeSeriesMap[{"a", "b", "new" -> Function[f[#c]], "c"}, ts]#Timestampを使って時系列のタイムスタンプにマッピングする:
ts = TimeSeries[{"a" -> {11, 17, 13}, "b" -> {"cat", "dog", "fox"}, "c" -> {.1, .5, .9}}, {Today}]TimeSeriesMap[fun[#Timestamp]&, ts]//Normalts = TimeSeries[{.34, .56, .19}, {0}]TimeSeriesMap[f, ts]TimeSeriesMap[f[#Value]&, ts]% === %%TimeSeriesMap[f[#Value] + g[#Timestamp]&, ts]アプリケーション (9)
基本的なアプリケーション (2)
ローマ時代の地理多角形の時系列を使って面積の時系列を計算する:
ts = EntityValue[Entity["HistoricalCountry", "RomanEmpire"], Dated["Polygon", All]]TimeSeriesMap[GeoArea, ts]DateListPlot[%, TargetUnits -> "RomanCommonLeugae" ^ 2]フィンランドからスウェーデンまでの鉄道線路の長さの比を計算する:
[image]DateListPlot[data, PlotLegends -> Rest[ColumnKeys[data]]]TimeSeriesMap[#Finland / #Sweden&, data]DateListPlot[%, PlotLabel -> "Finland/Sweden"]自然現象 (3)
ts = TimeSeries[TimeEventSeries`TimestampData[Association["UniformlySpacedQ" -> True, "Count" -> 1153,
"Endpoints" -> TabularColumn[Association[
"Data" -> {2, {{{1748736000000, 1749081600000}, {}, None}}, None},
"ElementType" -> TypeSpe ... arInterpolation",
"LongFlux" -> "LinearInterpolation"], "TimeWindow" ->
DateInterval[{{{2025, 6, 1, 0, 0, 0.}, {2025, 6, 5, 0, 0, 0.}}}, "Instant", "Gregorian",
"-05:00"], "MetaInformation" -> Association["Name" -> "SolarXRayFlux"]]];ColumnKeys[ts]ListLogPlot[ts, Joined -> True]TimeSeriesMap[Function[#LongFlux / #ShortFlux], ts]ListLinePlot[%, PlotRange -> All]2014年5月におけるイリノイ州シャンペーンの風速の時系列:
data = WeatherData[{"Champaign", "Illinois"}, "WindSpeed", {2014, 5}]wd = TransformMissing[data, "Interpolation"]TimeSeriesMapを使って1.5MWの風力タービンの出力についての時系列を構築する:
if = InterpolatingFunction[{{0., 30.}}, {5, 7, 0, {61}, {4}, 0, 0, 0, 0, Automatic, {}, {}, False},
{{0., 0.5, 1., 1.5, 2., 2.5, 3., 3.5, 4., 4.5, 5., 5.5, 6., 6.5, 7., 7.5, 8., 8.5, 9., 9.5, 10.,
10.5, 11., 11.5, 12., 12.5, 13., 13.5, 14., 14.5, ... 1477., 1494., 1500., 1500., 1500., 1500., 1500., 1500., 1500., 1500., 1500., 1500., 1500.,
1500., 1500., 1500., 1500., 1500., 1500., 1500., 1500., 1500., 1500., 1500., 1500., 1500., 0.,
0., 0., 0., 0., 0., 0., 0., 0., 0.}}, {Automatic}];
power[s_] := Quantity[if[QuantityMagnitude[s, "m/s"]], "Kilowatts"];output = TimeSeriesMap[power, wd]ma = MovingMap[Mean, output, {Quantity[1, "Day"]}];DateListPlot[ma, PlotTheme -> {"Detailed", "ThinLines"}, FrameLabel -> Automatic, ImageSize -> 300, Filling -> Bottom]FindAstroEvent["MarchEquinox", DateRange[DateObject@{1800}, {2599}, "Year"]]3月におけるそれらの日付を,小数の端数日を含む実数として求める:
es = TimeSeriesMap[DateValue[#, "DayExact"]&, %]MinMax[es]TimeObject[24FractionalPart[First[%]]]年ごとにどのようにずれていくか,また400年周期においてはうるう日の扱いがどのように異なるう必要があるかを示す:
DateListPlot[es, Joined -> False, FrameTicks -> {{{{19, "Mar 19 00:00"}, {19.5, "Mar 19 12:00"}, {20, "Mar 20 00:00"}, {20.5, "Mar 20 12:00"}, {21, "Mar 21 00:00"}, {21.5, "Mar 21 12:00"}}, None}, {Automatic, None}}]金融 (1)
prices = TemporalData[TimeSeries, {{{26.97, 26.65, 26.55, 27.52, 27.54, 27.41, 26.42, 26.34, 26.68, 28.53,
28.03, 27.9, 27.69, 28.1, 28.73, 28.39, 29.17, 30.08, 30.78, 31.28, 30.91, 30.8, 31.73, 32.,
31.56, 31.96, 33.04, 34.01, 33.56, 35.79, 36.21 ... 9.85, 39.93, 39.98}},
{TemporalData`DateSpecification[{2013, 1, 2, 0, 0, 0.}, {2013, 11, 27, 0, 0, 0}, {1, "Week"}]},
1, {"Continuous", 1}, {"Discrete", 1}, 1,
{ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, True, 10.1];
currentMaximumPrices = Block[{currMax = prices["FirstValue"]}, TimeSeriesMap[(currMax = Max[currMax, #])&, prices]]DateListPlot[{prices, currentMaximumPrices}, PlotLegends -> {"Prices", "CurrentMaximumPrices"}]経済 (2)
労働力人口および失業率のデータを用いて,フランスにおける失業者数を求める:
data = Block[...]Tabular[data]fun[g_] := Function[#[ExtendedKey["LaborForce", g]] * Normal[#[ExtendedKey["UnemploymentRate", g]]]]unemployment = TimeSeriesMap[{"FemaleUnemployed" -> fun["Female"], "MaleUnemployed" -> fun["Male"]}, data]DateListPlot[unemployment, PlotLegends -> {"Female", "Male"}]total = TimeSeriesMap[Total, unemployment]DateListPlot[{unemployment, total}, PlotLegends -> LineLegend[...]]ts = TimeSeries[TimeEventSeries`TimestampData[Association["UniformlySpacedQ" -> False,
"Timestamps" -> TabularColumn[Association[
"Data" -> {163, {{NumericArray[{14245, 14276, 14304, 14335, 14365, 14396, 14426, 14457,
14488, 14518, ... ",
"Other" -> "LinearInterpolation"], "TimeWindow" ->
DateInterval[{{{2009, 1, 1, 0, 0, 0.}, {2022, 7, 1, 0, 0, 0.}}}, "Day", "Gregorian", None, "UT",
Automatic], "MetaInformation" -> Association["Name" -> "WebBrowsersMarketShare"]]];ts["FirstValue"]//Normal時間の経過に渡って最も人気のあるWebブラウザを3つ取り上げる:
TimeSeriesMap[Keys@TakeLargest[#, 3]&, ts]DateListPlot[%, ScalingFunctions -> NominalScale[Automatic], PlotLegends -> {"first", "second", "third"}]ランダム過程 (1)
TimeSeriesMapを用いて,ARProcessに対する共分散行列の行列式を計算する:
cov = CovarianceFunction[ARProcess[{{{1 / 3, 1 / 2}, {-1 / 4, 1 / 2}}}, {{1, 1 / 3}, {1 / 3, 1}}], {10}];det = TimeSeriesMap[Det, cov]det["Values"]//Normal%//N特性と関係 (5)
TimeSeriesMap[f[#Timestamp]&, {x, y, z}]//Normalts = TimeSeries[{7, 9, 16}, {1}];TimeSeriesMap[# + c&, ts]["Path"](ts + c)["Path"]単純な時系列の引数の場合,マップされた関数における#は値を表す:
simpleTS = TimeSeries[{3.5, 6.7, 8.4}, {11}]TimeSeriesMap[f[#]&, simpleTS]//Normal単純な時系列を,名前付き成分"a"を持つ新しい時系列に変換する:
compTS = RenameColumns[simpleTS, "Value" -> "a"]TimeSeriesMap[f[#]&, compTS]//NormalTimeSeriesMap[f[#a]&, compTS]//Normal複数成分からなる時系列を取り上げ,2つの新しい成分を持つ別の時系列を構成する:
ts = TimeSeries[{"a" -> {11, 17, 13}, "b" -> {"cat", "giraffe", "fox"}, "c" -> {.1, .5, .9}}, {0}]cspec = {"s" -> Function[Sqrt[#a]], "e" -> Function[Entropy[#b]]};TimeSeriesMap[cspec, ts]この結果は,Tabularに変換し,ConstructColumnsを用いてから元に戻すことによっても得られる:
ConstructColumns[Tabular[ts], cspec]TimeSeries[%, {ts["Times"]}]TimeSeriesMap[f,ts]はTimeSeriesMapThread[Function[f[#2]],ts]に等しい:
ts = TimeSeries[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}, {1}]res = TimeSeriesMap[f, ts]Normal[res]res === TimeSeriesMapThread[f[#2]&, ts]考えられる問題 (2)
キー"Timestamp"は新しい成分キーとして使用できない:
ts = TimeSeries[{11, 17, 13}, {Today}]TimeSeriesMap["Timestamp" -> f, ts]
TimeSeriesMap["time" -> f, ts]名前付きの成分を持つ時系列については,#Valueは認識されない:
ts = TimeSeries[{3.5, 6.7, 8.4}, {11}, {"a"}]TimeSeriesMap[f[#Value]&, ts]#を使って連想全体にアクセスする,あるいは#aを使って成分"a"の値にアクセスする:
TimeSeriesMap[f[#]&, ts]//NormalTimeSeriesMap[f[#a]&, ts]//Normalおもしろい例題 (2)
ts = TemporalData[TimeSeries,
{{{{1.37, 64.97, 26.85, 2.79, 3.07, 0.01, 0, 0, 0, 0.12, 0.03, 0.01, 0, 0.01, 0, 0, 0, 0, 0, 0.08,
0, 0, 0, 0, 0.15, 0, 0, 0, 0, 0, 0.27, 0.04, 0.02, 0, 0, 0.02, 0, 0, 0, 0.2},
{1.5, 63.98, 27.66, 2.83, 3.09, 0 ... "Samsung", "AOL", "SeaMonkey", "Openwave", "Whale Browser", "Phantom", "SonyEricsson",
"Pale Moon", "Obigo", "Jasmine", "Other"}, ResamplingMethod ->
{"Interpolation", InterpolationOrder -> 1}, ValueDimensions -> 40}}, True, 314.1];ts["FirstValue"]ts["MetaInformation"]best7ts = TimeSeriesMap[With[{pos = Reverse@TakeLargest[# -> "Index", 7]}, {#[[pos]], ts["MetaInformation"][[pos]]}]&, ts];Animate[BarChart[First[best7ts[t]], BarOrigin -> Left, PlotLabel -> DateObject[t, "Month"], PlotRange -> {0, 75}, AxesLabel -> "%", ChartLabels -> Placed[Last[best7ts[t]], After], ChartStyle -> "DarkRainbow"], {t, ts["Dates"]}, AnimationRate -> 3, AnimationRunning -> False, SaveDefinitions -> True]start = DateObject[{2025, 1, 1}, "Day"];
end = DateObject[{2025, 12, 31}, "Day"];
range = DateRange[start, end, "Day"];rises = Sunrise[Entity["City", {"London", "GreaterLondon", "UnitedKingdom"}], range, TimeZone -> Entity["City", {"London", "GreaterLondon", "UnitedKingdom"}]]sets = Sunset[Entity["City", {"London", "GreaterLondon", "UnitedKingdom"}], range, TimeZone -> Entity["City", {"London", "GreaterLondon", "UnitedKingdom"}]]rises["FirstValue"]riseHour = TimeSeriesMap[DateValue[#, "HourExact"]&, rises]setHour = TimeSeriesMap[DateValue[#, "HourExact"]&, sets]ListPlot[Transpose[{riseHour["Values"], setHour["Values"]}], AxesLabel -> {"sunrise", "sunset"}, PlotStyle -> PointSize[Small], ColorFunction -> "Rainbow"]テキスト
Wolfram Research (2014), TimeSeriesMap, Wolfram言語関数, https://reference.wolfram.com/language/ref/TimeSeriesMap.html (2026年に更新).
CMS
Wolfram Language. 2014. "TimeSeriesMap." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/TimeSeriesMap.html.
APA
Wolfram Language. (2014). TimeSeriesMap. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TimeSeriesMap.html
BibTeX
@misc{reference.wolfram_2026_timeseriesmap, author="Wolfram Research", title="{TimeSeriesMap}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/TimeSeriesMap.html}", note=[Accessed: 17-November-2026]}
BibLaTeX
@online{reference.wolfram_2026_timeseriesmap, organization={Wolfram Research}, title={TimeSeriesMap}, year={2026}, url={https://reference.wolfram.com/language/ref/TimeSeriesMap.html}, note=[Accessed: 17-November-2026]}