WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター
モデルのシミュレーションと解析を始める

モデルのシミュレーションと解析を始める

モデルの探究シミュレーション
モデルの表現モデルデータ
Wolfram言語にはシステムモデリング機能が含まれているため，多様な領域における実世界の現象のシミュレーションと解析が実行できる．
完全な製品としてのWolfram SystemModelerにも，モデルの生成，探究，シミュレーション，解析のための，専用のグラフィカルユーザインターフェースが含まれている．
このチュートリアルでは，Wolfram言語に含まれている機能を紹介する．
モデルの探究
SystemModelerにはさまざまな複雑性を持つ多様な分野の例題が含まれている．これらの例題はすべてSystemModelExamplesコマンドを使って調べたりシミュレーションを実行したりすることができる．以下のセルを評価すると，インタラクティブな例題ブラウザが生成される．
Wolfram Language code: SystemModelExamples[]
すべての例題モデルをリストすることもできる．
Wolfram Language code: SystemModelExamples["Models"]//Shallow
例題およびモデルに関する他のソースとして以下がある．
モデルの表現
Wolfram言語のシステムモデルはSystemModelで表すことができる．モデルは，上記のSystemModelExamples等の関数から利用することも，その名前を文字列として参照することで利用することもできる．
Wolfram Language code: SystemModel["DocumentationExamples.Modeling.ControlledMotorGearPendulum"]
結果のオブジェクトはコピーアンドペーストしたり，他の関数の入力に使ったり，特性をクエリしたりすることができる．
Wolfram Language code: [image]["Diagram"]
シミュレーション
SystemModelSimulateはModel Centerで作成されたモデルのシミュレーションを実行し，SystemModelSimulationDataオブジェクトを返す．そのシミュレーションからの結果を可視化するためには，SystemModelPlot使う．
SystemModelSimulate[model]
model のシミュレーションを実行する
SystemModelSimulationData[…]
シミュレーションの結果を含むオブジェクト
SystemModelPlot[sd,"MyPlot"]
SystemModelSimulationData sd の保存されたプロット"MyPlot"を表示する
SystemModelPlot[sd,{"v1",…}]
プロット変数 vi
基本的なシステムモデルシミュレーション関数

基本的なシミュレーションとプロット

モデルのシミュレーションを実行するためには，モデルを引数として，コマンドSystemModelSimulateを使う．
Wolfram Language code: sim1 = SystemModelSimulate[[image]]
SystemModelSimulateの出力はSystemModelSimulationDataオブジェクトである．このオブジェクトは，シミュレーションの変数をプロットするためにSystemModelPlotで使うことができる．多くの例題モデルでは，モデルの作成者によって定義されたプロットが保存されている．これらはシミュレーションの結果の"PlotNames"特性を使ってリストすることができる．
Wolfram Language code: pNames = sim1["PlotNames"]
このようなプロットはSystemModelPlotで簡単に表示することができる．
Wolfram Language code: SystemModelPlot[sim1, First[pNames]]

シミュレーションデータ

シミュレーションの結果のオブジェクトにも，多数の特性がある．
Wolfram Language code: sim1["Properties"]
シミュレーションの中の変数の名前を見てみる．
Wolfram Language code: sim1["VariableNames"]//Short
SystemModelPlotを使って，2つの変数をプロットする．
Wolfram Language code: SystemModelPlot[sim1, {"syse.sys.resistor.i", "syse.sys.resistor.v"}, PlotRange -> All]
時間2における変数"syse.sys.resistor.i"と"syse.sys.resistor.v"の値を取り出す．
Wolfram Language code: sim1[{"syse.sys.resistor.i", "syse.sys.resistor.v"}, 2]

パラメータの変化

オプション"ParameterValues"を使って2つのパラメータを変化させて再びシミュレーションを実行し，それぞれのシミュレーションの結果の変数を比較する．
Wolfram Language code: parSettings = {"syse.sys.R" -> 5.2, "syse.sys.L" -> 0.002};
Wolfram Language code: sim2 = SystemModelSimulate["DocumentationExamples.Modeling.ControlledMotorGearPendulum", <|"ParameterValues" -> parSettings|>];
Wolfram Language code: SystemModelPlot[{sim1, sim2}, {"phi"}]

パラメータスイープ

1つの変数の多数の値に対する複数のシミュレーションは自動的に並列で実行される．さまざまな跳ね返り特性"e"で跳ねるボールのシミュレーションを行う．
Wolfram Language code: simball = SystemModelSimulate["DocumentationExamples.Simulation.BouncingBall", 4, <|"ParameterValues" -> {"e" -> {0.6, 0.7, 0.8, 0.9}}|>]
時間の経過に伴うボールの高さをプロットする．
Wolfram Language code: SystemModelPlot[simball, {"h"}]

カスタムプロット

シミュレーションの結果をデータとして取り込むことにより，多くの方法で結果を可視化し解析することができる．例えば，Chua回路の結果をParametricPlotでプロットする．
Wolfram Language code: mchua = "Modelica.Electrical.Analog.Examples.ChuaCircuit";
Wolfram Language code: simchua = SystemModelSimulate[mchua, 50000];
変数"C1.v"および"C2.v"を選ぶ．
Wolfram Language code: {c1v, c2v} = simchua[{"C1.v", "C2.v"}, t];
Wolfram Language code: ParametricPlot[{c1v, c2v}, {t, 0, 50000}]
ParametricPlot3Dでローレンツアトラクタ(Lorenz attractor)でを使うことで美しいシミュレーションの結果が生成される．
Wolfram Language code: mlorenz = "DocumentationExamples.Simulation.LorenzAttractor";
Wolfram Language code: simlorenz = SystemModelSimulate[mlorenz, 100, Method -> {"DASSL", "InterpolationPoints" -> 15000}];
Wolfram Language code: ParametricPlot3D[Evaluate[simlorenz[{"x", "y", "z"}, t]], {t, 0, 100}, ColorFunction -> ColorData["SunsetColors"], PlotPoints -> 120]
モデルデータ
Wolfram言語からモデルのシミュレーションを実行するだけではなく，より直接的にモデルを操作することもできる．モデルについての情報を取り出すためにはSystemModelを，平衡点を得るためにはFindSystemModelEquilibriumを，線形の状態空間表現を得るためにはSystemModelLinearizeを使う．
SystemModel[model,…]
model についての情報を取り出す
FindSystemModelEquilibrium[model]
model の平衡点を見付ける
SystemModelLinearize[model]
model の線形状態空間表現を得る
システムモデリング関数

モデルの方程式

SystemModelを使ってモデルに関する情報を取り出す．まず，モデル情報の概要を得る．
Wolfram Language code: model = [image];
Wolfram Language code: model["Summary"]
時間変数 t に依存するシステム方程式を得る．
Wolfram Language code: eqns = model["SystemEquations", t]
すべての導関数が0になる点，つまり平衡点を見付ける．
Wolfram Language code: vars = model["SystemVariables"]; Solve[eqns /. Derivative[1][_][t] -> 0, Through[vars[t]]]
モデルについての情報を得るために使うことのできるSystemModelの特性が多数ある，
Wolfram Language code: model["Properties"]

平衡点と線形表現

FindSystemModelEquilibriumを使って，攪拌層のモデルの平衡点を見付ける．
Wolfram Language code: mtank = [image];
Wolfram Language code: FindSystemModelEquilibrium[mtank]
関数SystemModelLinearizeは，平衡点におけるモデルの線形状態空間表現を与える．結果はWolfram言語のStateSpaceModelである．
Wolfram Language code: lin = SystemModelLinearize[mtank]
Wolfram言語の制御機能を使うと，この表現をさらに操作することができる．極配置を使って制御器を設計し，単位刻み入力に対する出力応答を表示する．
Wolfram Language code: ctrl = StateFeedbackGains[lin, {-0.251, -0.222, -0.222}, "Data"]
Wolfram Language code: csys = ConnectSystemModelController["CLS", mtank, ctrl]
Wolfram Language code: SystemModelPlot[csys, {"y1", "y2"}, 25, <|"Inputs" -> {"u1" -> UnitStep, "u2" -> UnitStep}|>]