WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Annulus[{x,y},{rinner,router}]

{x,y}を中心とする，内半径 rinner，外半径 routerのアニュラスを表す．

Annulus[{x,y},{rinner,router},{θ1,θ2}]

角度 θ1から θ2までのアニュラスを表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
グラフィックス  
指定  
スタイリング  
座標  
領域  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

Annulus

Annulus[{x,y},{rinner,router}]

{x,y}を中心とする，内半径 rinner，外半径 routerのアニュラスを表す．

Annulus[{x,y},{rinner,router},{θ1,θ2}]

角度 θ1から θ2までのアニュラスを表す．

詳細とオプション

  • Annulusは，穴あき円板としても知られている．
  • Annulusは，幾何学領域およびグラフィックスプリミティブとして使うことができる．
  • Annulus[]はAnnulus[{0,0},{1/2,1}]に等しい．
  • Annulus[r]はAnnulus[{0,0},{r/2,r}]に等しい．
  • Annulus[{rinner,router}]はAnnulus[{0,0},{rinner,router}]に等しい．
  • Annulusは，塗り潰された領域{p|r_(inner)<=TemplateBox[{{p, -, {{, {x, ,, y}, }}}}, Norm]<=r_(outer)}あるいは{p|r_(inner)<=TemplateBox[{{p, -, {{, {x, ,, y}, }}}}, Norm]<=r_(outer)} intersection Disk[{x,y},r_(outer),{theta_1,theta_2}]を表す．
  • Annulusは，およびを許容する．
  • 角度は，正の x 方向からラジアン単位で反時計回りに測られる．
  • AnnulusはGraphicsで使うことができる．
  • グラフィックスでは，{xi,yi}はDynamic式でよい．
  • グラフィックスの描画は，FaceForm，EdgeForm等の指示子および色の影響を受ける．

例題

すべて開く すべて閉じる

例  (4)

標準的なアニュラス：

Wolfram Language code: Annulus[]
Wolfram Language code: Graphics[Annulus[]]

アニュラスの一部：

Wolfram Language code: Graphics[{Orange, Annulus[{0, 0}, {1 / 2, 1}, {0, 3Pi / 2}]}]

さまざまなスタイルのアニュラス：

Wolfram Language code: {Graphics[{Pink, Annulus[]}], Graphics[{EdgeForm[Thick], Pink, Annulus[]}], Graphics[{EdgeForm[Dashed], Pink, Annulus[]}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, Annulus[]}]}

アニュラスのAreaを求める：

Wolfram Language code: Area[Annulus[{0, 0}, {1 / 2, 1}]]

アニュラスのスライスの面積：

Wolfram Language code: Area[Annulus[{0, 0}, {r / 2, r}, {0, 3Pi / 2}]]

スコープ  (17)

グラフィックス  (7)

指定  (4)

半径を指定する：

Wolfram Language code: Graphics[{Red, Annulus[1], Green, Annulus[3], Blue, Annulus[7]}]

中心を指定する：

Wolfram Language code: Graphics[{Red, Annulus[{0, 0}, {1, 2}], Green, Annulus[{1, 1}, {1, 2}], Blue, Annulus[{2, 2}, {1, 2}]}]

アニュラスの一部：

Wolfram Language code: Graphics[Annulus[{0, 0}, {1, 2}, {0, 3Pi / 2}]]
Wolfram Language code: Graphics[Annulus[{0, 0}, {1, 2}, {-2Pi / 3, -1Pi / 3}]]

原点における基本的なアニュラスの短縮形：

Wolfram Language code: Graphics[Annulus[], Frame -> True]

スタイリング  (2)

色指示子で各アニュラスの表面色を指定する：

Wolfram Language code: Table[Graphics[{c, Annulus[]}], {c, {Red, Green, Blue, Yellow}}]

FaceFormおよびEdgeFormを使って内部と境界のスタイルを指定することができる：

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], Annulus[]}]

アニュラスの境界：

Wolfram Language code: Graphics[{Yellow, EdgeForm[Directive[Thick, Blue]], Annulus[]}]

座標  (1)

点はDynamicでよい：

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x], {-.7, .7}], Graphics[{Annulus[], Annulus[Dynamic[{x, 2}], 1 / 4]}]}]

領域  (10)

埋込み次元：

Wolfram Language code: RegionEmbeddingDimension[Annulus[{``x``, ``y``}, {Subscript[``r``, ``inner``], Subscript[``r``, ``outer``]}]]

幾何次元：

Wolfram Language code: RegionDimension[Annulus[{``x``, ``y``}, {Subscript[``r``, ``inner``], Subscript[``r``, ``outer``]}]]

点の帰属判定：

Wolfram Language code: {RegionMember[Annulus[], {0, 0}], RegionMember[Annulus[], {0, 1}]}

点の帰属条件を得る：

Wolfram Language code: RegionMember[Annulus[{Subscript[x, 0], Subscript[y, 0]}, {Subscript[``r``, ``inner``], Subscript[``r``, ``outer``]}], {x, y}]

面積：

Wolfram Language code: ℛ = Annulus[];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

重心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Pink, ℛ}, {Blue, Point[c]}}]

点からの距離：

Wolfram Language code: ℛ = Annulus[];
Wolfram Language code: {RegionDistance[ℛ, {1, 2}], RegionDistance[ℛ, {0, 0}]}

基本的なアニュラス内の最近点までの距離：

Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -3, 3}, {y, -3, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

点からの符号付き距離：

Wolfram Language code: ℛ = Annulus[];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 2}], SignedRegionDistance[ℛ, {0, 0}]}

基本的アニュラスまでの符号付き距離：

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}, Exclusions -> Norm[{x, y}] == 1]

領域内の最近点：

Wolfram Language code: ℛ = Annulus[{1, 2}, {1, 2}, {0, 3Pi / 2}];
Wolfram Language code: RegionNearest[ℛ, {5, 6}]

最近点：

Wolfram Language code: pts = Table[{1, 2} + 5{Cos[k 2 π / 16], Sin[k 2π / 16]}, {k, 0., 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

アニュラスは有界である：

Wolfram Language code: ℛ = Annulus[{1, 1}, {2, 3}];
Wolfram Language code: BoundedRegionQ[ℛ]

範囲を求める：

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{Gray, ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.1, Yellow], Cuboid@@Transpose[rr]}}]

アニュラス上で積分する：

Wolfram Language code: ℛ = Annulus[{Subscript[x, 0], Subscript[y, 0]}, {Subscript[r, 1], Subscript[r, 2]}];
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

アニュラス上で最適化する：

Wolfram Language code: ℛ = Annulus[];
Wolfram Language code: {MinValue[{x y - x, {x, y}∈ℛ}, {x, y}], ArgMin[{x y - x, {x, y}∈ℛ}, {x, y}]}

アニュラス内で方程式を解く：

Wolfram Language code: ℛ = Annulus[{1, 2}, {3, 4}];
Wolfram Language code: Solve[x^2 + y^2 == 3 && x y == 1 && {x, y}∈ℛ, {x, y}]
Wolfram Language code: Show[{Graphics[{{Green, ℛ}, {Blue, Circle[{0, 0}, Sqrt[3]]}}], Plot[1 / x, {x, -3, 5}, PlotRange -> {{-3, 5}, {-3, 6}}], Graphics[{PointSize[Large], Red, Point[{x, y}] /. %}]}, Axes -> True]

アプリケーション  (4)

アニュラスの上で関数をプロットする：

Wolfram Language code: Plot3D[Sin[x + Cos[y]], {x, y}∈Annulus[]]

コンデンサは基本的に間に絶縁体が入った導体平板のペアである．コンデンサの電気容量は板の分離と重なり合う面積の関数で，このことから，重なり合う部分を変えるために回転させることができる半アニュラスの集合から作ることができる可変コンデンサを作ることができる．接続している2つのアニュラスの重なり合う部分の弧を与える関数を作る：

Wolfram Language code: overlaparc[arc1_, arc2_] := IntervalIntersection[Interval[arc1], Interval[arc2]][[1]]

次に重なり合う面積を求める関数を作る：

Wolfram Language code: overlaparea[ri_, angle_] := Area[Annulus[{0, 0}, {ri, 1}, overlaparc[{0, Pi}, {angle, angle + Pi}]]]

であるので，電気容量を計算する関数を作ることができる：

Wolfram Language code: capacitance[area_, distance_, dielectricconstant_] := dielectricconstant * Quantity["ElectricConstant"] * Quantity[area, "Centimeters" ^ 2] / Quantity[distance, "Centimeters"]

インタラクティブでグラフィカルな容量（単位：ピコファラッド）を表示する可変コンデンサの表現形を作ることができる：

Wolfram Language code: Manipulate[Graphics[{Blue, Annulus[{0, 0}, {ri, 1}, {0, Pi}], Red, Annulus[{0, 0}, {ri, 1}, {a, a + Pi}]}, PlotLabel -> UnitConvert[capacitance[overlaparea[ri, a], d, 1], "Picofarads"], PlotRange -> 1], {{a, Pi / 2, "Offset Angle"}, 0, Pi - .01}, {{ri, .5, "Inner Radius (cm)"}, 0.01, .9}, {{d, .1, "Separation Distance (cm)"}, 0.01, 1}, SaveDefinitions -> True]

木の成長につれて，その年の気候によって断面にさまざまな太さの年輪が見られる．アニュラスを使って年輪に似たパターンを作ることができる．まず，ランダムではあるが隣接した内半径と外半径のリストを生成する：

Wolfram Language code: numberofrings = 50;radii = (Transpose@({PadLeft[#, numberofrings + 2], PadRight[#, numberofrings + 2]}&@Accumulate[RandomReal[{0, 1}, numberofrings + 1]]))[[2 ;; -2]];

ランダムな色（茶系）を使って同心円のアニュラスの表を作成する：

Wolfram Language code: annuluses = Table[{x = RandomReal[{-.2, .4}];RGBColor[x + .6, x + .4, x + .2], Annulus[{0, 0}, radii[[i]]]}, {i, Length[radii]}];

最後に，最小のアニュラスの内半径と半径が等しい円板を中心としてすべてのアニュラスを可視化する：

Wolfram Language code: Graphics[{Brown, Disk[{0, 0}, radii[[1, 1]]], annuluses}]

ある種の条件下で金環日食が起こることがある．「アニュラス（環）」の語は，空に浮かぶ太陽と月の相対的な大きさのため，太陽の一部（コロナ）が月の周りに見えて明るい環を形成するところからきている．この現象のインタラクティブなデモンストレーションを作り，金環日食時に明るい白の環を作ることができる：

Wolfram Language code: sun[x_] := {Blend[{White, Yellow}, Abs[x]], Disk[{0, 0}, 2]}; moon[x_] := {GrayLevel[Abs[x / 10]], Disk[{x, 0}, 1.95]}; annulareclipse[x_] := {If[x == 0, {White, Annulus[{0, 0}, {1.95, 2.2}]}, {}]};
Wolfram Language code: Manipulate[Graphics[{sun[x], moon[x], annulareclipse[x]}, PlotRange -> {{-3, 3}, {-2.2, 2.3}}, Background -> Black], {{x, -3, "Move the Moon:"}, -3, 3, .1}, SaveDefinitions -> True]

特性と関係  (6)

Diskは，が0に近付く際のAnnulusの極限である：

Wolfram Language code: Manipulate[Graphics[{Disk[], Annulus[{2, 0}, {ri, 1}]}, PlotRange -> {{-1, 3}, {-1, 1}}, ImageSize -> Small], {{ri, .5}, .5, .00001}]

Circleは が に近付く際のAnnulusの極限である：

Wolfram Language code: Manipulate[Graphics[{Circle[], Annulus[{2, 0}, {ri, 1}]}, PlotRange -> {{-1, 3}, {-1, 1}}, ImageSize -> Small], {{ri, .5}, .5, .99}]

アニュラスは2つの同心Disk領域間のRegionDifferenceの閉包である：

Wolfram Language code: Subscript[ℛ, 1] = RegionUnion[RegionDifference[Disk[{0, 0}, 2], Disk[{0, 0}, 1]], Circle[{0, 0}, 1]]; Subscript[ℛ, 2] = Annulus[{0, 0}, {1, 2}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegionは任意のAnnulusを表すことができる：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[0 < Subscript[r, inner] < Subscript[r, outer] && Subsuperscript[r, inner, 2] ≤ (x - Subscript[c, 1])^2 + (y - Subscript[c, 2])^2 ≤ Subsuperscript[r, outer, 2], {x, y}];
Wolfram Language code: Subscript[ℛ, 2] = Annulus[{Subscript[c, 1], Subscript[c, 2]}, {Subscript[r, inner], Subscript[r, outer]}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ParametricRegionはAnnulusを表すことができる：

Wolfram Language code: Subscript[ℛ, 1] = ParametricRegion[{r Cos[θ], r Sin[θ]}, {{θ, 0, 2π}, {r, 1, 2}}]; Subscript[ℛ, 2] = Annulus[{0, 0}, {1, 2}];
Wolfram Language code: Region[Subscript[ℛ, 1]]
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Annulusは，半径の円から未満の点である：

Wolfram Language code: Subscript[ℛ, 1] = Circle[{x, y}, (Subscript[``r``, ``outer``] + Subscript[``r``, ``inner``]) / 2]; Subscript[ℛ, 2] = Annulus[{x, y}, {Subscript[``r``, ``inner``], Subscript[``r``, ``outer``]}];
Wolfram Language code: Reduce[Subscript[∀, {Subscript[r, inner], Subscript[r, outer]}, 0 < Subscript[r, inner] < Subscript[r, outer]](RegionDistance[Subscript[ℛ, 1], {x, y}] ≤ (1/2) (Subscript[r, outer] - Subscript[r, inner])⧦RegionMember[Subscript[ℛ, 2], {x, y}]), {x, y}, Reals]

おもしろい例題  (3)

ランダムなアニュラスの集合：

Wolfram Language code: Graphics[Table[{EdgeForm[Black], Hue[RandomReal[]], Annulus[RandomReal[4, {2}], RandomReal[1]]}, {40}]]

アニュラスの族：

Wolfram Language code: Graphics[Table[{Hue[t / 30, 1, .9, .3], Annulus[{Cos[2Pi t / 30], Sin[2Pi t / 30]}, 1]}, {t, 30}]]

デジタル花弁：

Wolfram Language code: Graphics[Table[{EdgeForm[Opacity[.6]], Hue[(-11 + q + 10 r) / 72], Annulus[(8 - r){Cos[2Pi q / 12], Sin[2Pi q / 12]}, (8 - r) / 3]}, {r, 6}, {q, 12}]]
Wolfram Research (2015), Annulus, Wolfram言語関数， https://reference.wolfram.com/language/ref/Annulus.html.

テキスト

Wolfram Research (2015), Annulus, Wolfram言語関数， https://reference.wolfram.com/language/ref/Annulus.html.

CMS

Wolfram Language. 2015. "Annulus." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Annulus.html.

APA

Wolfram Language. (2015). Annulus. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Annulus.html

BibTeX

@misc{reference.wolfram_2026_annulus, author="Wolfram Research", title="{Annulus}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/Annulus.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_annulus, organization={Wolfram Research}, title={Annulus}, year={2015}, url={https://reference.wolfram.com/language/ref/Annulus.html}, note=[Accessed: 08-September-2026]}