WOLFRAM

Wolfram 语言与系统参考资料中心

BlockchainBlockData  (for Bitcoin)

$BlockchainBase = "Bitcoin"

BlockchainBlockData["hash"]

给出比特币区块链上具有指定哈希的块的信息.

BlockchainBlockData[n]

给出比特币区块链上区块 n 的信息.

BlockchainBlockData[-n]

给出比特币区块链上倒数第 n 个区块的信息.

BlockchainBlockData[bspec,prop]

给出区块的指定属性.

更多信息

  • BlockchainBlockData[-1] 给出最新的比特币区块的信息.
  • 属性包括：
  • "BlockHash"区块的哈希
    "BlockNumber"区块在比特区块链中的编号（高度）
    "Timestamp"区块被挖出的时间
    "Amounts"区块的金额信息
    "Size"区块的字节数
    "Nonce"该区块的哈希使用的随机数 (nonce)
    "Version"区块的版本
    "Confirmations"确认次数
    "PreviousBlockHash"前一个区块的哈希
    "MerkleRoot"交易的 Merkle 根哈希
    "TotalTransactions"此区块中交易的总数
    "TransactionList"区块的交易 ID 列表
  • "Amounts" 给出一个关联，以下属性为键：
  • "BlockReward"挖出此区块获得的奖励
    "TotalFee"此区块交易费用的总和
    "TotalInput"此区块交易的输入金额的总和
    "TotalOutput"此区块交易的输出金额的总和
  • 可能的选项包括：
  • BlockchainBase $BlockchainBase设置区块链及其网络
    MaxItems All最多返回多少项
  • BlockchainBlockData 可以访问比特币的主网（默认）和测试网. 要想指定这些网络，请使用 BlockchainBase 选项.
  • MaxItems 的设置指定了结果中最多包含多少笔交易.

范例

打开所有单元 关闭所有单元

基本范例  (6)

用高度获取比特币区块链中一个区块的信息：

Wolfram Language code: BlockchainBlockData[123123, BlockchainBase -> "Bitcoin"]//Dataset

获取比特币测试网络 (testnet) 区块链的最新区块：

Wolfram Language code: BlockchainBlockData[-1, BlockchainBase -> {"Bitcoin", "Testnet"}]//Dataset

用区块哈希来获取有关比特币区块的信息：

Wolfram Language code: BlockchainBlockData["0000000000000000001240ca996608e85efbb813d1feeada0165d2fa855b31b3", BlockchainBase -> "Bitcoin"]//Dataset

通过提供高度列表或区块哈希获取多个比特币区块：

Wolfram Language code: BlockchainBlockData[{1, 123456, "0000000000000000001240ca996608e85efbb813d1feeada0165d2fa855b31b3"}, BlockchainBase -> "Bitcoin"]//Dataset

从比特币区块获取一个属性：

Wolfram Language code: BlockchainBlockData[500000, "Timestamp", BlockchainBase -> "Bitcoin"]

从比特币区块获取多个属性：

Wolfram Language code: BlockchainBlockData[500000, {"Timestamp", "Nonce", "PreviousBlockHash"}, BlockchainBase -> "Bitcoin"]

范围  (12)

金额  (1)

获取与比特币区块关联的金额的信息：

Wolfram Language code: BlockchainBlockData[500000, "Amounts", BlockchainBase -> "Bitcoin"]//Dataset

区块哈希  (1)

获取比特币区块的区块哈希：

Wolfram Language code: BlockchainBlockData[500000, "BlockHash", BlockchainBase -> "Bitcoin"]

区块高度  (1)

获取比特币区块的高度哈希：

Wolfram Language code: BlockchainBlockData["00000000000000000024fb37364cbf81fd49cc2d51c09c75c35433c3a1945d04", "BlockNumber", BlockchainBase -> "Bitcoin"]

确认数  (1)

获取比特币区块的确认次数：

Wolfram Language code: BlockchainBlockData["00000000000000000024fb37364cbf81fd49cc2d51c09c75c35433c3a1945d04", "Confirmations", BlockchainBase -> "Bitcoin"]

MerkleRoot  (1)

获取比特币区块的 Merkle root：

Wolfram Language code: BlockchainBlockData["00000000000000000024fb37364cbf81fd49cc2d51c09c75c35433c3a1945d04", "MerkleRoot", BlockchainBase -> "Bitcoin"]

随机数  (1)

获取比特币区块的哈希使用的随机数：

Wolfram Language code: BlockchainBlockData["00000000000000000024fb37364cbf81fd49cc2d51c09c75c35433c3a1945d04", "Nonce", BlockchainBase -> "Bitcoin"]

前一区块哈希  (1)

获取前一个比特币区块的区块哈希：

Wolfram Language code: BlockchainBlockData["00000000000000000024fb37364cbf81fd49cc2d51c09c75c35433c3a1945d04", "PreviousBlockHash", BlockchainBase -> "Bitcoin"]

区块大小  (1)

获取比特币区块的大小（以字节为单位）：

Wolfram Language code: BlockchainBlockData["00000000000000000024fb37364cbf81fd49cc2d51c09c75c35433c3a1945d04", "Size", BlockchainBase -> "Bitcoin"]

时间戳  (1)

获取比特币区块被挖出来的时间：

Wolfram Language code: BlockchainBlockData["00000000000000000024fb37364cbf81fd49cc2d51c09c75c35433c3a1945d04", "Timestamp", BlockchainBase -> "Bitcoin"]

交易总数  (1)

获取比特币区块中包含的交易的总数：

Wolfram Language code: BlockchainBlockData["00000000000000000024fb37364cbf81fd49cc2d51c09c75c35433c3a1945d04", "TotalTransactions", BlockchainBase -> "Bitcoin"]

交易列表  (1)

获取比特币区块中包含的交易的列表：

Wolfram Language code: BlockchainBlockData["00000000000000000024fb37364cbf81fd49cc2d51c09c75c35433c3a1945d04", "TransactionList", BlockchainBase -> "Bitcoin"]//Shallow

版本  (1)

获取比特币区块的版本：

Wolfram Language code: BlockchainBlockData["00000000000000000024fb37364cbf81fd49cc2d51c09c75c35433c3a1945d04", "Version", BlockchainBase -> "Bitcoin"]

选项  (3)

BlockchainBase  (2)

主网  (1)

从比特币主网的随机区块获取信息：

Wolfram Language code: BlockchainBlockData[RandomInteger[300000], BlockchainBase -> {"Bitcoin", "Mainnet"}]//Dataset

测试网  (1)

从比特币测试网络的随机区块获取信息：

Wolfram Language code: BlockchainBlockData[RandomInteger[200000], BlockchainBase -> {"Bitcoin", "Testnet"}]//Dataset

MaxItems  (1)

从最新的比特币区块获取前 5 笔交易：

Wolfram Language code: BlockchainBlockData[-1, "TransactionList", BlockchainBase -> "Bitcoin", MaxItems -> 5]

应用  (3)

获取最新比特币区块的大小，以兆字节为单位：

Wolfram Language code: UnitConvert[BlockchainBlockData[-1, "Size", BlockchainBase -> "Bitcoin"], "Megabytes"]//N

获取比特币区块包含的一个随机交易：

Wolfram Language code: RandomChoice[BlockchainBlockData[-1, "TransactionList", BlockchainBase -> "Bitcoin"]]

获取有关区块矿工的信息：

Wolfram Language code: txList = BlockchainBlockData[420000, "TransactionList"];

提取 coinbase 的交易 ID：

Wolfram Language code: coinbase = txList[[1]]

获取矿工的地址：

Wolfram Language code: miner = Lookup[BlockchainTransactionData[coinbase, "Outputs"][[1]], "Address"]

获取该地址的信息：

Wolfram Language code: BlockchainAddressData[miner, BlockchainBase -> "Bitcoin"]//Dataset

可能存在的问题  (2)

不存在的哈希  (1)

将一个区块链中的区块哈希用在另一个区块链中将返回 Missing：

Wolfram Language code: btcBlockHash = BlockchainBlockData[-1, "BlockHash", BlockchainBase -> "Bitcoin"]
Wolfram Language code: BlockchainBlockData[btcBlockHash, BlockchainBase -> {"Bitcoin", "Testnet"}]

不正确的哈希  (1)

提供不是十六进制数的区块哈希将返回 $Failed：

Wolfram Language code: BlockchainBlockData["6h6h6h6h", BlockchainBase -> "Bitcoin"]

巧妙范例  (2)

根据比特币区块生成声音：

Wolfram Language code: Sound[SoundNote[#, # * 0.05, "NewAge"]& /@ Take[Flatten[ToCharacterCode[BlockchainBlockData[300000, "TransactionList", BlockchainBase -> "Bitcoin"]]] - 60, 100]]

获取 coinbase 交易的输入脚本，并将其解码为 ASCII 字符：

Wolfram Language code: genesisCoinbase = BlockchainBlockData[0, "TransactionList"]//First; FromCharacterCode[FromDigits[#, 16]& /@ StringPartition[Lookup[BlockchainTransactionData[genesisCoinbase, "Inputs"][[1]], "ScriptString"], 2]]
Wolfram Research (2019)，BlockchainBlockData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/blockchain/BlockchainBlockData-Bitcoin.html.

文本

Wolfram Research (2019)，BlockchainBlockData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/blockchain/BlockchainBlockData-Bitcoin.html.

CMS

Wolfram 语言. 2019. "BlockchainBlockData." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/blockchain/BlockchainBlockData-Bitcoin.html.

APA

Wolfram 语言. (2019). BlockchainBlockData. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/blockchain/BlockchainBlockData-Bitcoin.html 年

BibTeX

@misc{reference.wolfram_2026_blockchainblockdata, author="Wolfram Research", title="{BlockchainBlockData}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/blockchain/BlockchainBlockData-Bitcoin.html}", note=[Accessed: 14-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_blockchainblockdata, organization={Wolfram Research}, title={BlockchainBlockData}, year={2019}, url={https://reference.wolfram.com/language/ref/blockchain/BlockchainBlockData-Bitcoin.html}, note=[Accessed: 14-August-2026]}