WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

"ByteArray" （コンパイルタイプ）

"ByteArray"

バイトの一次元配列を表す．

詳細

  • "ByteArray"はTypedおよび型を指定する関連した構造で使うことができる．
  • "ByteArray"オブジェクトは自動的にメモリ管理される．

コンストラクタ

  • ByteArray["string"]はBase64で符号化した文字列からバイト値を抽出することによって"ByteArray"オブジェクトを構築する．
  • ByteArray[na]は配列 na のコピーを構築する．ここで na は型"NumericArray"::["UnsignedInteger8", 1]を持つ．
  • CreateTypeInstance["ByteArray",len]は長さ len のバイト配列を構築する．
  • CreateTypeInstance["ByteArray",byte,len]は byte 値で満たされた長さ len のバイト配列を構築する．

変換

    式

  • "ByteArray"オブジェクトはByteArray式に変換することもByteArray式から変換することもができる．

    • "NumericArray"

  • "ByteArray"オブジェクトは"NumericArray"::["UnsignedInteger8",1]オブジェクトに変換することも"NumericArray"::["UnsignedInteger8",1]オブジェクトから変換することもできる．

ランタイムエラー

    ArrayPartError

  • "ByteArray"から要素を抽出する操作では，その要素が存在しない場合ランタイムエラーとなる可能性がある．

    • Cast

  • "ByteArray"オブジェクトから，または"ByteArray"オブジェクトへのキャストでは，オブジェクトがターゲットタイプに変換できない場合ランタイムエラーとなる可能性がある．

例題

すべて開く すべて閉じる

例  (2)

"ByteArray"はCompiledCodeFunctionの入力または出力として使うことができる：

Wolfram Language code: cf = FunctionCompile[Function[Typed[ba, "ByteArray"], ba]]
Wolfram Language code: cf[ByteArray[{1, 2, 3}]]

コンパイルされたコードで"ByteArray"を生成する：

Wolfram Language code: func = FunctionCompile@Function[Typed[str, "String"], ByteArray[str] ]
Wolfram Language code: func["AQIDBAUGBwg="]

スコープ  (8)

構築  (4)

文字列から"ByteArray"を構築する：

Wolfram Language code: func = FunctionCompile@Function[Typed[str, "String"], ByteArray[str] ]
Wolfram Language code: func["AQIDBAUGBwg="]

数値配列から"ByteArray"を構築する：

Wolfram Language code: func = FunctionCompile@Function[Typed[na, "NumericArray"::["UnsignedInteger8", 1]], ByteArray[na] ]
Wolfram Language code: func[NumericArray[{1, 2, 3}, "UnsignedInteger8"]]

指定された長さの"ByteArray"インスタンスを生成する：

Wolfram Language code: func = FunctionCompile@Function[Typed[len, "MachineInteger"], CreateTypeInstance["ByteArray", len] ]
Wolfram Language code: Length[func[10]]

生成されたバイト配列はランダムな値で満たされる：

Wolfram Language code: Normal[func[10]]

初期値で満たされた，指定の長さの"ByteArray"インスタンスを生成する：

Wolfram Language code: func = FunctionCompile@Function[{Typed[byte, "UnsignedInteger8"], Typed[len, "MachineInteger"]}, CreateTypeInstance["ByteArray", byte, len] ]
Wolfram Language code: Normal[func[42, 10]]

変換  (4)

"ByteArray"を"NumericArray"に変換する：

Wolfram Language code: func = FunctionCompile@Function[{Typed[ba, "ByteArray"]}, Cast[ba, "NumericArray"::["UnsignedInteger8", 1]] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

"NumericArray"から"ByteArray"に変換する：

Wolfram Language code: func = FunctionCompile@Function[{Typed[na, "NumericArray"::["UnsignedInteger8", 1]]}, Cast[na, "ByteArray"] ]
Wolfram Language code: func[NumericArray[{1, 2, 3}, "UnsignedInteger8"]]

"ByteArray"を"InertExpression"に変換する：

Wolfram Language code: func = FunctionCompile@Function[{Typed[ba, "ByteArray"]}, Cast[ba, "InertExpression"] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

"InertExpression"から"ByteArray"に変換する：

Wolfram Language code: func = FunctionCompile@Function[{Typed[expr, "InertExpression"]}, Cast[expr, "ByteArray"] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

特性と関係  (5)

長さを得る：

Wolfram Language code: func = FunctionCompile@Function[Typed[ba, "ByteArray"], Length[ba] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

頭部を得る：

Wolfram Language code: func = FunctionCompile@Function[Typed[ba, "ByteArray"], Head[ba] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

要素を得る：

Wolfram Language code: func = FunctionCompile@Function[{Typed[ba, "ByteArray"], Typed[x, "MachineInteger"]}, ba[[x]] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}], 2]

"ByteArray"を通常の式に変換する：

Wolfram Language code: func = FunctionCompile@Function[{Typed[ba, "ByteArray"]}, Normal[ba] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

"ByteArray"を文字列に変換する：

Wolfram Language code: func = FunctionCompile@Function[{Typed[ba, "ByteArray"]}, ToString[ba] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

考えられる問題  (2)

Partを使う場合，その要素が存在しないとランタイムエラーを引き起こす可能性がある：

Wolfram Language code: func = FunctionCompile[Function[Typed[ba, "ByteArray"], ba[[4]]]]; func[ByteArray[{1, 2, 3}]]

キャストを使う場合，そのオブジェクトがターゲットの型に変換できないと，ランタイムエラーを引き起こすことがある：

Wolfram Language code: func = FunctionCompile[Function[Typed[expr, "InertExpression"], Cast[expr, "ByteArray"]]]; func[4]