WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター
"HeldExpression" (比較法)

"HeldExpression" (比較法)

式を評価せずに比較する．

詳細

  • "HeldExpression"比較法は，2つの式が任意のホールドラッパー内で同一なら両者が等価であるとみなす．
  • 解答集の値と提出された答の両方が，Hold，HoldPattern，HoldComplete等のホールドラッパーに包まれて与えられることが多い．
  • パターン付きの解答集の値は，標準的なパターンマッチングをサポートするために，HoldPattern[expr]を使って与えられなければならない．HoldCompleteあるいはHoldの使用にはパターン式のリテラルなマッチングが必要である．

例題

すべて開く すべて閉じる

例  (2)

未評価の式用のAssessmentFunctionを作成する：

Wolfram Language code: heldtest = AssessmentFunction[Hold[Nest[f, x, 3]], "HeldExpression"]

提出された答は厳密にマッチしなければならない：

Wolfram Language code: heldtest[Hold[Nest[f, x, 3]]]

評価結果は正答とはされない：

Wolfram Language code: heldtest[Hold[f[f[f[x]]]]]

未評価の数式用のAssessmentFunctionを作成する：

Wolfram Language code: heldmath = AssessmentFunction[Hold[1 + 2], "HeldExpression"]

提出された答は同一でなければならない：

Wolfram Language code: heldmath[Hold[1 + 2]]

同一ではないが数学的に等価な提出物は不正解とみなされる：

Wolfram Language code: heldmath[Hold[2 + 1]]
Wolfram Language code: heldmath[Hold[3]]

スコープ  (1)

コード問題に対する評価関数を作成する：

Wolfram Language code: rangetest = AssessmentFunction[Hold[Range /@ Range[4]], "HeldExpression"]

QuestionObjectでこれを使う：

Wolfram Language code: qo = QuestionObject[QuestionInterface["Code", "Use only Range and Map to create this output: {{1},{1,2},{1,2,3},{1,2,3,4}}"], rangetest]

正答を与える：

Wolfram Language code: qo

出力を提出しても不正解とされる：

Wolfram Language code: qo

特性と関係  (4)

Holdを使った評価関数は，パターンを文字通りに扱う：

Wolfram Language code: holdassess = AssessmentFunction[Hold[Nest[f, x, _]], "HeldExpression"]

パターンに一致する提出物は，不正解とされる：

Wolfram Language code: holdassess[Hold[Nest[f, x, 2]]]

厳密でリテラルなマッチは正解とされる：

Wolfram Language code: holdassess[Hold[Nest[f, x, _]]]

代りにHoldPatternを使ってパターンマッチをサポートする：

Wolfram Language code: holdpatternassess = AssessmentFunction[HoldPattern[Nest[f, x, _]], "HeldExpression"]

一致するホールドされた式は正解とみなされる：

Wolfram Language code: holdpatternassess[Hold[Nest[f, x, 2]]]

評価結果は受け入れられない：

Wolfram Language code: holdpatternassess[Hold[f[f[x]]]]

"Expression"比較法は，存在する場合はホールドラッパーを含めて式全体を比較する：

Wolfram Language code: exprcomp = AssessmentFunction[HoldPattern[_ + 2], "Expression"]

ホールドラッパーが異なると正答とはされないかもしれない：

Wolfram Language code: exprcomp[Hold[1 + 2]]

"HeldExpression"を使ってホールドラッパー内の式を比較する：

Wolfram Language code: heldexprcomp = AssessmentFunction[HoldPattern[_ + 2], "HeldExpression"]

同じ答は正答とされる：

Wolfram Language code: heldexprcomp[Hold[1 + 2]]

ホールドされた数式用の評価を作成する：

Wolfram Language code: holdaf = AssessmentFunction[Hold[1 + 2 + 3], "HeldExpression"]

同じ答を"ArithmeticResult"として扱う別の評価を作成する：

Wolfram Language code: mathaf = AssessmentFunction[Hold[1 + 2 + 3], "ArithmeticResult"]

"HeldExpression"は，加算における項の並べ替えのような基本的等価性も許容しないが，"ArithmeticResult"はこれを許容する：

Wolfram Language code: holdaf[Hold[3 + 1 + 2]]
Wolfram Language code: mathaf[Hold[3 + 1 + 2]]

ホールドされたコードの式用の評価を作成する：

Wolfram Language code: holdaf = AssessmentFunction[HoldPattern[Table[i ^ 2, {i, RandomInteger[10]}]], "HeldExpression"]

同じ答を"CodeEquivalence"解として扱う別の評価を作成する：

Wolfram Language code: codeaf = AssessmentFunction[HoldPattern[Table[i ^ 2, {i, RandomInteger[10]}]], "CodeEquivalence"]

"HeldExpression"は同一ではない答の等価性を求めようとしないが，"CodeEquivalence"は求めようとする：

Wolfram Language code: holdaf[HoldPattern[# ^ 2& /@ Range[RandomInteger[10]]]]
Wolfram Language code: codeaf[HoldPattern[# ^ 2& /@ Range[RandomInteger[10]]]]

考えられる問題  (1)

QuestionObjectは，Holdラッパーに包み込まれて与えられた場合でも，値のフォーマットを許容する：

Wolfram Language code: QuestionObject["Which creates a 2D display of values", AssessmentFunction[{Hold[Grid[{{a, b}, {c, d}}]] -> 1, Hold[Table[{{a, b}, {c, d}}, 1]], Hold[{Row@{a, b}, Row@{c, d}}]}, "HeldExpression"]]

DisableFormattingを使ってQuestionObjectのフォーマットを回避する：

Wolfram Language code: QuestionObject["Which creates a 2D display of values", AssessmentFunction[{Hold[DisableFormatting@Grid[{{a, b}, {c, d}}]] -> 1, Hold[Table[{{a, b}, {c, d}}, 1]], Hold[DisableFormatting@{Row@{a, b}, Row@{c, d}}]}, "HeldExpression"]]