WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Adjugate[m]

正方行列 m の随伴行列を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
特殊行列  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

Adjugate

Adjugate[m]

正方行列 m の随伴行列を与える．

詳細

  • 随伴行列は古典随伴行列としても知られている．
  • 可逆行列 m の随伴行列はInverse[m]Det[m]で与えられる．
  • 行列 m とその随伴行列の行列積は，行列式 m に m と同じ大きさの恒等行列を掛けたものに等しい．
  • 行列 m は数値行列でも記号行列でもよいが，正方行列でなければならない．
  • Adjugate[m]は，StandardFormとTraditionalFormでは とフォーマットされる． »

例題

すべて開く すべて閉じる

例  (3)

2×2行列の随伴行列を計算する：

Wolfram Language code: Adjugate[{{5, 4}, {4, 11}}]

記号行列の随伴行列を計算する：

Wolfram Language code: m = {{a, b}, {c, d}};
Wolfram Language code: Adjugate[m]//MatrixForm

3×3行列の随伴行列を計算する：

Wolfram Language code: m = {{15, 3, 4}, {3, 15, 11}, {-2, 1, 7}};

m との関係を確認する：

Wolfram Language code: Adjugate[m].m == Det[m]IdentityMatrix[Length[m]]

スコープ  (10)

基本的な用法  (6)

機械精度行列の随伴行列：

Wolfram Language code: Adjugate[{{43.2, 25.1}, {27.1, 41.2}}]

複素行列の随伴行列：

Wolfram Language code: Adjugate[{{E^5, 1, 3 - 2I}, {1 + I, (π/2), 5}, {0, 1, -4}}]//MatrixForm

厳密行列の随伴行列：

Wolfram Language code: Adjugate[{{4, 3}, {3, 4}}]

任意精度行列の随伴行列：

Wolfram Language code: N[{{π, Sqrt[2], E}, {(1/Sqrt[2]), 1 + Sqrt[2], 2 π}, {-(1/Sqrt[2]) + 2 π, -1 + Sqrt[2], 2 E - 2 π}}, 12]//MatrixForm
Wolfram Language code: Adjugate[%]//MatrixForm

記号行列の随伴行列：

Wolfram Language code: Adjugate[{{a, b, c}, {d, e, f}, {g, h, i}}]//MatrixForm

出力のフォーマット：

Wolfram Language code: Adjugate[m]

特殊行列  (4)

疎な行列の随伴行列は正規行列として返される：

Wolfram Language code: SparseArray[{{1, 3} -> 1, {2, 2} -> 2, {3, 1} -> 3}, {3, 3}]
Wolfram Language code: Adjugate[%]

構造化行列の随伴行列：

Wolfram Language code: SymmetrizedArray[{{1, 1} -> 3, {2, 2} -> 1, {3, 1} -> -5}, {3, 3}, Symmetric[All]]
Wolfram Language code: Adjugate[%]
Wolfram Language code: QuantityArray[Partition[Range[9], 3], {"Meters", "Seconds", "Kilograms"}]
Wolfram Language code: Adjugate[%]

恒等行列はそれ自体の随伴行列である：

Wolfram Language code: Adjugate[IdentityMatrix[3]]

ヒルベルト(Hilbert)行列の随伴行列：

Wolfram Language code: Adjugate[HilbertMatrix[5]]

アプリケーション  (4)

Adjugateを使って余因子を計算する：

Wolfram Language code: cofactor[m_, {i_, j_}] := Adjugate[m][[j, i]]
Wolfram Language code: m = (⁠| | | | | | | - | - | - | - | - | | 6 | 0 | 4 | 9 | 5 | | 1 | 9 | 3 | 1 | 2 | | 5 | 4 | 5 | 3 | 8 | | 3 | 9 | 8 | 2 | 5 | | 4 | 1 | 6 | 6 | 4 |⁠);
Wolfram Language code: cofactor[m, {1, 3}]

関数cofactorを確認する：

Wolfram Language code: Apply[And, Table[cofactor[m, {i, j}] == (-1) ^ (i + j)Det[Drop[m, {i}, {j}]], {i, Length[m]}, {j, Length[m]}], {0, 1}]

Adjugateを使って行列の逆行列を計算する：

Wolfram Language code: m = {{1, 3, 5}, {7, 1, -1}, {8, 4, 1}};
Wolfram Language code: 1 / Det[m] Adjugate[m]//MatrixForm

Inverseと比較する：

Wolfram Language code: Inverse[m]//MatrixForm

Adjugateを使って線形方程式を解く：

Wolfram Language code: m = {{1, 1, 1}, {1, 2, 3}, {1, 4, 9}}; b = {1, 2, 3};
Wolfram Language code: Adjugate[m].b / Det[m]

LinearSolveと比較する：

Wolfram Language code: LinearSolve[m, b]

陰的デカルト方程式として表された曲面のガウスの曲率を計算する関数を定義する：

Wolfram Language code: gaussianCurvature[f_, {x_, y_, z_}] := Module[{grad, hess}, grad = Grad[f, {x, y, z}]; hess = Grad[grad, {x, y, z}]; grad.Adjugate[hess].grad / (grad.grad) ^ 2]

正20面体対称曲面の陰的デカルト方程式：

Wolfram Language code: icosurf[x_, y_, z_] := 1 - x^2 - y^2 - 2 x (x^4 - 10 x^2 y^2 + 5 y^4) z - z^2 + 5 (x^2 + y^2)^2 z^2 - 5 (x^2 + y^2) z^4 + z^6 - (x^2 + y^2 + z^2)^3

上記のガウスの曲率を計算する：

Wolfram Language code: icogc[x_, y_, z_] = Simplify[gaussianCurvature[icosurf[x, y, z], {x, y, z}]];
Wolfram Language code: Short[%, 10]

ガウスの曲率の正（赤）と負（青）の領域を曲面上に可視化する：

Wolfram Language code: ContourPlot3D[icosurf[x, y, z] == 0, {x, -9 / 8, 9 / 8}, {y, -9 / 8, 9 / 8}, {z, -9 / 8, 9 / 8}, ColorFunction -> Function[{x, y, z}, ColorData["ThermometerColors"][LogisticSigmoid[10icogc[x, y, z]]]], ColorFunctionScaling -> False, Mesh -> None, PlotPoints -> 31]

特性と関係  (5)

m.Adjugate[m]はDet[m]に同じサイズの恒等行列を掛けたものに等しい：

Wolfram Language code: m = {{1, 3, 5}, {7, 1, -1}, {8, 4, 1}};
Wolfram Language code: m.Adjugate[m] == Det[m]IdentityMatrix[Length[m]]

Inverse[m]は随伴行列を行列式で割ったものに等しい：

Wolfram Language code: m = {{1, 3, 5}, {7, 1, -1}, {8, 4, 1}};
Wolfram Language code: Inverse[m] == Adjugate[m] / Det[m]

n×n 行列 m について，Adjugate[m]はLinearSolve[m,Det[m]IdentityMatrix[n]]に等しい：

Wolfram Language code: m = {{1, 3, 5}, {7, 1, -1}, {8, 4, 1}};
Wolfram Language code: Adjugate[m] == LinearSolve[m, Det[m]IdentityMatrix[Length[m]]]

n×n 行列 m について，Det[Adjugate[m]]==Det[m]n-1である：

Wolfram Language code: m = {{1, 3, 5}, {7, 1, -1}, {8, 4, 1}};
Wolfram Language code: Det[Adjugate[m]] == Det[m]^Length[m] - 1

Minors[m]はAdjugateを使って計算できる：

Wolfram Language code: m = RandomInteger[9, {5, 5}]; Reverse[Minors[m], {1, 2}] == Transpose[Adjugate[m]]Table[(-1) ^ (i + j), {i, Length[m]}, {j, Length[m]}]

考えられる問題  (1)

随伴行列は正方行列についてしか定義されない：

Wolfram Language code: Adjugate[{{1, 3, 4}, {2, 5, 6}}]

おもしろい例題  (2)

正方行列の余因子多項式を計算するための関数を定義する：

Wolfram Language code: adjugatePolynomial[A_ ? SquareMatrixQ, x_] := With[{n = Length[A]}, Sum[Sum[Product[((-1)^id[[l]] + 1/l^id[[l]](id[[l]]!))Tr[MatrixPower[A, l]]^id[[l]], {l, n - 1}], {id, FrobeniusSolve[Range[n - 1], n - s - 1]}]x^s, {s, 0, n - 1}]]

行列の余因子多項式を計算する：

Wolfram Language code: m = {{1, 1, 1}, {1, 2, 3}, {1, 4, 9}};
Wolfram Language code: ap[x_] = adjugatePolynomial[m, x]

行列の余因子多項式を行列自体において評価すると随伴行列が与えられる：

Wolfram Language code: MatrixFunction[ap, m]//FullSimplify
Wolfram Language code: Adjugate[m]

正方行列の反復余因子を計算する関数を定義する：

Wolfram Language code: iteratedAdjugate[A_ ? SquareMatrixQ, k_Integer ? NonNegative] := With[{n = Length[A]}, Det[A]^((n - 1)^k - (-1)^k/n) - Boole[OddQ[k]]If[OddQ[k], Adjugate[A], A]]

行列の最初のいくつかの反復を計算する：

Wolfram Language code: m = {{1, 3, 5}, {7, 1, -1}, {8, 4, 1}};
Wolfram Language code: Table[iteratedAdjugate[m, k], {k, 0, 5}]

上記はNestListをAdjugateと一緒に使うことに等しい：

Wolfram Language code: NestList[Adjugate, m, 5]
Wolfram Research (2021), Adjugate, Wolfram言語関数， https://reference.wolfram.com/language/ref/Adjugate.html.

テキスト

Wolfram Research (2021), Adjugate, Wolfram言語関数， https://reference.wolfram.com/language/ref/Adjugate.html.

CMS

Wolfram Language. 2021. "Adjugate." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Adjugate.html.

APA

Wolfram Language. (2021). Adjugate. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Adjugate.html

BibTeX

@misc{reference.wolfram_2026_adjugate, author="Wolfram Research", title="{Adjugate}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/Adjugate.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_adjugate, organization={Wolfram Research}, title={Adjugate}, year={2021}, url={https://reference.wolfram.com/language/ref/Adjugate.html}, note=[Accessed: 16-August-2026]}