WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

アップグレード情報：

NumberTheory`NumberTheoryFunctions`

SquareFreeQ，PrimePowerQ，KroneckerSymbol，ChineseRemainder，PrimitiveRootが組込みのMathematica カーネル関数に加わった．
NextPrimeとPreviousPrimeが新しく加わった組込みの Mathematica カーネル関数NextPrimeとして利用できるようになった．
Random[Prime,…]が，新しく加わった組込みの Mathematica カーネル関数RandomPrimeとして利用できるようになった．
PrimeFactorListの機能が，強化された組込みの Mathematica カーネル関数FactorIntegerで利用できる．
SqrtModが組込みの Mathematica カーネル関数PowerModとして利用できるようになった．
SqrtModListが新しく加わった組込みの Mathematica カーネル関数PowerModListとして利用できるようになった．
ClassNumberが新しく加わった組込みの Mathematica カーネル関数NumberFieldClassNumberとして利用できるようになった．
SumOfSquaresRが組込みの Mathematica カーネル関数SquaresRとして利用できるようになった．
OrderedSumOfSquaresRepresentationsが組込みの Mathematica カーネル関数PowersRepresentationsとして利用できるようになった．

SquareFreeQ

異なる素数の積には平方因子がない：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; SquareFreeQ[2*3*5*7]
Wolfram Language code: SquareFreeQ[2 * 3 * 5 * 7]

NextPrimeとPreviousPrime

100万以降の最初の素数：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; NextPrime[1000000]
Wolfram Language code: NextPrime[1000000]

100万未満で最後の素数：

Version 5.2 PreviousPrime[1000000]
Wolfram Language code: NextPrime[1000000, -1]

Random[Prime, ...]

10と100の間の素数の乱数：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; Random[Prime, {10, 100}]
Wolfram Language code: RandomPrime[{10, 100}]

PrimeFactorList

有理数の素因数のリストを求める：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; PrimeFactorList[713/41]
Wolfram Language code: FactorInteger[713 / 41][[All, 1]]

PrimePowerQ

単独の素数のベキ乗である数：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; PrimePowerQ[12167]
Wolfram Language code: PrimePowerQ[12167]

ChineseRemainder

x が4を法とする3に等しいか，x が5を法とする4に等しくなるような最小の正の整数 x：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; ChineseRemainder[{3, 4}, {4, 5}]
Wolfram Language code: ChineseRemainder[{3, 4}, {4, 5}]

SqrtModとSqrtModList

が11を法とする3に等しくなるような，最小の非負の整数 を求める：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; SqrtMod[3, 11]
Wolfram Language code: PowerMod[3, 1 / 2, 11]

以下は，関係を満足する11より小さい整数すべてを返す：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; SqrtModList[3, 11]
Wolfram Language code: PowerModList[3, 1 / 2, 11]

ClassNumber

により生成された代数的数体のクラス番号を見付ける：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; ClassNumber[-10099]
Wolfram Language code: NumberFieldClassNumber[Sqrt[-10099]]

FundamentalDiscriminantQ

FundamentalDiscriminantQは次の定義で置き換えることができる：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; FundamentalDiscriminantQ[3243601]
Wolfram Language code: FundamentalDiscriminantQ[n_] := n ≠ 1 && Mod[n, 4] == 1 && SquareFreeQ[n] || !(Mod[n, 16] ≠ 8 ≠ 12) && SquareFreeQ[Quotient[n, 4]] FundamentalDiscriminantQ[3243601]

ClassList

ClassListは次の定義で置き換えることができる：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; ClassList[-403]
Wolfram Language code: ClassList[n_ ? Negative] := Select[Flatten[#, 1]&@Table[ {i, j, (j ^ 2 - n) / (4i)}, {i, Sqrt[-n / 3]}, {j, 1 - i, i}], Mod[#3, 1] == 0 && #3 ≥ # && GCD[##] == 1 && !(# == #3 && #2 < 0)&@@#&] ClassList[-403]

KroneckerSymbol

クロネッカー記号を見付ける：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; KroneckerSymbol[5, 3]
Wolfram Language code: KroneckerSymbol[5, 3]

SumOfSquares

100を3つの平方の和として表す方法が何通りあるか：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; SumOfSquaresR[3, 100]
Wolfram Language code: SquaresR[3, 100]

SumOfSquaresRepresentations

SumOfSquaresRepresentationsは次の定義で置換することができる：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; SumOfSquaresRepresentations[3, 100]
Wolfram Language code: SumOfSquaresRepresentations[d_, n_] := Module[{x, a, sol}, a = Array[x, d]; sol = Reduce[a.a == n, a, Integers];If[sol === False, {}, a /. {ToRules[sol]}]]
Wolfram Language code: SumOfSquaresRepresentations[3, 100]

OrderedSumOfSquaresRepresentations

100を3つの平方の和として表す順序のリスト：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; OrderedSumOfSquaresRepresentations[3, 100]
Wolfram Language code: Reverse /@ PowersRepresentations[100, 3, 2]

LeastPrimeFactor

LeastPrimeFactorは次の定義で置き換えることができる：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; LeastPrimeFactor[3243601]
Wolfram Language code: LeastPrimeFactor[n_Integer /; n > 1] := Prime@NestWhile[# + 1&, 1, Mod[n, Prime[#]] ≠ 0&] LeastPrimeFactor[3243601]

QuadraticRepresentation

QuadraticRepresentationは次の定義で置き換えることができる：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; QuadraticRepresentation[3, 4410796736359]
Wolfram Language code: QuadraticRepresentation[d_, n_] := Module[{x, y, ans}, ans = FindInstance[{x ^ 2 + d y ^ 2 == n, x ≥ 0, y ≥ 0}, {x, y}, Integers, 1]; ({x, y} /. ans[[1]]) /; Head@ans =!= FindInstance] QuadraticRepresentation[3, 4410796736359]

これが本当に可能な表現のひとつであるかどうかを確かめる：

Wolfram Language code: {1, 3}.% ^ 2 == 4410796736359

SumOfFactors

より小さい の因数の和を計算する：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; SumOfFactors[360]
Wolfram Language code: DivisorSigma[1, 360] - 360

WhichRootOfUnity

WhichRootOfUnityは次の定義で置き換えることができる：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; WhichRootOfUnity[Sqrt[(5 - Sqrt[5])/8] - I (1 + Sqrt[5])/4]
Wolfram Language code: WhichRootOfUnity[z_] := Module[{d, ans}, If[z == 1, Return[{1, 1}]]; (ans = FullSimplify[Arg[z] / (2Pi)]; {d = Denominator[ans], Mod[Numerator[ans], d]} /; MatchQ[ans, _Rational]) /; PossibleZeroQ[Abs[z] - 1]] WhichRootOfUnity[Sqrt[(5 - Sqrt[5]) / 8] - I(1 + Sqrt[5]) / 4]

AliquotSequence

AliquotSequenceは次の定義で置き換えることができる：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; AliquotSequence[220]
Wolfram Language code: AliquotSequence[n_] := NestWhileList[DivisorSigma[1, #] - #&, n, Unequal[##, 0]&, All] AliquotSequence[220]

AliquotCycle

AliquotCycleは次の定義で置き換えることができる：

Version 5.2 << NumberTheory`NumberTheoryFunctions`; AliquotCycle[562]
Wolfram Language code: AliquotCycle[n_] := NestWhileList[DivisorSigma[1, #] - #&, n, Unequal[##, 0]&, All] /. {{___, 0} :> {0}, {___, i_, s___, i_} :> RotateLeft[{i, s}, Position[{i, s}, Min@{i, s}, {1}, 1][[1, 1]] - 1]} AliquotCycle[562]

もとのパッケージはWeb (library.wolfram.co.jp/infocenter/MathSource/6774)で利用できるようになった．