WOLFRAM

Wolfram 语言与系统参考资料中心

"Managed" （编译类型）

"Managed"::[t]

代表一个将自动内存管理添加到 t 的类型.

更多信息

  • "Managed" 为类型添加内存管理，例如由外部库暴露的类型.
  • t 不能是已拥有自动内存管理的状态.
  • "Managed" 使用自动引用计数来自动释放不再使用的对象.
  • 从编译代码返回的托管对象继续由 Wolfram Language 内核进行内存管理.
  • 当作为参数传递给由 LibraryFunctionDeclaration 声明的函数时，托管对象会自动解包. »

函数构造

  • CreateTypeInstance["Managed"::[t],obj,freeFunc] 构造一个包含 obj 的托管对象，该对象可在 "Managed" 对象释放时执行 freeFunc[obj]. freeFunc 必须有类型签名 {t}"Null".
  • CreateTypeInstance["Managed"::[t],obj] 把 DeleteObject 作为 freeFunc 使用.
  • 对于特定的 "Managed"::[t] 类型有许多构造函数，这些构造函数在编译类型 t 的页面上有记录. 例如，"Managed"::["CString"] 的构造函数用 "CString" 来记录.

操作

  • 对于类型为 "Managed" 的实例，可以使用以下操作：
  • man["BorrowValue"]如果被包装的对象有效，则获取其值
    man["UnmanageObject"]对被包装对象负责

属性

  • 类型为 "Managed"::[t] 的 man 的 Information[man,"BaseType"] 给出 "TypeSpecifier"::[t].
  • UnmanageObject 解包并使一个托管对象失效，获取被包装对象的所有权.
    UnmanageObject[man] 等同于 man["UnmanageObject"].

转换

    表达式

  • "Managed" 对象被转换为内存管理的表达式. 当表达式被释放时，则执行原始管理对象的释放函数.

运行时错误

    InvalidManaged

  • 在用 UnmanageObject 解除管理后使用托管对象，可能会产生运行时错误.

范例

打开所有单元 关闭所有单元

基本范例  (3)

编译一个返回托管 "CString" 对象的程序：

Wolfram Language code: cf = FunctionCompile[Function[Typed[str, "String"], Cast[str, "Managed"::["CString"]] ]]
Wolfram Language code: cf["Hello, World!"]

当托管对象超出范围时，包装的 "CString" 被自动释放：

Wolfram Language code: With[{before = MemoryInUse[]}, Do[cf["test"], 100];MemoryInUse[] - before]

编译一个函数，使得该函数可以返回一个释放时会打印出来的托管对象：

Wolfram Language code: cf = FunctionCompile[Function[{}, CreateTypeInstance["Managed", 12, Function[obj, Echo["freed"];]] ]]

创建托管对象，然后使其传递超出范围：

Wolfram Language code: Module[{obj}, obj = cf[];Echo["body"]];

编译一个函数，通过将字符串转换为托管的 C 字符串并使用其借用值来返回字符串的长度：

Wolfram Language code: func = FunctionCompile[ Function[{Typed[str, "String"]}, Module[{cstrMan, cstr, len}, cstrMan = Cast[str, "Managed"::["CString"]]; cstr = cstrMan["BorrowValue"]; len = LibraryFunction["strlen"][cstr]; len ] ] ]
Wolfram Language code: func["Hello, World!"]

范围  (4)

托管对象是在编译的代码中管理的内存：

Wolfram Language code: cf = FunctionCompile[Function[{}, Module[{obj}, obj = CreateTypeInstance["Managed", 12, Function[obj, Echo["freed"];]]; Echo["body"]; ] ]]
Wolfram Language code: cf[]

可以用 UnmanageObject 来访问管理对象的内容：

Wolfram Language code: createManaged = FunctionCompile[Function[{}, CreateTypeInstance["Managed", 12, Function[obj, Echo["freed"];]] ]]
Wolfram Language code: unmanage = FunctionCompile[Function[Typed[arg, "Managed"::["MachineInteger"]], UnmanageObject[arg] ]]

创建托管对象：

Wolfram Language code: man = createManaged[]

使用 UnmanageObject 提取其内容：

Wolfram Language code: unmanage[man]

UnmanageObject 会使托管对象失效，因此对 UnmanageObject 的后续调用会失败：

Wolfram Language code: unmanage[man]

已经解除管理的托管对象不会被自动释放. 编译用于创建和解除管理对象的函数：

Wolfram Language code: createManaged = FunctionCompile[Function[{}, CreateTypeInstance["Managed", 12, Function[obj, Echo["freed"];]] ]]
Wolfram Language code: unmanage = FunctionCompile[Function[Typed[arg, "Managed"::["MachineInteger"]], arg["UnmanageObject"] ]]

创建一个托管对象，然后使其传递超出范围：

Wolfram Language code: Module[{obj}, obj = createManaged[];Echo["body"]];

在让对象传递超出范围之前，取消对其的托管：

Wolfram Language code: Module[{obj}, obj = createManaged[];unmanage[obj];Echo["body"]];

表示一个以非托管 C 语言数组为参数的函数：

Wolfram Language code: dec = LibraryFunctionDeclaration["sumArray", "compilerDemoBase", {"CArray"::["CLong"], "CLong"} -> "CInt"];

托管的 C 语言数组在传递给库函数之前被借用并自动解包：

Wolfram Language code: cf = FunctionCompile[dec, Function[Typed[arg, "ListVector"::["CLong"]], Module[{carr}, carr = CreateTypeInstance["Managed"::["CArray"::["CLong"]], arg]; LibraryFunction["sumArray"][carr, Length[arg]] ] ] ]
Wolfram Language code: cf[Range[100]]

可能存在的问题  (1)

从已被解除托管的托管对象中借用值会导致错误. 为以下操作编写编译函数：从托管对象中创建值、将托管对象解除托管，以及从托管对象中借用值：

Wolfram Language code: createManaged = FunctionCompile[Function[{}, CreateTypeInstance["Managed", 12, Function[obj, Echo["freed"];]] ]]
Wolfram Language code: unmanage = FunctionCompile[Function[Typed[arg, "Managed"::["MachineInteger"]], arg["UnmanageObject"] ]]
Wolfram Language code: borrow = FunctionCompile[Function[Typed[arg, "Managed"::["MachineInteger"]], arg["BorrowValue"] ], CompilerRuntimeErrorAction -> None]

创建一个托管对象：

Wolfram Language code: man = createManaged[]

解除其内容的托管：

Wolfram Language code: unmanage[man]

借用未托管对象的内容是一个错误：

Wolfram Language code: borrow[man]