WOLFRAM

Wolfram 语言与系统参考资料中心

UnmanageObject[man]

获取封装在托管对象中的内存的所有权.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

UnmanageObject

UnmanageObject[man]

获取封装在托管对象中的内存的所有权.

更多信息

  • man 可以是 ManagedObject 或编译代码中 "Managed" 类型的对象.
  • 在编译代码中，UnmanageObject 的类型签名为 {"Managed"::[t]}t.
  • UnmanageObject[man] 可变地使托管对象 man 无效. 在编译代码中，在 man 失效后再次使用它会导致运行时错误.
  • UnmanageObject 可以在将对象传递给将对它进行长期引用的外部代码时使用.

范例

打开所有单元 关闭所有单元

基本范例  (2)

创建一个托管对象：

Wolfram Language code: man = CreateManagedObject[foo, Echo]

托管对象处于激活状态：

Wolfram Language code: man["Active"]

取消托管，返回原来封装的值：

Wolfram Language code: UnmanageObject[man]

托管对象不再处于激活状态：

Wolfram Language code: man["Active"]

编译一个创建托管对象的函数：

Wolfram Language code: createManaged = FunctionCompile[Function[{}, CreateTypeInstance["Managed", 12, Function[obj, Null;]] ]]

编译一个取消托管的函数：

Wolfram Language code: unmanage = FunctionCompile[Function[Typed[arg, "Managed"::["MachineInteger"]], UnmanageObject[arg] ]]

创建托管对象：

Wolfram Language code: managed = createManaged[]

取消托管，返回原来封装的值：

Wolfram Language code: unmanage[managed]

范围  (3)

当托管对象不再被引用时，对释放的函数进行计算：

Wolfram Language code: With[{man = CreateManagedObject[foo, Echo]}, Null]

如果取消了对托管对象的托管，则不会对释放的函数进行计算：

Wolfram Language code: With[{man = CreateManagedObject[foo, Echo]}, UnmanageObject[man];]

托管对象被 UnmanageObject 变为无效，当它们超出范围时不会被释放. 编译用于取消托管的函数：

Wolfram Language code: createManaged = FunctionCompile[Function[{}, CreateTypeInstance["Managed", 12, Function[obj, Echo["freed"];]] ]]
Wolfram Language code: unmanage = FunctionCompile[Function[Typed[arg, "Managed"::["MachineInteger"]], UnmanageObject[arg] ]]

创建托管对象，并让它超出范围：

Wolfram Language code: Module[{obj}, obj = createManaged[];Echo["body"]];

在让它超出范围之前取消托管：

Wolfram Language code: Module[{obj}, obj = createManaged[];unmanage[obj];Echo["body"]];

托管对象的内容可以通过取消托管然后创建一个新的托管对象来借用. 编译一个用于创建托管 C 数组的函数：

Wolfram Language code: createManagedArray = FunctionCompile[Function[{}, CreateTypeInstance["Managed"::["CArray"::["MachineInteger"]], {1, 2, 3}] ]]

编译一个取消托管、修改然后重新托管 C 数组的函数：

Wolfram Language code: modifyManagedArray = FunctionCompile[Function[Typed[carr, "Managed"::["CArray"::["MachineInteger"]]], Module[{unmanagedArr}, unmanagedArr = UnmanageObject[carr]; ToRawPointer[unmanagedArr, 0, 42]; CreateTypeInstance["Managed", unmanagedArr] ] ]]

创建托管 C 数组：

Wolfram Language code: carr = createManagedArray[]

对它进行修改，返回一个新的托管 C 数组：

Wolfram Language code: carr2 = modifyManagedArray[carr]

属性和关系  (2)

分配原始内存的函数通常返回一个托管对象：

Wolfram Language code: ptr = RawMemoryAllocate["UnsignedInteger8", 10]

取消对指针的托管：

Wolfram Language code: rawPtr = UnmanageObject[ptr]

往指针中写入一个值：

Wolfram Language code: RawMemoryWrite[rawPtr, 42]

因为指针不再处于托管状态，当不再使用内存时，调用 RawMemoryFree：

Wolfram Language code: RawMemoryFree[rawPtr]

托管对象由使用 LibraryFunctionDeclaration 声明的函数自动解除封装，因此无需调用 UnmanageObject：

Wolfram Language code: dec = LibraryFunctionDeclaration["sumArray", "compilerDemoBase", {"CArray"::["CLong"], "CLong"} -> "CInt"];

托管 C 数组在传递给库函数之前被借用并自动解除封装：

Wolfram Language code: cf = FunctionCompile[dec, Function[Typed[arg, "ListVector"::["CLong"]], Module[{carr}, carr = CreateTypeInstance["Managed"::["CArray"::["CLong"]], arg]; LibraryFunction["sumArray"][carr, Length[arg]] ] ] ]
Wolfram Language code: cf[Range[100]]

可能存在的问题  (1)

编译托管整数的函数：

Wolfram Language code: funcs = FunctionCompile[ <| "create" -> Function[{}, CreateTypeInstance["Managed", 12, Function[obj, Null;]] ], "unmanage" -> Function[Typed[arg, "Managed"::["MachineInteger"]], UnmanageObject[arg] ] |>]

创建托管的整数：

Wolfram Language code: managed = funcs["create"][]

取消托管，返回原来封装的值：

Wolfram Language code: funcs["unmanage"][managed]

随后的 UnmanageObject 调用将失败，因为托管对象在取消托管时失效：

Wolfram Language code: funcs["unmanage"][managed]
Wolfram Research (2022)，UnmanageObject，Wolfram 语言函数，https://reference.wolfram.com/language/ref/UnmanageObject.html.

文本

Wolfram Research (2022)，UnmanageObject，Wolfram 语言函数，https://reference.wolfram.com/language/ref/UnmanageObject.html.

CMS

Wolfram 语言. 2022. "UnmanageObject." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/UnmanageObject.html.

APA

Wolfram 语言. (2022). UnmanageObject. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/UnmanageObject.html 年

BibTeX

@misc{reference.wolfram_2026_unmanageobject, author="Wolfram Research", title="{UnmanageObject}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/UnmanageObject.html}", note=[Accessed: 20-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_unmanageobject, organization={Wolfram Research}, title={UnmanageObject}, year={2022}, url={https://reference.wolfram.com/language/ref/UnmanageObject.html}, note=[Accessed: 20-June-2026]}