Wolfram 语言与系统参考资料中心

ApplyTo

ApplyTo[x,f] 或 x//=f

计算 f[x] 并将 x 重置到结果.

范例

打开所有单元关闭所有单元

基本范例 (1)

创建一个有值的变量：

Wolfram Language code: x = 1

使用 ApplyTo 计算 f[x]：

Wolfram Language code: x//=f

结果存储在 x 中：

Wolfram Language code: x

范围 (5)

使用有运算符形式的 ApplyTo：

Wolfram Language code:

x = {1, 2, 3};
x//=Map[f];
x

使用 ApplyTo 和 Function：

Wolfram Language code:

x = {1, 2, 3};
x//=# ^ 2&;
x

使用 ApplyTo 和 Composition：

Wolfram Language code:

x = 1;
x//=f @* g;
x

使用 ApplyTo 和 RightComposition：

Wolfram Language code:

x = 1;
x//=f /* g;
x

ApplyTo 的第一个参数不一定需要是符号：

Wolfram Language code: list = {1, 2, 3}

Wolfram Language code: list[[2]]//=f

Wolfram Language code: list

应用 (2)

使用 ApplyTo 调换列表中两个元素的位置：

Wolfram Language code: list = Range[6];

Wolfram Language code: list[[{3, 5}]]//=Reverse

现在 3 和 5 在 list 中的位置已被调换：

Wolfram Language code: list

构建一个矩阵：

Wolfram Language code: (mat = Table[((i + j)π/4), {i, 4}, {j, 4}])//MatrixForm

用 ApplyTo 计算第二列的 Sin：

Wolfram Language code: mat[[All, 2]]//=Sin

该列已被修改：

Wolfram Language code: mat//MatrixForm

属性和关系 (3)

ApplyTo 是 Set 和函数应用的结合：

Wolfram Language code:

x = a;
x//=f;
x

Wolfram Language code:

x = a;
x = f[x];
x

同样的，使用后缀标记：

Wolfram Language code:

x = a;
x = x//f;
x

ApplyTo 可看作是 Construct 的赋值格式：

Wolfram Language code:

x = a;
x = Construct[f, x];
x

ApplyTo 是 AddTo、AppendTo 和类似函数的推广：

Wolfram Language code:

y = 1; z = 1;
y//=# + 2&;
z += 2;
y === z

Wolfram Language code:

y = {a, b, c}; z = {a, b, c};
y//=Append[#, d]&;
AppendTo[z, d];
y === z

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

ApplyTo

更多信息

范例

基本范例 (1)

范围 (5)

应用 (2)

属性和关系 (3)

文本

CMS

APA

BibTeX

BibLaTeX

ApplyTo

更多信息

范例

基本范例 (1)

范围 (5)

应用 (2)

属性和关系 (3)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX