WOLFRAM

Wolfram 语言与系统参考资料中心
用神经网络分类数据

用神经网络分类数据

分类向量数据 多任务分类
分类类别数据
分类向量数据
根据三个正态分布的聚类创建一个人工数据集：
Wolfram Language code: makeCluster[class_, μ_, ρ_] := RandomVariate[MultinormalDistribution[μ, {{1, 2ρ}, {2ρ, 4}}], 600] -> class;
Wolfram Language code: clusters = makeCluster@@@{{Red, {1.5, 1.5}, -.2}, {Green, {-1.5, 1}, .1}, {Blue, {0, -2.5}, .8}};
绘制数据集：
Wolfram Language code: plot = ListPlot[Keys[clusters], PlotStyle -> {RGBColor[0.8, 0., 0.], RGBColor[0., 0.8, 0.], RGBColor[0., 0., 0.8]}, AspectRatio -> 1, Frame -> True, PlotRange -> {{-5, 5}, {-5, 5}}]
培训数据包括规则映射点至所在的聚类：
Wolfram Language code: trainingData = Flatten[Thread /@ clusters]; RandomSample[trainingData, 6]
创建一个网络计算点在每个聚类中的概率，使用 "Class" 解码器分类数据为 Red、Green 或 Blue：
Wolfram Language code: net = NetChain[{LinearLayer[30], ElementwiseLayer[Ramp], LinearLayer[3], SoftmaxLayer[]}, "Input" -> {2}, "Output" -> NetDecoder[{"Class", {Red, Green, Blue}}]]
在数据上培训网络：
Wolfram Language code: results = NetTrain[net, trainingData, All] trained = results["TrainedNet"]
计算每个聚类上的中心的网络：
Wolfram Language code: trained[{{1.5, 1}, {-1.5, 1}, {0, -3}}]
显示每个类达到 0.75 后验概率时在特征空间的轮廓：
Wolfram Language code: Show[plot, Quiet@Table[ContourPlot[trained[{x, y}, "Probabilities" -> color] == 0.75, {x, -5, 5}, {y, -5, 5}, ContourStyle -> {Thick, Darker[color, .3]}], {color, {Red, Green, Blue}}]]
绘制由位置函数熵测量的分类器的不确定度：
Wolfram Language code: ArrayPlot[Table[trained[{x, y}, "Entropy"], {y, 5, -4, -.1}, {x, -4, 4, .1}]]
在 Fisher Iris 数据集上执行逻辑回归. 首先，获取培训数据：
Wolfram Language code: trainingData = ExampleData[{"MachineLearning", "FisherIris"}, "TrainingData"]; testData = ExampleData[{"MachineLearning", "FisherIris"}, "TestData"];
Wolfram Language code: RandomSample[trainingData, 5]
构建分配给每个范例的唯一标签列表：
Wolfram Language code: labels = Union[Values[trainingData]]
创建一个 NetChain 执行分类，使用 "Class" 解码器诠释网络的输出为每类的概率：
Wolfram Language code: net = NetChain[{3, SoftmaxLayer[]}, "Input" -> 4, "Output" -> NetDecoder[{"Class", labels}]]
NetTrain 会自动使用带有 NetEncoder 的 CrossEntropyLossLayer 来诠释培训数据中的类标签：
Wolfram Language code: results = NetTrain[net, trainingData, All] trained = results["TrainedNet"]
分类输入：
Wolfram Language code: trained[{6.1, 2.8, 4., 1.3}]
获取与分类相关联的概率：
Wolfram Language code: trained[{6.1, 2.8, 4., 1.3}, "Probabilities"]
使用 NetMeasurements 检验在测试集上被培训的网络的分类性能：
Wolfram Language code: NetMeasurements[trained, testData, "Accuracy"]
Wolfram Language code: NetMeasurements[trained, testData, "ConfusionMatrixPlot"]
分类类别数据
在包含类别和数字值的数据集上执行逻辑回归.
首先，获取培训数据，然后去掉包含丢失数据的行：
Wolfram Language code: data = ExampleData[{"Dataset", "Titanic"}]; data = DeleteMissing[data, 1, 2]
把数据分成培训和测试数据集：
Wolfram Language code: {trainingData, testData} = TakeDrop[RandomSample[data], 800];
分类变量不能直接用在神经网络上，必须编码为数值张量.
创建 "Class" 编码器编码分类变量为单热编码向量：
Wolfram Language code: classEncoder = NetEncoder[{"Class", {"1st", "2nd", "3rd"}, "UnitVector"}] genderEncoder = NetEncoder[{"Class", {"male", "female"}, "UnitVector"}]
把编码器应用于类标签产生单位向量：
Wolfram Language code: classEncoder /@ {"1st", "2nd", "3rd"}
Wolfram Language code: genderEncoder /@ {"male", "female"}
创建一个带有输入的网络对应每个特征，使用 "Boolean" 解码器诠释网络的输出作为生存的概率.
在进一步处理前，输入特征首先级联在一起：
Wolfram Language code: net = NetGraph[{CatenateLayer[], LinearLayer[], LogisticSigmoid, ReshapeLayer[{1}]}, {NetPort["age"] -> 4, {NetPort["class"], 4, NetPort["sex"]} -> 1, 1 -> 2 -> 3 -> NetPort["survived"]}, "class" -> classEncoder, "sex" -> genderEncoder, "survived" -> "Boolean"]
Wolfram Language code: trainingData[[1]]
在培训数据上培训网络. NetTrain 会自动在网络输出上附着一层 CrossEntropyLossLayer["Binary"]：
Wolfram Language code: results = NetTrain[net, trainingData, All, MaxTrainingRounds -> 1000] trained = results["TrainedNet"]
预测乘客是否会生存：
Wolfram Language code: trained[<|"class" -> "2nd", "age" -> 24, "sex" -> "female"|>]
获取与输入相关联的生存概率：
Wolfram Language code: trained[<|"class" -> "2nd", "age" -> 24, "sex" -> "female"|>, None]
绘制 "class" 和 "sex" 相组合的年龄函数的生存概率：
Wolfram Language code: p[class_, age_, sex_] := trained[<|"class" -> class, "age" -> age, "sex" -> sex|>, None];
Wolfram Language code: Plot[{p["1st", x, "female"], p["3rd", x, "female"], p["1st", x, "male"], p["3rd", x, "male"]}, {x, 0, 100}, PlotLegends -> {"female, 1st class", "female, 3rd class", "male, 1st class", "male, 3rd class"}, Frame -> True, FrameLabel -> {"age (years)", "survival probability"}]
使用 NetMeasurements 在测试集上测试培训网络的精确度：
Wolfram Language code: NetMeasurements[trained, testData, "Accuracy"]
精确度可以与指定方法为 "LogisticRegression"，使用 Classify 获得的相比较：
Wolfram Language code: cf = Classify[trainingData -> "survived", Method -> "LogisticRegression"]; ClassifierMeasurements[cf, testData -> "survived", "Accuracy"]
多任务分类
通过创建产生两个独立分类的网络执行多任务学习.
首先获取培训数据：
Wolfram Language code: obj = ResourceObject["CIFAR-100"]
培训数据包含图像以及对应的高级和低级标签：
Wolfram Language code: trainingData = ResourceData[obj, "TrainingDataset"]; RandomSample[trainingData, 5]
从 "Label" 和 "SubLabel" 列中提取唯一标签：
Wolfram Language code: labels = Union@Normal@trainingData[All, "Label"]
Wolfram Language code: sublabels = Union@Normal@trainingData[All, "SubLabel"]
创建会产生 500 个特征的向量的卷积网络：
Wolfram Language code: convnet = NetChain[{ ConvolutionLayer[20, {5, 5}], ElementwiseLayer[Ramp], PoolingLayer[{2, 2}, {2, 2}], ConvolutionLayer[50, {5, 5}], ElementwiseLayer[Ramp], PoolingLayer[{2, 2}, {2, 2}], FlattenLayer[], LinearLayer[500], ElementwiseLayer[Ramp] }, "Input" -> NetEncoder[{"Image", {32, 32}}]]
为高级和低级标签创建一个会产生独立分类的 NetGraph：
Wolfram Language code: net = NetGraph[{convnet, 100, SoftmaxLayer[], 20, SoftmaxLayer[]}, {NetPort["Image"] -> 1 -> 2 -> 3 -> NetPort["SubLabel"], 2 -> 4 -> 5 -> NetPort["Label"]}, "Label" -> NetDecoder[{"Class", labels}], "SubLabel" -> NetDecoder[{"Class", sublabels}]]
培训网络. NetTrain 会自动把 CrossEntropyLossLayer 对象粘贴在输出，使用对应的名称 "Label" 和 "SubLabel" 从培训数据获取目标值：
Wolfram Language code: results = NetTrain[net, trainingData, All, MaxTrainingRounds -> 10] trained = results["TrainedNet"]
在单幅图像上计算培训网络：
Wolfram Language code: trained[[image]]
在多幅图像上计算培训网络，只接受 "SubLabel" 输出：
Wolfram Language code: trained[{[image], [image], [image], [image], [image]}, NetPort@"SubLabel"]
获取输入图像上 "SubLabel" 输出类解码器的属性：
Wolfram Language code: trained[[image], NetPort@"SubLabel" -> {"TopProbabilities", 3}]
从随机采样中，选取网络为 "Label" 产生最高和最低熵预测的图像：
Wolfram Language code: images = RandomSample[Normal[trainingData][[All, "Image"]], 5000];
Wolfram Language code: entropies = trained[images, NetPort@"Label" -> "Entropy"];
Wolfram Language code: Labeled[images[[Ordering[entropies, -10]]], "high entropy"] Labeled[images[[Ordering[entropies, 10]]], "low entropy"]
使用 NetMeasurements 检测网络两个输出的精度：
Wolfram Language code: NetMeasurements[trained, trainingData, {<|"Measurement" -> "Accuracy", "Source" -> "Label", "Key" -> "Acc1"|>, <|"Measurement" -> "Accuracy", "Source" -> "SubLabel", "Key" -> "Acc2"|>}]
产生一个只计算 "SubLabel" 预测的子网络：
Wolfram Language code: subnet = Take[trained, {NetPort["Image"], NetPort["SubLabel"]}]
对单幅图像预测：
Wolfram Language code: subnet[[image]]