WOLFRAM

Wolfram 语言与系统参考资料中心

"ByteArray" （编译类型）

"ByteArray"

表示一维字节数组.

更多信息

  • "ByteArray" 可在 Typed 及相关结构中使用来指定类型.
  • "ByteArray" 对象自动由内存进行管理.

函数构造

  • ByteArray["string"] 通过从 Base64 编码的字符串中提取字节值来构造 "ByteArray" 对象.
  • ByteArray[na] 构造数组 na 的副本，其中 na 具有类型 "NumericArray"::["UnsignedInteger8", 1].
  • CreateTypeInstance["ByteArray",len] 构造一个长度为 len 的字节数组.
  • CreateTypeInstance["ByteArray",byte,len] 构造一个长度为 len 且用 byte 值填充的字节数组.

转换

    表达式

  • "ByteArray" 对象可以与 ByteArray 表达式相互转换.

    • "NumericArray"

  • "ByteArray" 对象可以与 "NumericArray"::["UnsignedInteger8",1] 对象相互转换.

运行时错误

    ArrayPartError

  • 如果元素不存在，需要从 "ByteArray" 中提取这些元素的操作可能会给出运行时错误.

    • Cast

  • 如果对象无法转换为目标类型，则从 "ByteArray" 对象进行转换可能会产生运行时错误.

范例

打开所有单元 关闭所有单元

基本范例  (2)

"ByteArray" 可以用作 CompiledCodeFunction 的输入或输出：

Wolfram Language code: cf = FunctionCompile[Function[Typed[ba, "ByteArray"], ba]]
Wolfram Language code: cf[ByteArray[{1, 2, 3}]]

用编译代码创建一个 "ByteArray"：

Wolfram Language code: func = FunctionCompile@Function[Typed[str, "String"], ByteArray[str] ]
Wolfram Language code: func["AQIDBAUGBwg="]

范围  (8)

构造  (4)

从字符串构造一个 "ByteArray"：

Wolfram Language code: func = FunctionCompile@Function[Typed[str, "String"], ByteArray[str] ]
Wolfram Language code: func["AQIDBAUGBwg="]

从数值数组构造一个 "ByteArray"：

Wolfram Language code: func = FunctionCompile@Function[Typed[na, "NumericArray"::["UnsignedInteger8", 1]], ByteArray[na] ]
Wolfram Language code: func[NumericArray[{1, 2, 3}, "UnsignedInteger8"]]

创建给定长度的 "ByteArray" 实例：

Wolfram Language code: func = FunctionCompile@Function[Typed[len, "MachineInteger"], CreateTypeInstance["ByteArray", len] ]
Wolfram Language code: Length[func[10]]

请注意，创建的字节数组填充有随机值：

Wolfram Language code: Normal[func[10]]

创建一个给定长度的 "ByteArray" 实例，并填充初始值：

Wolfram Language code: func = FunctionCompile@Function[{Typed[byte, "UnsignedInteger8"], Typed[len, "MachineInteger"]}, CreateTypeInstance["ByteArray", byte, len] ]
Wolfram Language code: Normal[func[42, 10]]

转换  (4)

将 "ByteArray" 转换为 "NumericArray"：

Wolfram Language code: func = FunctionCompile@Function[{Typed[ba, "ByteArray"]}, Cast[ba, "NumericArray"::["UnsignedInteger8", 1]] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

从 "NumericArray" 转换 "ByteArray"：

Wolfram Language code: func = FunctionCompile@Function[{Typed[na, "NumericArray"::["UnsignedInteger8", 1]]}, Cast[na, "ByteArray"] ]
Wolfram Language code: func[NumericArray[{1, 2, 3}, "UnsignedInteger8"]]

将 "ByteArray" 转换为 "InertExpression"：

Wolfram Language code: func = FunctionCompile@Function[{Typed[ba, "ByteArray"]}, Cast[ba, "InertExpression"] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

从 "ByteArray" 转换 "InertExpression"：

Wolfram Language code: func = FunctionCompile@Function[{Typed[expr, "InertExpression"]}, Cast[expr, "ByteArray"] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

属性和关系  (5)

得到长度：

Wolfram Language code: func = FunctionCompile@Function[Typed[ba, "ByteArray"], Length[ba] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

得到标头：

Wolfram Language code: func = FunctionCompile@Function[Typed[ba, "ByteArray"], Head[ba] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

得到元素：

Wolfram Language code: func = FunctionCompile@Function[{Typed[ba, "ByteArray"], Typed[x, "MachineInteger"]}, ba[[x]] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}], 2]

将 "ByteArray" 转换为普通表达式：

Wolfram Language code: func = FunctionCompile@Function[{Typed[ba, "ByteArray"]}, Normal[ba] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

将 "ByteArray" 转换为字符串：

Wolfram Language code: func = FunctionCompile@Function[{Typed[ba, "ByteArray"]}, ToString[ba] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

可能存在的问题  (2)

如果元素不存在，部分访问可能会导致运行时错误：

Wolfram Language code: func = FunctionCompile[Function[Typed[ba, "ByteArray"], ba[[4]]]]; func[ByteArray[{1, 2, 3}]]

如果对象无法转换为目标类型，则转换可能会导致运行时错误：

Wolfram Language code: func = FunctionCompile[Function[Typed[expr, "InertExpression"], Cast[expr, "ByteArray"]]]; func[4]