WOLFRAM

Wolfram 语言与系统参考资料中心

Antialiasing

是一个指定是否应该使用反失真的选项.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
渲染  
重采样  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

Antialiasing

Antialiasing

是一个指定是否应该使用反失真的选项.

更多信息

  • 在渲染或取样时，Antialiasing 用于最小化人工影响，也叫作混叠.
  • 当渲染二维图形元素时，Antialiasing 使元素边缘变模糊，从而避免由于离散的屏幕象素所引起的锯齿状.
  • 对于声音重取样，Antialiasing 有效地添加了一个低通滤泼器，以便移除可听见的人工影响，比如敲击鼠标声和弹出窗口声.
  • Antialiasing 的主要设置包括:
  • Automatic最优化每种电脑系统上的外观
    False不使用反失真
    True在渲染或取样时使用反失真
  • 在对图形元素使用反失真时，可能会使黑线条略显发灰.
  • Antialiasing 的开启和关闭不仅可以作用于全部图形，也可以作用于单一图形中个别基元或基元组.
  • Antialiasing 不改变字形外观. 字形反失真通常由全局操作系统设置进行控制.
  • Antialiasing 不改变 Graphics3D 对象的外观. 3D 图形抗锯齿是由 RenderingOptions 的子选项 "HardwareAntialiasingQuality" 控制的渲染器的一个全局属性.

范例

打开所有单元 关闭所有单元

基本范例  (1)

缺省使用反失真：

Wolfram Language code: Style[Graphics[Circle[]], Antialiasing -> True]

关闭反失真：

Wolfram Language code: Style[Graphics[Circle[]], Antialiasing -> False]

范围  (4)

渲染  (2)

为图形的单个部分控制反失真行为：

Wolfram Language code: Graphics[{Style[Circle[], Antialiasing -> True], Style[Circle[{1, 0}], Antialiasing -> False]}]

线条的反失真：

Wolfram Language code: {Style[Graphics[{Line[{{0, 0}, {7, 4}}]}], Antialiasing -> True], Style[Graphics[{Line[{{0, 0}, {7, 4}}]}], Antialiasing -> False]}

重采样  (2)

当进行无反失真的向下采样时，一些样本值可能会完全被忽略：

Wolfram Language code: ArrayResample[{2, 1, 2, 1, 2}, 3, Padding -> "Reflected", Antialiasing -> False]

如果加用反失真，位于新样本之间的所有样本将取平均值：

Wolfram Language code: ArrayResample[{2, 1, 2, 1, 2}, 3, Padding -> "Reflected", Antialiasing -> True]

向更低的采样率进行重采样时，默认情况下将应用反失真滤波器：

Wolfram Language code: a = AudioGenerator[{"Sin", 3500}, SampleRate -> 8000] + AudioGenerator[{"Sin", 1500}, SampleRate -> 8000]; Spectrogram[a]

在反失真滤波器下，进行因子为 .5 的重采样：

Wolfram Language code: Spectrogram[AudioResample[a, 4000]]

使用 Antialiasing->False：

Wolfram Language code: Spectrogram[AudioResample[a, 4000, Antialiasing -> False]]

应用  (1)

利用 Rasterize 观察线条反失真

Wolfram Language code: lines[Antialiasing -> a : True | False] := Table[Show[Rasterize[Graphics[Style[Line[{{0, 0}, {x, 1}}], Antialiasing -> a]], Background -> None, RasterSize -> 20, ImageSize -> 20], Frame -> True, FrameTicks -> False, GridLines -> Function[{m, M}, Range[Floor[m], Ceiling[M]]], GridLinesStyle -> Directive[Black, Opacity[.1]], ImageSize -> 100], {x, 6}]

加用反失真：

Wolfram Language code: lines[Antialiasing -> True]

不加用反失真：

Wolfram Language code: lines[Antialiasing -> False]

属性和关系  (1)

图形未与轴对齐时失真更为明显：

Wolfram Language code: {Style[Graphics[{FaceForm[], EdgeForm[Black], Rotate[Rectangle[], Pi / 5]}], Antialiasing -> True], Style[Graphics[{FaceForm[], EdgeForm[Black], Rotate[Rectangle[], Pi / 5]}], Antialiasing -> False]}

可能存在的问题  (2)

在某些计算机系统中，经过反失真的线条可能会显得稍粗和稍灰：

Wolfram Language code: {Style[Graphics[{FaceForm[], EdgeForm[Black], Rectangle[]}, ImageSize -> 100.5], Antialiasing -> True], Style[Graphics[{FaceForm[], EdgeForm[Black], Rectangle[]}, ImageSize -> 100.5], Antialiasing -> False]}

字形反失真取决于系统. Antialiasing 不起作用：

Wolfram Language code: {Text@Style["AaBbCc", Large, Antialiasing -> True], Text@Style["AaBbCc", Large, Antialiasing -> False]}

巧妙范例  (1)

加用反失真和未加用反失真图形中的摩尔模式：

Wolfram Language code: {Style[Graphics[Table[Line[{{{x, 0}, {1 - x, 1}}, {{0, x}, {1, 1 - x}}}], {x, 0, 1, .02}]], Antialiasing -> True], Style[Graphics[Table[Line[{{{x, 0}, {1 - x, 1}}, {{0, x}, {1, 1 - x}}}], {x, 0, 1, .02}]], Antialiasing -> False]}
Wolfram Research (2007)，Antialiasing，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Antialiasing.html （更新于 2016 年）.

文本

Wolfram Research (2007)，Antialiasing，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Antialiasing.html （更新于 2016 年）.

CMS

Wolfram 语言. 2007. "Antialiasing." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2016. https://reference.wolfram.com/language/ref/Antialiasing.html.

APA

Wolfram 语言. (2007). Antialiasing. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Antialiasing.html 年

BibTeX

@misc{reference.wolfram_2026_antialiasing, author="Wolfram Research", title="{Antialiasing}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/Antialiasing.html}", note=[Accessed: 07-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_antialiasing, organization={Wolfram Research}, title={Antialiasing}, year={2016}, url={https://reference.wolfram.com/language/ref/Antialiasing.html}, note=[Accessed: 07-August-2026]}