WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Antialiasing

アンチエイリアス処理を行うかどうかを指定するオプションである．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
描画  
リサンプリング  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

Antialiasing

Antialiasing

アンチエイリアス処理を行うかどうかを指定するオプションである．

詳細

  • Antialiasingは，描画あるいはサンプルの際のエイリアシングというアーチファクトを最小にするために使われる．
  • Antialiasingは，2Dのグラフィカル要素を描画する際に，離散的なスクリーン画素によってジグザグに見えることを防ぐためにエッジをぼやけさせる．
  • Antialiasingは，オーディオの再サンプリングの際は，事実上ローパスフィルタを加えて，可聴なアーチファクト（雑音）を削除する．
  • 次は，Antialiasingのよく使われる設定である．
  • Automaticコンピュータシステムのタイプによって見え方を最適化する
    Falseアンチエイリアス処理は行わない
    True描画あるいはサンプリングの際にアンチエイリアス処理を行う
  • グラフィカル要素のアンチエイリアス処理では，黒い線が多少灰色がかることがある．
  • Antialiasingは，グラフィックス全体だけでなく，1つのグラフィックス中の個々のプリミティブやプリミティブの集合についてもオン／オフを切り替えることができる．
  • Antialiasingはフォントの外観は変えない．フォントのアンチエイリアス処理は，一般に，大域的オペレーティングシステムの設定が制御している．
  • AntialiasingがGraphics3Dオブジェクトの外観を変えることはない．3Dのグラフィカルなアンチエイリアス処理は，RenderingOptionsの"HardwareAntialiasingQuality"サブオプションで制御されるレンダラーの大域特性である．

例題

すべて開く すべて閉じる

例  (1)

デフォルトでアンチエイリアス処理を行う：

Wolfram Language code: Style[Graphics[Circle[]], Antialiasing -> True]

アンチエイリアス処理をオフにする：

Wolfram Language code: Style[Graphics[Circle[]], Antialiasing -> False]

スコープ  (4)

描画  (2)

グラフィックスの個々の部分についてアンチエイリアス処理を制御する：

Wolfram Language code: Graphics[{Style[Circle[], Antialiasing -> True], Style[Circle[{1, 0}], Antialiasing -> False]}]

線のアンチエイリアス処理：

Wolfram Language code: {Style[Graphics[{Line[{{0, 0}, {7, 4}}]}], Antialiasing -> True], Style[Graphics[{Line[{{0, 0}, {7, 4}}]}], Antialiasing -> False]}

リサンプリング  (2)

アンチエイリアス処理なしでダウンサンプリングすると，サンプル値の中には完全に無視されるものがあるかもしれない：

Wolfram Language code: ArrayResample[{2, 1, 2, 1, 2}, 3, Padding -> "Reflected", Antialiasing -> False]

アンチエイリアス処理をすると，新たなサンプル間に入るサンプルはすべて平均される：

Wolfram Language code: ArrayResample[{2, 1, 2, 1, 2}, 3, Padding -> "Reflected", Antialiasing -> True]

より低いサンプルレートにリサンプルするときは，デフォルトでアンチエイリアスフィルタが適用される：

Wolfram Language code: a = AudioGenerator[{"Sin", 3500}, SampleRate -> 8000] + AudioGenerator[{"Sin", 1500}, SampleRate -> 8000]; Spectrogram[a]

アンチエイリアスフィルタを使い，.5の割合でリサンプルする：

Wolfram Language code: Spectrogram[AudioResample[a, 4000]]

Antialiasing->Falseを使う：

Wolfram Language code: Spectrogram[AudioResample[a, 4000, Antialiasing -> False]]

アプリケーション  (1)

Rasterizeを使って線のアンチエイリアス処理を観察する：

Wolfram Language code: lines[Antialiasing -> a : True | False] := Table[Show[Rasterize[Graphics[Style[Line[{{0, 0}, {x, 1}}], Antialiasing -> a]], Background -> None, RasterSize -> 20, ImageSize -> 20], Frame -> True, FrameTicks -> False, GridLines -> Function[{m, M}, Range[Floor[m], Ceiling[M]]], GridLinesStyle -> Directive[Black, Opacity[.1]], ImageSize -> 100], {x, 6}]

アンチエイリアス処理あり：

Wolfram Language code: lines[Antialiasing -> True]

アンチエイリアス処理なし：

Wolfram Language code: lines[Antialiasing -> False]

特性と関係  (1)

エイリアシングは，グラフィックスが座標軸と揃っていない場合により顕著になる：

Wolfram Language code: {Style[Graphics[{FaceForm[], EdgeForm[Black], Rotate[Rectangle[], Pi / 5]}], Antialiasing -> True], Style[Graphics[{FaceForm[], EdgeForm[Black], Rotate[Rectangle[], Pi / 5]}], Antialiasing -> False]}

考えられる問題  (2)

コンピュータシステムによっては，アンチエイリアス処理を施された線が若干太めで灰色に見えることがある：

Wolfram Language code: {Style[Graphics[{FaceForm[], EdgeForm[Black], Rectangle[]}, ImageSize -> 100.5], Antialiasing -> True], Style[Graphics[{FaceForm[], EdgeForm[Black], Rectangle[]}, ImageSize -> 100.5], Antialiasing -> False]}

フォントのアンチエイリアス処理はシステムに依存する．Antialiasingは影響しない：

Wolfram Language code: {Text@Style["AaBbCc", Large, Antialiasing -> True], Text@Style["AaBbCc", Large, Antialiasing -> False]}

おもしろい例題  (1)

アンチエイリアス処理をした干渉縞模様としていない干渉縞模様：

Wolfram Language code: {Style[Graphics[Table[Line[{{{x, 0}, {1 - x, 1}}, {{0, x}, {1, 1 - x}}}], {x, 0, 1, .02}]], Antialiasing -> True], Style[Graphics[Table[Line[{{{x, 0}, {1 - x, 1}}, {{0, x}, {1, 1 - x}}}], {x, 0, 1, .02}]], Antialiasing -> False]}
Wolfram Research (2007), Antialiasing, Wolfram言語関数， https://reference.wolfram.com/language/ref/Antialiasing.html （2016年に更新）.

テキスト

Wolfram Research (2007), Antialiasing, Wolfram言語関数， https://reference.wolfram.com/language/ref/Antialiasing.html （2016年に更新）.

CMS

Wolfram Language. 2007. "Antialiasing." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/Antialiasing.html.

APA

Wolfram Language. (2007). Antialiasing. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Antialiasing.html

BibTeX

@misc{reference.wolfram_2026_antialiasing, author="Wolfram Research", title="{Antialiasing}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/Antialiasing.html}", note=[Accessed: 06-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_antialiasing, organization={Wolfram Research}, title={Antialiasing}, year={2016}, url={https://reference.wolfram.com/language/ref/Antialiasing.html}, note=[Accessed: 06-October-2026]}