WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Enclose[expr]

expr を評価し，キャッチされないエラーが生成されたらFailureを返す．

Enclose[expr,f]

キャッチされたエラー err には f[err] を返す．

Enclose[expr,f,tag]

tag と一致するタグで生成されたエラーのみをキャッチする．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
考えられる問題  
関連項目
関連するガイド
引用書式

Enclose

Enclose[expr]

expr を評価し，キャッチされないエラーが生成されたらFailureを返す．

Enclose[expr,f]

キャッチされたエラー err には f[err] を返す．

Enclose[expr,f,tag]

tag と一致するタグで生成されたエラーのみをキャッチする．

詳細

  • Enclose[expr,…]は，評価中にエラーがキャッチされなければ，expr の値を返す． »
  • Encloseは，すでに内側のEncloseによってキャッチされたエラーは検知しない．
  • タグが与えられていない場合，Encloseはタグなしで語彙的に含まれるすべての確認関数にタグを加える． »
  • tag はどのような式でもよい（パターンでもよい）．
  • Confirm，ConfirmBy，ConfirmMatch，ConfirmQuiet， ConfirmAssertがスローするエラーをキャッチする．
  • Encloseは，特殊なタグを持つCatchを効果的に呼び出す．
  • f のデフォルト値はIdentityである．
  • f が文字列の場合，f[err]の代りに err[f]が返される． »

例題

すべて開く すべて閉じる

例  (2)

式を評価し，エラーが生成されたらすぐに終了する：

Wolfram Language code: Enclose[2 + 2]
Wolfram Language code: Enclose[2 + 2;Confirm[$Failed];4 + 4]

強力な関数を作成する：

Wolfram Language code: addtwo[x_] := Enclose[ConfirmBy[x, NumberQ] + 2]
Wolfram Language code: addtwo[4]
Wolfram Language code: addtwo[x]

スコープ  (6)

返す前にエラーを処理する：

Wolfram Language code: Enclose[2 + 2;Confirm[$Failed];4 + 4, f]

"Expression"に f を設定し，エラーをFailureで包まずに伝播する：

Wolfram Language code: Enclose[f[Confirm[Missing["NA"]]], "Expression"]

最も内側のEncloseが最優先される：

Wolfram Language code: Enclose[a;Enclose[b;Confirm[$Failed];c];d]

タグを使ってエラーを外側のEncloseに渡す：

Wolfram Language code: Enclose[a;Enclose[b;Confirm[$Failed, None, "tag"];c];d, Identity, "tag"]

エラーが発生した場合に固定値を返すために，f の定数関数を与える：

Wolfram Language code: Enclose[2 + 2;Confirm[$Failed];4 + 4, foo&]

エラーを複数レベルに伝播する：

Wolfram Language code: addtwo[x_] := Enclose[Confirm[x] + 2] framedAddtwo[x_] := Enclose[Framed[Confirm[addtwo[x]]]]
Wolfram Language code: framedAddtwo[5]
Wolfram Language code: framedAddtwo[$Failed]

確認をネストさせて複数回確認する：

Wolfram Language code: Enclose[f[ConfirmBy[ConfirmMatch[x, _Integer], EulerPhi[#] > 3&]]]

アプリケーション  (3)

失敗する可能性のある関数を安全に呼び出し，エラーを変更せずに伝播する：

Wolfram Language code: cityPopulation[s_] := Enclose[Confirm[Interpreter["City"][s]]["Population"], "Expression"]
Wolfram Language code: cityPopulation["nyc"]
Wolfram Language code: cityPopulation["null island"]

すべての国の一人当りのGDPを計算し，欠損値を伝播する：

Wolfram Language code: Short[Enclose[Confirm[#[[1]]] / Confirm[#[[2]]], Missing[]&]& /@ EntityValue["Country", {"GDP", "Population"}]]

BoundaryMeshRegionが使用できない多面体を無視して，頂点の各ペアの間に辺がある多面体をすべて検索する：

Wolfram Language code: Keys[Select[EntityValue["Polyhedron", "BoundaryMeshRegion", "EntityAssociation"], Enclose[CompleteGraphQ[MeshConnectivityGraph[Confirm[#], 2]], False&]&]]

考えられる問題  (3)

Catch[…,_]は，エラーが傍受できる：

Wolfram Language code: Enclose[Catch[Confirm[$Failed], _];d]

EncloseはThrowがスローした式はキャッチしない：

Wolfram Language code: Enclose[Throw[a];b]

タグが与えられないと，EncloseはConfirmのようなシンボルをタグ付きの異形と語彙的に置換する：

Wolfram Language code: Enclose[f[g[Confirm]]]
Wolfram Research (2020), Enclose, Wolfram言語関数， https://reference.wolfram.com/language/ref/Enclose.html.

テキスト

Wolfram Research (2020), Enclose, Wolfram言語関数， https://reference.wolfram.com/language/ref/Enclose.html.

CMS

Wolfram Language. 2020. "Enclose." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Enclose.html.

APA

Wolfram Language. (2020). Enclose. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Enclose.html

BibTeX

@misc{reference.wolfram_2026_enclose, author="Wolfram Research", title="{Enclose}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/Enclose.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_enclose, organization={Wolfram Research}, title={Enclose}, year={2020}, url={https://reference.wolfram.com/language/ref/Enclose.html}, note=[Accessed: 16-August-2026]}