WOLFRAM

Wolfram Language & System Documentation Center

Upgrading from:

Graphics`Graphics`

LogPlot, ListLogPlot, and related functions have been added to the built-in Mathematica kernel.
PolarPlot and ListPolarPlot have been added to the built-in Mathematica kernel.
GraphicsGrid has been added to the built-in Mathematica kernel.
BarChart and related functions have been added to the built-in Mathematica kernel.
PieChart has been added to the built-in Mathematica kernel.
Histogram has been added to the built-in Mathematica kernel.
ErrorListPlot is available in the newly created ErrorBar Plotting Package.

New system functions

LogPlot, LogLinearPlot, and LogLogPlot are part of the built-in Mathematica kernel:

Version 5.2 << Graphics`Graphics`; LogPlot[Sinh[x], {x, 0, 3}]
Wolfram Language code: LogPlot[Sinh[x], {x, 0, 3}]

LogPlot and ListLogPlot have the same functionality as LinearLogPlot and LinearLogListPlot:

Version 5.2 << Graphics`Graphics`; LinearLogListPlot[Exp[Range[0, 3, 0.2]]]
Wolfram Language code: ListLogPlot[Exp[Range[0, 3, 0.2]]]

ListLogPlot, ListLogLinearPlot, and ListLogLogPlot have the same functionality as LogListPlot, LogLinearListPlot, and LogLogListPlot:

Version 5.2 << Graphics`Graphics`; LogLogListPlot[Range[10]^2]
Wolfram Language code: ListLogLogPlot[Range[10] ^ 2]

PolarPlot is now part of the built-in Mathematica kernel:

Version 5.2 << Graphics`Graphics`; PolarPlot[Sqrt[t], {t, 0, 20}]
Wolfram Language code: PolarPlot[Sqrt[t], {t, 0, 20}]

ListPolarPlot has the same functionality as PolarListPlot:

Version 5.2 << Graphics`Graphics`; PolarListPlot[Range[0, 10, 0.2]]
Wolfram Language code: ListPolarPlot[Range[0, 10, 0.2]]

Show can be used in place of DisplayTogether since graphics are no longer displayed as side effects:

Version 5.2 << Graphics`Graphics`; DisplayTogether[Plot[x, {x, 0, 1}], Plot[x^2, {x, 0, 1}]]
Wolfram Language code: Show[Plot[x, {x, 0, 1}], Plot[x ^ 2, {x, 0, 1}]]

GraphicsGrid can be used in place of DisplayTogetherArray since graphics are no longer displayed as side effects:

Version 5.2 << Graphics`Graphics`; DisplayTogetherArray[ Table[DensityPlot[Sin[x + a] Cos[y + b], {x, 0, Pi}, {y, 0, Pi}], {a, 0, 2}, {b, 0, 2}]]
Wolfram Language code: GraphicsGrid[Table[DensityPlot[Sin[x + a]Cos[y + b], {x, 0, Pi}, {y, 0, Pi}], {a, 0, 2}, {b, 0, 2}]]

Generate a list plot with text markers:

Version 5.2 << Graphics`Graphics`; TextListPlot[RealDigits[N[Pi]][[1]]]
Wolfram Language code: data = RealDigits[N[Pi]][[1]]; Graphics[{Inset[#, {#, data[[#]]}]}& /@ Range@Length@data, Axes -> True, AxesOrigin -> {0, 0}]

Generate a labeled list plot:

Version 5.2 << Graphics`Graphics`; LabeledListPlot[RealDigits[N[Pi]][[1]]]
Wolfram Language code: data = RealDigits[N[Pi]][[1]]; Graphics[{PointSize[.015], Point[{#, data[[#]]}], Inset[#, Scaled[{.015, 0}, {#, data[[#]]}], Left]}& /@ Range@Length@data, Axes -> True, AxesOrigin -> {0, 0}]

Combine a plot and a list plot:

Version 5.2 << Graphics`Graphics`; ListAndCurvePlot[Range[10], x + Sin[x], {x, 0, 10}]
Wolfram Language code: Show[ListPlot[Range[10]], Plot[x + Sin[x], {x, 0, 10}]]

Display a plot with coordinates scaled by given functions:

Version 5.2 << Graphics`Graphics`; ScaledPlot[Sin[x], {x, 0, \[Pi]}, ScaleFunction -> {Cos, ArcSin}, AxesOrigin -> Automatic, PlotStyle -> Automatic]
Wolfram Language code: ParametricPlot[{Cos[t], ArcSin[Sin[t]]}, {t, 0, Pi}]

Display a list plot with coordinates scaled by given functions:

Version 5.2 << Graphics`Graphics`; ScaledListPlot[Table[Sin[x], {x, 0, \[Pi], .025 \[Pi]}], ScaleFunction -> {# &, ArcSin}, AxesOrigin -> Automatic, PlotStyle -> Automatic]
Wolfram Language code: ListPlot[Table[{x, ArcSin[Sin[x]]}, {x, 0, π, .025π}]]

The functionality of SkewGraphics and TransformGraphics is now available in the built-in Mathematica kernel function GeometricTransformation:

Version 5.2 << Graphics`Graphics`; Show[SkewGraphics[Plot[Sin[x], {x, 0, 2 Pi}], {{1, 1}, {0, 1}}]]
Wolfram Language code: Plot[Sin[x], {x, 0, 2Pi}] /. Graphics[gr_, opts___] :> Graphics[GeometricTransformation[gr, {{1, 1}, {0, 1}}], opts]

Histogram is now a built-in Mathematica function:

Version 5.2 << Graphics`Graphics`; Histogram[{.9, .0, .2, .8, .6, .9, .6, .9, .6, .3}]
Wolfram Language code: Histogram[{.9, .0, .2, .8, .6, .9, .6, .9, .6, .3}, ChartStyle -> Red]

BarChart is now a built-in Mathematica function:

Version 5.2 << Graphics`Graphics`; BarChart[Range[3]]
Wolfram Language code: BarChart[Range[3], ChartLabels -> Range[3], ChartStyle -> Red]

The functionality of PercentileBarChart is now available in BarChart:

Version 5.2 << Graphics`Graphics`; PercentileBarChart[{1, -3, 4, 5, 2, 3}, {3, 6, 4, 3}]
Wolfram Language code: BarChart[{{1, -3, 4, 5, 2, 3}, {3, 6, 4, 3, 0, 0}}//Transpose, ChartLayout -> "Percentile", ChartStyle -> {Red, Blue}]

The functionality of StackedBarChart is now available using ChartLayout in BarChart:

Version 5.2 << Graphics`Graphics`; StackedBarChart[{1, -3, 4, 5, 2, 3}, {3, 6, 4, 3}]
Wolfram Language code: BarChart[{{1, -3, 4, 5, 2, 3}, {3, 6, 4, 3, 0, 0}} // Transpose, ChartLayout -> "Stacked", ChartStyle -> {Red, Blue}]

GeneralizedBarChart can be replaced by the following definition:

Version 5.2 << Graphics`Graphics`; GeneralizedBarChart[{{1, 3, .2}, {4, 9, 1}, {2.1, -6, .5}}, {{3, 5, .5}, {1.5, -2, 1}, {-.4, 2, .5}}, BarOrientation -> Horizontal]
Wolfram Language code: GeneralizedBarChart[ll__, opts___ ? OptionQ] := Module[{d0, a, b, hor = (BarOrientation /. Flatten@{opts}) === Horizontal}, Graphics[{EdgeForm[Black], Table[{d0, a, b} = {ll}[[i, j]];{Hue[.6(i - 1) / (Length@{ll} - 1)], If[hor, Rectangle[{0, d0 - b / 2}, {a, d0 + b / 2}], Rectangle[{d0 - b / 2, 0}, {d0 + b / 2, a}]]}, {i, Length@{ll}}, {j, Length@{ll}[[i]]}]}, FilterRules[{opts}, Options[Graphics]]]] GeneralizedBarChart[{{1, 3, .2}, {4, 9, 1}, {2.1, -6, .5}}, {{3, 5, .5}, {1.5, -2, 1}, {-.4, 2, .5}}, AspectRatio -> 1 / GoldenRatio, Axes -> True, BarOrientation -> Horizontal]

PieChart is now a built-in Mathematica function:

Version 5.2 << Graphics`Graphics`; PieChart[Range[4]]
Wolfram Language code: PieChart[Range[4], ChartLabels -> Range[4], ColorFunction -> (Hue[Rescale[#, {0, 1}, {0, 3 / 4}]]&), SectorOrigin -> 0]
ErrorBar Plotting Package

ErrorListPlot from Graphics`Graphics` is now found in the ErrorBar Plotting Package.

Version 5.2 << Graphics`Graphics` ErrorListPlot[{{1, 0.2}, {2, 0.3}, {1.5, 0.1}, {0.8, 0.25}}]

Load ErrorBarPlots` to use ErrorListPlot functionality:

Wolfram Language code: <<ErrorBarPlots`; ErrorListPlot[{{1, 0.2}, {2, 0.3}, {1.5, 0.1}, {0.8, 0.25}}]

The original package is now available on the web at library.wolfram.com/infocenter/MathSource/6808.