WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

RDFCollection[{e1,e2,…}]

RDFStoreやSPARQLSelectのような関数の，eiのリスト状の集合を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
考えられる問題  
関連項目
関連するガイド
引用書式
GraphStore`
GraphStore`

RDFCollection

RDFCollection[{e1,e2,…}]

RDFStoreやSPARQLSelectのような関数の，eiのリスト状の集合を表す．

詳細とオプション

  • RDFの語彙集合には次の項が含まれる．
  • URL["http://www.w3.org/1999/02/22-rdf-syntax-ns#first"]集合をその第1要素にリンクする
    URL["http://www.w3.org/1999/02/22-rdf-syntax-ns#rest"]集合を残りにリンクする
    URL["http://www.w3.org/1999/02/22-rdf-syntax-ns#nil"]空白集合

例題

すべて開く すべて閉じる

例  (1)

Wolfram Language code: Needs["GraphStore`"]

Bobが好む果物をリストにするグラフを指定する：

Wolfram Language code: ex[s_] := URL["http://example.org/" <> s];
Wolfram Language code: RDFStore[{ RDFTriple[ex["bob"], ex["favoriteFruits"], RDFCollection[{ex["mango"], ex["strawberry"]}]] }]

スコープ  (2)

Wolfram Language code: Needs["GraphStore`"]

文字の集合を含むRDFグラフを指定する：

Wolfram Language code: rdf[s_] := URL["http://www.w3.org/1999/02/22-rdf-syntax-ns#" <> s]; ex[s_] := URL["http://example.org/" <> s];
Wolfram Language code: g = RDFStore[{ RDFTriple[ex["a"], ex["list"], RDFCollection[{"a", "b", "c"}]] }];

3つの要素を含む集合があるかどうかチェックする：

Wolfram Language code: g//SPARQLAsk[RDFTriple[SPARQLVariable["x"], SPARQLVariable["y"], RDFCollection[{SPARQLVariable["e1"], SPARQLVariable["e2"], SPARQLVariable["e3"]}]]]

真ん中の要素を取り出す：

Wolfram Language code: g//SPARQLSelect[RDFTriple[SPARQLVariable["x"], SPARQLVariable["y"], RDFCollection[{SPARQLVariable["e1"], SPARQLVariable["e2"], SPARQLVariable["e3"]}]] -> "e2"]

すべての要素を取り出す：

Wolfram Language code: g//SPARQLSelect[{ RDFTriple[ex["a"], ex["list"], SPARQLVariable["l"]], SPARQLPropertyPath[SPARQLVariable["l"], {rdf["rest"]..., rdf["first"]}, SPARQLVariable["x"]] } -> "x"]
Wolfram Language code: Needs["GraphStore`"]

異なる2つの方法でRDFグラフを指定する：

Wolfram Language code: rdf[s_] := URL["http://www.w3.org/1999/02/22-rdf-syntax-ns#" <> s]; ex[s_] := URL["http://example.org/" <> s];
Wolfram Language code: g1 = RDFStore[{ RDFTriple[ex["a"], ex["list"], RDFCollection[{1, 2}]] }];
Wolfram Language code: g2 = RDFStore[{ RDFTriple[ex["a"], ex["list"], RDFBlankNode["a"]], RDFTriple[RDFBlankNode["a"], rdf["first"], 1], RDFTriple[RDFBlankNode["a"], rdf["rest"], RDFBlankNode["b"]], RDFTriple[RDFBlankNode["b"], rdf["first"], 2], RDFTriple[RDFBlankNode["b"], rdf["rest"], rdf["nil"]] }];

RDFグラフは同型である：

Wolfram Language code: iso = SelectFirst[ AssociationThread[ Cases[First[g2], _RDFBlankNode, {2}], # ]& /@ Permutations[Cases[First[g1], _RDFBlankNode, {2}]], ContainsExactly[First[g1], First[g2] /. #]& ]
Wolfram Language code: ContainsExactly[First[g1], First[g2] /. iso]

考えられる問題  (1)

Wolfram Language code: Needs["GraphStore`"]

RDFは組込みのリストデータ型を持たない：

Wolfram Language code: ex[s_] := URL["http://example.org/" <> s];
Wolfram Language code: ExportString[ RDFStore[{ RDFTriple[ex["a"], ex["numberList"], {1, 2}] }], "Turtle" ]

代りにRDFの集合を使う：

Wolfram Language code: ExportString[ RDFStore[{ RDFTriple[ex["a"], ex["numberList"], RDFCollection[{1, 2}]] }], "Turtle", "Prefixes" -> <|"ex" -> "http://example.org/"|> ]

リスト値ではない特性を選択して，それに複数の値を割り当てることもできる：

Wolfram Language code: ExportString[ RDFStore[{ RDFTriple[ex["a"], ex["number"], 1], RDFTriple[ex["a"], ex["number"], 2] }], "Turtle", "Prefixes" -> <|"ex" -> "http://example.org/"|> ]
Wolfram Research (2019), RDFCollection, Wolfram言語関数， https://reference.wolfram.com/language/GraphStore/ref/RDFCollection.html.

テキスト

Wolfram Research (2019), RDFCollection, Wolfram言語関数， https://reference.wolfram.com/language/GraphStore/ref/RDFCollection.html.

CMS

Wolfram Language. 2019. "RDFCollection." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/GraphStore/ref/RDFCollection.html.

APA

Wolfram Language. (2019). RDFCollection. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/GraphStore/ref/RDFCollection.html

BibTeX

@misc{reference.wolfram_2026_rdfcollection, author="Wolfram Research", title="{RDFCollection}", year="2019", howpublished="\url{https://reference.wolfram.com/language/GraphStore/ref/RDFCollection.html}", note=[Accessed: 08-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_rdfcollection, organization={Wolfram Research}, title={RDFCollection}, year={2019}, url={https://reference.wolfram.com/language/GraphStore/ref/RDFCollection.html}, note=[Accessed: 08-August-2026]}