WOLFRAM

Wolfram 语言与系统参考资料中心

Annulus[{x,y},{rinner,router}]

表示中心在 {x,y}，内径为 rinner，外径为 router 的圆环.

Annulus[{x,y},{rinner,router},{θ1,θ2}]

表示角度从 θ1 到 θ2 的圆环.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
图形  
规范  
样式  
坐标  
区域  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

Annulus

Annulus[{x,y},{rinner,router}]

表示中心在 {x,y}，内径为 rinner，外径为 router 的圆环.

Annulus[{x,y},{rinner,router},{θ1,θ2}]

表示角度从 θ1 到 θ2 的圆环.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (4)

标准圆环：

Wolfram Language code: Annulus[]
Wolfram Language code: Graphics[Annulus[]]

圆环扇区：

Wolfram Language code: Graphics[{Orange, Annulus[{0, 0}, {1 / 2, 1}, {0, 3Pi / 2}]}]

不同样式的环体：

Wolfram Language code: {Graphics[{Pink, Annulus[]}], Graphics[{EdgeForm[Thick], Pink, Annulus[]}], Graphics[{EdgeForm[Dashed], Pink, Annulus[]}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, Annulus[]}]}

得到圆环的 Area：

Wolfram Language code: Area[Annulus[{0, 0}, {1 / 2, 1}]]

圆环切片的面积：

Wolfram Language code: Area[Annulus[{0, 0}, {r / 2, r}, {0, 3Pi / 2}]]

范围  (17)

图形  (7)

规范  (4)

指定半径：

Wolfram Language code: Graphics[{Red, Annulus[1], Green, Annulus[3], Blue, Annulus[7]}]

指定中心：

Wolfram Language code: Graphics[{Red, Annulus[{0, 0}, {1, 2}], Green, Annulus[{1, 1}, {1, 2}], Blue, Annulus[{2, 2}, {1, 2}]}]

圆环扇区：

Wolfram Language code: Graphics[Annulus[{0, 0}, {1, 2}, {0, 3Pi / 2}]]
Wolfram Language code: Graphics[Annulus[{0, 0}, {1, 2}, {-2Pi / 3, -1Pi / 3}]]

中心在原点的基本圆环的简写形式：

Wolfram Language code: Graphics[Annulus[], Frame -> True]

样式  (2)

颜色指令指定各个圆环的表面颜色：

Wolfram Language code: Table[Graphics[{c, Annulus[]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm 和 EdgeForm 可用于指定内部和边界的样式：

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], Annulus[]}]

圆环的边界：

Wolfram Language code: Graphics[{Yellow, EdgeForm[Directive[Thick, Blue]], Annulus[]}]

坐标  (1)

点可以是 Dynamic：

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x], {-.7, .7}], Graphics[{Annulus[], Annulus[Dynamic[{x, 2}], 1 / 4]}]}]

区域  (10)

嵌入维数：

Wolfram Language code: RegionEmbeddingDimension[Annulus[{``x``, ``y``}, {Subscript[``r``, ``inner``], Subscript[``r``, ``outer``]}]]

几何维数：

Wolfram Language code: RegionDimension[Annulus[{``x``, ``y``}, {Subscript[``r``, ``inner``], Subscript[``r``, ``outer``]}]]

点成员检验：

Wolfram Language code: {RegionMember[Annulus[], {0, 0}], RegionMember[Annulus[], {0, 1}]}

得到点成员的条件：

Wolfram Language code: RegionMember[Annulus[{Subscript[x, 0], Subscript[y, 0]}, {Subscript[``r``, ``inner``], Subscript[``r``, ``outer``]}], {x, y}]

面积：

Wolfram Language code: ℛ = Annulus[];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

形心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Pink, ℛ}, {Blue, Point[c]}}]

到点的距离：

Wolfram Language code: ℛ = Annulus[];
Wolfram Language code: {RegionDistance[ℛ, {1, 2}], RegionDistance[ℛ, {0, 0}]}

到基本圆环上最近点的距离：

Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -3, 3}, {y, -3, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

到一个点的带符号距离：

Wolfram Language code: ℛ = Annulus[];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 2}], SignedRegionDistance[ℛ, {0, 0}]}

到基本圆环的带符号距离：

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}, Exclusions -> Norm[{x, y}] == 1]

区域上的最近点：

Wolfram Language code: ℛ = Annulus[{1, 2}, {1, 2}, {0, 3Pi / 2}];
Wolfram Language code: RegionNearest[ℛ, {5, 6}]

最近点：

Wolfram Language code: pts = Table[{1, 2} + 5{Cos[k 2 π / 16], Sin[k 2π / 16]}, {k, 0., 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

圆环是有界的：

Wolfram Language code: ℛ = Annulus[{1, 1}, {2, 3}];
Wolfram Language code: BoundedRegionQ[ℛ]

得到它的范围：

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{Gray, ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.1, Yellow], Cuboid@@Transpose[rr]}}]

在圆环上积分：

Wolfram Language code: ℛ = Annulus[{Subscript[x, 0], Subscript[y, 0]}, {Subscript[r, 1], Subscript[r, 2]}];
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

队员和进行最优化：

Wolfram Language code: ℛ = Annulus[];
Wolfram Language code: {MinValue[{x y - x, {x, y}∈ℛ}, {x, y}], ArgMin[{x y - x, {x, y}∈ℛ}, {x, y}]}

求解圆环上的方程：

Wolfram Language code: ℛ = Annulus[{1, 2}, {3, 4}];
Wolfram Language code: Solve[x^2 + y^2 == 3 && x y == 1 && {x, y}∈ℛ, {x, y}]
Wolfram Language code: Show[{Graphics[{{Green, ℛ}, {Blue, Circle[{0, 0}, Sqrt[3]]}}], Plot[1 / x, {x, -3, 5}, PlotRange -> {{-3, 5}, {-3, 6}}], Graphics[{PointSize[Large], Red, Point[{x, y}] /. %}]}, Axes -> True]

应用  (4)

在圆环上绘制函数图形：

Wolfram Language code: Plot3D[Sin[x + Cos[y]], {x, y}∈Annulus[]]

电容器本质上是一对中间有绝缘体的导电板. 电容器的电容是导电板分离和重合面积的函数，它允许创建由一组由半圆环制成的可变电容器，通过旋转这些圆环可以改变它们之间的重叠部分. 制作一个函数，返回两个同心圆环重叠的圆弧：

Wolfram Language code: overlaparc[arc1_, arc2_] := IntervalIntersection[Interval[arc1], Interval[arc2]][[1]]

然后做一个函数求重叠部分的面积：

Wolfram Language code: overlaparea[ri_, angle_] := Area[Annulus[{0, 0}, {ri, 1}, overlaparc[{0, Pi}, {angle, angle + Pi}]]]

已知 ，做一个函数计算电容：

Wolfram Language code: capacitance[area_, distance_, dielectricconstant_] := dielectricconstant * Quantity["ElectricConstant"] * Quantity[area, "Centimeters" ^ 2] / Quantity[distance, "Centimeters"]

创建可变电容器的交互式图形表示，显示其电容（以皮法计）：

Wolfram Language code: Manipulate[Graphics[{Blue, Annulus[{0, 0}, {ri, 1}, {0, Pi}], Red, Annulus[{0, 0}, {ri, 1}, {a, a + Pi}]}, PlotLabel -> UnitConvert[capacitance[overlaparea[ri, a], d, 1], "Picofarads"], PlotRange -> 1], {{a, Pi / 2, "Offset Angle"}, 0, Pi - .01}, {{ri, .5, "Inner Radius (cm)"}, 0.01, .9}, {{d, .1, "Separation Distance (cm)"}, 0.01, 1}, SaveDefinitions -> True]

随着树的成长，它的横截面根据每年的气候产生不同宽度的年轮. 可以使用圆环创建类似年轮的图案. 首先，生成随机但相邻的内径和外径的列表：

Wolfram Language code: numberofrings = 50;radii = (Transpose@({PadLeft[#, numberofrings + 2], PadRight[#, numberofrings + 2]}&@Accumulate[RandomReal[{0, 1}, numberofrings + 1]]))[[2 ;; -2]];

创建具有随机（褐）色的同心圆环的表格：

Wolfram Language code: annuluses = Table[{x = RandomReal[{-.2, .4}];RGBColor[x + .6, x + .4, x + .2], Annulus[{0, 0}, radii[[i]]]}, {i, Length[radii]}];

最后，可视化所有圆环以及半径等于中心最小圆环内径的圆盘：

Wolfram Language code: Graphics[{Brown, Disk[{0, 0}, radii[[1, 1]]], annuluses}]

在某些情况下，可能会发生日环食. 这个术语（Annular）源自圆环（Annulus），因为太阳和月亮在天空中的相对大小使得太阳（日冕）的一部分绕月可见，形成一个明亮的环. 可以将这种现象进行互动演示，并制作一个明亮的白环，使其出现在日环食的时刻：

Wolfram Language code: sun[x_] := {Blend[{White, Yellow}, Abs[x]], Disk[{0, 0}, 2]}; moon[x_] := {GrayLevel[Abs[x / 10]], Disk[{x, 0}, 1.95]}; annulareclipse[x_] := {If[x == 0, {White, Annulus[{0, 0}, {1.95, 2.2}]}, {}]};
Wolfram Language code: Manipulate[Graphics[{sun[x], moon[x], annulareclipse[x]}, PlotRange -> {{-3, 3}, {-2.2, 2.3}}, Background -> Black], {{x, -3, "Move the Moon:"}, -3, 3, .1}, SaveDefinitions -> True]

属性和关系  (6)

Disk 是 趋向0时 Annulus 的极限：

Wolfram Language code: Manipulate[Graphics[{Disk[], Annulus[{2, 0}, {ri, 1}]}, PlotRange -> {{-1, 3}, {-1, 1}}, ImageSize -> Small], {{ri, .5}, .5, .00001}]

Circle 是 趋向 时 Annulus 的极限：

Wolfram Language code: Manipulate[Graphics[{Circle[], Annulus[{2, 0}, {ri, 1}]}, PlotRange -> {{-1, 3}, {-1, 1}}, ImageSize -> Small], {{ri, .5}, .5, .99}]

圆环是两个同心 Disk 区域之间 RegionDifference 的封闭区域：

Wolfram Language code: Subscript[ℛ, 1] = RegionUnion[RegionDifference[Disk[{0, 0}, 2], Disk[{0, 0}, 1]], Circle[{0, 0}, 1]]; Subscript[ℛ, 2] = Annulus[{0, 0}, {1, 2}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegion 可以表示任何 Annulus：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[0 < Subscript[r, inner] < Subscript[r, outer] && Subsuperscript[r, inner, 2] ≤ (x - Subscript[c, 1])^2 + (y - Subscript[c, 2])^2 ≤ Subsuperscript[r, outer, 2], {x, y}];
Wolfram Language code: Subscript[ℛ, 2] = Annulus[{Subscript[c, 1], Subscript[c, 2]}, {Subscript[r, inner], Subscript[r, outer]}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ParametricRegion 可以表示 Annulus：

Wolfram Language code: Subscript[ℛ, 1] = ParametricRegion[{r Cos[θ], r Sin[θ]}, {{θ, 0, 2π}, {r, 1, 2}}]; Subscript[ℛ, 2] = Annulus[{0, 0}, {1, 2}];
Wolfram Language code: Region[Subscript[ℛ, 1]]
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Annulus 半径为 的圆上小于 的点：

Wolfram Language code: Subscript[ℛ, 1] = Circle[{x, y}, (Subscript[``r``, ``outer``] + Subscript[``r``, ``inner``]) / 2]; Subscript[ℛ, 2] = Annulus[{x, y}, {Subscript[``r``, ``inner``], Subscript[``r``, ``outer``]}];
Wolfram Language code: Reduce[Subscript[∀, {Subscript[r, inner], Subscript[r, outer]}, 0 < Subscript[r, inner] < Subscript[r, outer]](RegionDistance[Subscript[ℛ, 1], {x, y}] ≤ (1/2) (Subscript[r, outer] - Subscript[r, inner])⧦RegionMember[Subscript[ℛ, 2], {x, y}]), {x, y}, Reals]

巧妙范例  (3)

随机圆环的集合：

Wolfram Language code: Graphics[Table[{EdgeForm[Black], Hue[RandomReal[]], Annulus[RandomReal[4, {2}], RandomReal[1]]}, {40}]]

一组圆环：

Wolfram Language code: Graphics[Table[{Hue[t / 30, 1, .9, .3], Annulus[{Cos[2Pi t / 30], Sin[2Pi t / 30]}, 1]}, {t, 30}]]

数码花瓣：

Wolfram Language code: Graphics[Table[{EdgeForm[Opacity[.6]], Hue[(-11 + q + 10 r) / 72], Annulus[(8 - r){Cos[2Pi q / 12], Sin[2Pi q / 12]}, (8 - r) / 3]}, {r, 6}, {q, 12}]]
Wolfram Research (2015)，Annulus，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Annulus.html.

文本

Wolfram Research (2015)，Annulus，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Annulus.html.

CMS

Wolfram 语言. 2015. "Annulus." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Annulus.html.

APA

Wolfram 语言. (2015). Annulus. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Annulus.html 年

BibTeX

@misc{reference.wolfram_2026_annulus, author="Wolfram Research", title="{Annulus}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/Annulus.html}", note=[Accessed: 19-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_annulus, organization={Wolfram Research}, title={Annulus}, year={2015}, url={https://reference.wolfram.com/language/ref/Annulus.html}, note=[Accessed: 19-August-2026]}