WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AnatomyStyling[g]

AnatomyPlot3Dで使われるグラフィックス指示子で，解剖学的実体に基づいたグラフィックスオブジェクトをグラフィックス指示子または指示子 g の連想を使ってどのように描画するかを指定する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

AnatomyStyling

AnatomyStyling[g]

AnatomyPlot3Dで使われるグラフィックス指示子で，解剖学的実体に基づいたグラフィックスオブジェクトをグラフィックス指示子または指示子 g の連想を使ってどのように描画するかを指定する．

詳細

  • AnatomyStylingの使用にはインターネット接続が必要なことがある．
  • AnatomyStyling[]は顔は描かない．
  • AnatomyStyling["Natural"]は，前に使った指示子を無視して，解剖学的実体に基づいたグラフィックスオブジェクトを初期状態で回復する．
  • AnatomyStylingには，解剖学的実体に対応するキーと指示子に対応する値を持つAssociationを使うことができる．
  • AnatomyStylingは，AnatomyPlot3D内の他のプリミティブの一部ではない解剖学的実体にのみ適用される．

例題

すべて開く すべて閉じる

例  (1)

腕の中の上腕二頭筋を緑で彩色する：

Wolfram Language code: AnatomyPlot3D[{AnatomyStyling[<|Entity["AnatomicalStructure", "BicepsBrachii"] -> Green|>], Entity["AnatomicalStructure", "LeftArm"]}]

左腎を緑で彩色する：

Wolfram Language code: AnatomyPlot3D[{AnatomyStyling[<|Entity["AnatomicalStructure", "LeftKidney"] -> Green|>], Entity["AnatomicalStructure", "Kidney"]}]

左手の人指し指にカスタムの照明を適用する：

Wolfram Language code: AnatomyPlot3D[{AnatomyStyling[<|Entity["AnatomicalStructure", "LeftIndexFinger"] -> (Lighting -> {{"Ambient", GrayLevel[.3]}, {"Directional", Blue, ImageScaled[{1, 1, 1}]}})|>], Entity["AnatomicalStructure", "SkeletonOfLeftHand"]}]

スコープ  (5)

ある実体についてのEdgeFormを変更する．これは，すべてのオブジェクトに影響するスタンドアロンのEdgeForm指示子を使って行うことができる：

Wolfram Language code: AnatomyPlot3D[{EdgeForm[{Thick, Blue}], Entity["AnatomicalStructure", "LeftFemur"], Cuboid[{200, -44, 550}, {222, 44, 575}]}]

解剖学的実体のみに適用されるAnatomyStylingを使うこともできる：

Wolfram Language code: AnatomyPlot3D[{AnatomyStyling[EdgeForm[{Thick, Blue}]], Entity["AnatomicalStructure", "LeftFemur"], Cuboid[{200, -44, 550}, {222, 44, 575}]}]

AnatomyStylingは，引数なしで使うとFaceForm[]のように振る舞う：

Wolfram Language code: AnatomyPlot3D[{AnatomyStyling[], EdgeForm[Blue], Entity["AnatomicalStructure", "SeventhCervicalVertebra"]}]

AnatomyStyling["Natural"]は，前に使った指示子を無視してもとの状態のスタイルを回復する：

Wolfram Language code: AnatomyPlot3D[{Red, Entity["AnatomicalStructure", "SeventhCervicalVertebra"], AnatomyStyling["Natural"], Entity["AnatomicalStructure", "FirstThoracicVertebra"]}]

次の例は，この関数が上腕二頭筋のような「中間」構造を（たとえそれがより小さい原子的な成分から作られたものであっても）処理できることを示している：

Wolfram Language code: AnatomyPlot3D[{AnatomyStyling[<|Entity["AnatomicalStructure", "BicepsBrachii"] -> Green|>], Entity["AnatomicalStructure", "LeftArm"]}]

次の例は，より下位レベルの原子的な構造に別々にアクセスできることを示している：

Wolfram Language code: AnatomyPlot3D[{AnatomyStyling[<|Entity["AnatomicalStructure", "LongHeadOfLeftBicepsBrachii"] -> Green, Entity["AnatomicalStructure", "ShortHeadOfLeftBicepsBrachii"] -> Blue|>], Entity["AnatomicalStructure", "LeftArm"]}]

次の例は，筋肉（あるいは任意の他の実体）をある特定の色に塗り，それを除いた他のすべてのオブジェクトを別の1色で塗れることを示している：

Wolfram Language code: AnatomyPlot3D[{AnatomyStyling[<|_ -> Red, Entity["AnatomicalStructure", "Muscle"] -> Blue|>], Entity["AnatomicalStructure", "LeftArm"]}]

選択した筋肉に切取り平面を適用する：

Wolfram Language code: GraphicsRow[{AnatomyPlot3D[{AnatomyStyling[<|Entity["AnatomicalStructure", "BicepsBrachii"] -> Directive[Green]|>], Entity["AnatomicalStructure", "LeftArm"]}], AnatomyPlot3D[{AnatomyStyling[<|Entity["AnatomicalStructure", "BicepsBrachii"] -> Directive[Green, ClipPlanes -> {InfinitePlane[{{183, -57, 1156}, {175, -69, 1139}, {179, -65, 1153}}]}]|>], Entity["AnatomicalStructure", "LeftArm"]}]}]

おもしろい例題  (1)

「逆光」とX線の効果を組み合せたシミュレーションを行う：

Wolfram Language code: reverselights = Join[{{"Ambient", Black}}, Table[{"Directional", Hue[.58, .5, 1], ImageScaled[{Sin[x], Cos[x], -.5}]}, {x, 0, 2 Pi - 2 Pi / 8, 2 Pi / 8}]];
Wolfram Language code: AnatomyPlot3D[{AnatomyStyling[<|_ -> Directive[Specularity[White, 50], Hue[.58, 0, 1, .1], Lighting -> reverselights], Entity["AnatomicalStructure", "LeftHumerus"] -> Red|>], Entity["AnatomicalStructure", "LeftArm"]}, Background -> Hue[.58, 1, .3], SphericalRegion -> True]
Wolfram Research (2019), AnatomyStyling, Wolfram言語関数， https://reference.wolfram.com/language/ref/AnatomyStyling.html.

テキスト

Wolfram Research (2019), AnatomyStyling, Wolfram言語関数， https://reference.wolfram.com/language/ref/AnatomyStyling.html.

CMS

Wolfram Language. 2019. "AnatomyStyling." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AnatomyStyling.html.

APA

Wolfram Language. (2019). AnatomyStyling. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AnatomyStyling.html

BibTeX

@misc{reference.wolfram_2026_anatomystyling, author="Wolfram Research", title="{AnatomyStyling}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/AnatomyStyling.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_anatomystyling, organization={Wolfram Research}, title={AnatomyStyling}, year={2019}, url={https://reference.wolfram.com/language/ref/AnatomyStyling.html}, note=[Accessed: 10-August-2026]}