BarnesG

BarnesG[z]

バーンズ(Barnes)のG関数を与える．

詳細

BarnesGは二重ガンマ関数としても知られている．
記号操作・数値操作の両方に適した数学関数である．
バーンズのG関数は，正の整数については $TemplateBox[{n}, BarnesG]=product_(k=1)^(n-1)TemplateBox[{k}, Gamma]$ と定義され，その他の場合は $TemplateBox[{z}, BarnesG]=(2 pi)^(z/2) exp((z-1) (TemplateBox[{z}, LogGamma]-z/2)-TemplateBox[{{-, 2}, z}, PolyGamma2])$ と定義される．
バーンズのG関数は関数方程式を満足する．
BarnesG[z]は不連続な分枝切断線を持たない z の整関数である．
BarnesGは，特別な引数の場合に自動的に厳密値を計算する．
BarnesGは任意の数値精度で評価できる．
BarnesGは自動的にリストに縫い込まれる．
BarnesGはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開くすべて閉じる

例 (5)

数値的に評価する：

Wolfram Language code: BarnesG[10]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[BarnesG[z], {z, -4, 4}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[BarnesG[z], {z, -1 - I, 1 + I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[BarnesG[x], {x, 0, 2}]//FullSimplify

Infinityにおける級数展開：

Wolfram Language code: Series[BarnesG[x], {x, ∞, 2}]

スコープ (27)

数値評価 (6)

数値的に評価する：

Wolfram Language code: BarnesG[0.5]

Wolfram Language code: BarnesG[3]

高精度で評価する：

Wolfram Language code: N[BarnesG[1 / 7], 20]

出力精度は入力精度に従う：

Wolfram Language code: BarnesG[0.222255555666222222222222222]

複素数入力：

Wolfram Language code: BarnesG[1.3 + I]

高精度で効率的に評価する：

Wolfram Language code: BarnesG[0.5`1000]//Timing

Wolfram Language code: BarnesG[0.7`1000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: BarnesG[Interval[{1.17, 1.18}]]

Wolfram Language code: BarnesG[CenteredInterval[1 / 2, 1 / 1000]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: BarnesG[ Around[2.1, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: BarnesG[{{1 / 2, 1}, {1, 1 / 2}}]

MatrixFunctionを使って行列のBarnesG関数を計算することもできる：

Wolfram Language code: MatrixFunction[BarnesG[#]&, {{1 / 2, 1}, {1, 1 / 2}}]//FullSimplify

特定の値 (4)

無限大における値：

Wolfram Language code: BarnesG[Infinity]

ゼロにおける値：

Wolfram Language code: BarnesG[0]

半整数の引数について記号的に評価する：

Wolfram Language code: BarnesG[{-1 / 2, 3 / 2}]

1/4の整数倍について記号的に評価する：

Wolfram Language code: BarnesG[{-3 / 4, 1 / 4}]

最初の正の最大値を求める：

Wolfram Language code: xmax = x /. N@Solve[D[BarnesG[x], x] == 0 && 0 < x < 2, x, Reals][[1]]//Quiet

Wolfram Language code: Plot[BarnesG[x], {x, -1, 4}, Epilog -> Style[Point[{xmax, BarnesG[xmax]}], PointSize[Large], Red]]

可視化 (2)

BarnesG関数をプロットする：

Wolfram Language code: Plot[BarnesG[x], {x, -4, 4}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[BarnesG[z]], {z, -3 - 4I, 3 + 4I}, Contours -> 24]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[BarnesG[z]], {z, -3 - 4I, 3 + 4I}, Contours -> 24]

関数の特性 (10)

BarnesGはすべての実数値と複素数値について定義される：

Wolfram Language code: FunctionDomain[BarnesG[x], x]

Wolfram Language code: FunctionDomain[BarnesG[z], z, Complexes]

BarnesGの値域を近似する：

Wolfram Language code: FunctionRange[BarnesG[x], x, y]

BarnesGは x の解析関数である：

Wolfram Language code: FunctionAnalytic[BarnesG[x], x]

BarnesGは非増加でも非減少でもない：

Wolfram Language code: FunctionMonotonicity[BarnesG[x], x]

BarnesGは単射ではない：

Wolfram Language code: FunctionInjective[BarnesG[x], x]

Wolfram Language code: Plot[{BarnesG[x], .2}, {x, -4, 4}]

BarnesGは全射である：

Wolfram Language code: FunctionSurjective[BarnesG[x], x]

Wolfram Language code: Plot[{BarnesG[x], 5}, {x, -5, 5}]

BarnesGは非負でも非正でもない：

Wolfram Language code: FunctionSign[BarnesG[x], x]

BarnesGは特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[BarnesG[x], x]

Wolfram Language code: FunctionDiscontinuities[BarnesG[x], x]

BarnesGは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[BarnesG[x], x]

TraditionalFormによる表示：

Wolfram Language code: BarnesG[z]//TraditionalForm

微分 (2)

z についての一次導関数：

Wolfram Language code: D[BarnesG[z], z]

z についての高次導関数：

Wolfram Language code: Table[D[BarnesG[z], {z, k}], {k, 1, 3}]//FullSimplify

z についての高次導関数をプロットする：

Wolfram Language code: Plot[%, {z, -4, 4}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

級数展開 (3)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[BarnesG[x], {x, 0, 2}]//Normal//FullSimplify

の周りの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@FullSimplify[Table[Series[BarnesG[x], {x, 0, m}], {m, 1, 5, 2}]];
Plot[{BarnesG[x], terms}, {x, 0, 10}, PlotRange -> {-100, 100}]

生成点におけるテイラー展開：

Wolfram Language code: Series[BarnesG[x], {x, x0, 2}]// Normal//FullSimplify

Infinityにおける級数展開を求める：

Wolfram Language code: Series[BarnesG[x], {x, Infinity, 1}]

アプリケーション (5)

BarnesGの整数値は超階乗(superfactorial)に関連する：

Wolfram Language code: Table[ Product[k!, {k, n}], {n, 10}]

Wolfram Language code: Table[BarnesG[n + 2], {n, 10}]

BarnesGは記号ソルバによって生成されることがある：

Wolfram Language code: Product[Gamma[i] / CatalanNumber[i], i]

Wolfram Language code: Sum[Log[Pochhammer[3, i]], {i, 0, n}]

Wolfram Language code: RSolve[y[i + 1] == i! y[i], y, i]

大きい整数の格納に必要なビット数を計算する：

Wolfram Language code: Log2[BarnesG[500]]//N

厳密な結果と比較する：

Wolfram Language code: BitLength[BarnesG[500]]

が奇素数の場合，ウィルソンの定理を一般化するととなる．最初のいくつかの奇素数を確認する：

Wolfram Language code: Table[Mod[(p - 1)!!, p] == Mod[BarnesG[p + 1], p], {p, Prime[Range[2, 11]]}]

最初の個の正の整数と整数シフトで構築されたコーシー(Cauchy)行列を定義する：

Wolfram Language code: cmat[b_, n_Integer] := CauchyMatrix[b + Range[n], Range[n]]

任意のについてのコーシー行列を示す：

Wolfram Language code: MatrixForm[cmat[b, 5]]

コーシー行列の行列式はBarnesGによって表すことができる．最初のいくつかのケースについて，特定のの値を使って検証する：

Wolfram Language code:

With[{b = 3, n = 9}, 
	Table[Det[cmat[b, n]] == (BarnesG[n + b + 2]^2BarnesG[n + 1]^2/BarnesG[b + 2]BarnesG[2n + b + 2]), {k, n}]]

特性と関係 (2)

BarnesGは微分方程式を満足する：

Wolfram Language code: DSolve[{y[1] == 1, y'[z] == y[z] BarnesG'[z] / BarnesG[z]}, y, z]

Wolfram Language code: y[15] /. First[%]//FullSimplify

Wolfram Language code: BarnesG[15]

FindSequenceFunctionはBarnesG数列を認識する：

Wolfram Language code: Table[BarnesG[n], {n, 10}]

Wolfram Language code: FindSequenceFunction[%, n]

おもしろい例題 (3)

ベル(Bell)数から構築されたハンケル(Hankel)行列の行列式：

Wolfram Language code: Table[Det[HankelMatrix[BellB[Range[n]], BellB[Range[n, 2n - 1]]]], {n, 10}]

Wolfram Language code: Table[BarnesG[n + 1], {n, 10}]

オイラー数から構築したハンケル行列の行列式：

Wolfram Language code: Table[Det[HankelMatrix[EulerE[Range[0, n - 1]], EulerE[Range[n - 1, 2n - 2]]]], {n, 10}]

Wolfram Language code: Table[(-1)^Binomial[n, 2]BarnesG[n + 1]^2, {n, 10}]

ヒルベルト行列の行列式はバーンズのG関数で表すことができる：

Wolfram Language code: hilbertDet[n_] := BarnesG[n + 1] ^ 4 / BarnesG[2 n + 1]

最初のいくつかのケースについて式を確認する：

Wolfram Language code: Table[hilbertDet[n] == Det[HilbertMatrix[n]], {n, 2, 9}]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

BarnesG

詳細

例題

例 (5)