WOLFRAM

Wolfram 语言与系统参考资料中心

BarnesG[z]

给出巴尼斯 G 函数 TemplateBox[{z}, BarnesG].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值运算  
特殊值  
可视化  
函数的属性  
微分  
级数展开式  
应用  
属性和关系  
巧妙范例  
参见
相关指南
相关链接
历史
按以下格式引用：

BarnesG

BarnesG[z]

给出巴尼斯 G 函数 TemplateBox[{z}, BarnesG].

更多信息

  • BarnesG 也被称作双伽玛函数.
  • 数学函数，适宜于符号和数值运算.
  • 对于正整数 ，巴尼斯 G 函数的定义为 TemplateBox[{n}, BarnesG]=product_(k=1)^(n-1)TemplateBox[{k}, Gamma]，在其他情况下，定义为 TemplateBox[{z}, BarnesG]=(2 pi)^(z/2) exp((z-1) (TemplateBox[{z}, LogGamma]-z/2)-TemplateBox[{{-, 2}, z}, PolyGamma2]).
  • 巴尼斯 G 函数满足函数方程 TemplateBox[{{z, +, 1}}, BarnesG]=TemplateBox[{z}, BarnesG] TemplateBox[{z}, Gamma].
  • BarnesG[z] 是一个没有分支切割不连续的 z 的整体函数.
  • 对于某些特殊参数，BarnesG 会自动用精确精度进行计算.
  • BarnesG 可求任意数值精度的值.
  • BarnesG 自动逐项作用于列表的各个元素.
  • BarnesG 可与 Interval 和 CenteredInterval 对象一起使用. »

范例

打开所有单元 关闭所有单元

基本范例  (5)

数值化计算：

Wolfram Language code: BarnesG[10]

在实数的子集上绘图：

Wolfram Language code: Plot[BarnesG[z], {z, -4, 4}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[BarnesG[z], {z, -1 - I, 1 + I}, PlotLegends -> Automatic]

在原点的级数展开：

Wolfram Language code: Series[BarnesG[x], {x, 0, 2}]//FullSimplify

在 Infinity 的级数展开：

Wolfram Language code: Series[BarnesG[x], {x, ∞, 2}]

范围  (27)

数值运算  (6)

数值运算：

Wolfram Language code: BarnesG[0.5]
Wolfram Language code: BarnesG[3]

高精度运算：

Wolfram Language code: N[BarnesG[1 / 7], 20]

输出精度与输入精度一致：

Wolfram Language code: BarnesG[0.222255555666222222222222222]

复数输入：

Wolfram Language code: BarnesG[1.3 + I]

进行高效的高精度运算：

Wolfram Language code: BarnesG[0.5`1000]//Timing
Wolfram Language code: BarnesG[0.7`1000];//Timing

使用 Interval 和 CenteredInterval 对象计算最坏情况下的保证区间：

Wolfram Language code: BarnesG[Interval[{1.17, 1.18}]]
Wolfram Language code: BarnesG[CenteredInterval[1 / 2, 1 / 1000]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: BarnesG[ Around[2.1, 0.01]]

计算数组中每个元素的值：

Wolfram Language code: BarnesG[{{1 / 2, 1}, {1, 1 / 2}}]

或用 MatrixFunction 计算矩阵形式的 BarnesG 函数：

Wolfram Language code: MatrixFunction[BarnesG[#]&, {{1 / 2, 1}, {1, 1 / 2}}]//FullSimplify

特殊值  (4)

无穷处的值：

Wolfram Language code: BarnesG[Infinity]

在零处的值：

Wolfram Language code: BarnesG[0]

在半整数参数下进行符号化运算：

Wolfram Language code: BarnesG[{-1 / 2, 3 / 2}]

使用 1/4 的整数倍进行符号化运算：

Wolfram Language code: BarnesG[{-3 / 4, 1 / 4}]

求第一个正极大值：

Wolfram Language code: xmax = x /. N@Solve[D[BarnesG[x], x] == 0 && 0 < x < 2, x, Reals][[1]]//Quiet
Wolfram Language code: Plot[BarnesG[x], {x, -1, 4}, Epilog -> Style[Point[{xmax, BarnesG[xmax]}], PointSize[Large], Red]]

可视化  (2)

绘制 BarnesG 函数：

Wolfram Language code: Plot[BarnesG[x], {x, -4, 4}]

绘制 的实部：

Wolfram Language code: ComplexContourPlot[Re[BarnesG[z]], {z, -3 - 4I, 3 + 4I}, Contours -> 24]

绘制 的虚部：

Wolfram Language code: ComplexContourPlot[Im[BarnesG[z]], {z, -3 - 4I, 3 + 4I}, Contours -> 24]

函数的属性  (10)

BarnesG 对所有实数和复数有定义：

Wolfram Language code: FunctionDomain[BarnesG[x], x]
Wolfram Language code: FunctionDomain[BarnesG[z], z, Complexes]

BarnesG 的近似值域：

Wolfram Language code: FunctionRange[BarnesG[x], x, y]

BarnesG 是 x 的解析函数：

Wolfram Language code: FunctionAnalytic[BarnesG[x], x]

BarnesG 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[BarnesG[x], x]

BarnesG 不是单射函数：

Wolfram Language code: FunctionInjective[BarnesG[x], x]
Wolfram Language code: Plot[{BarnesG[x], .2}, {x, -4, 4}]

BarnesG 是满射函数：

Wolfram Language code: FunctionSurjective[BarnesG[x], x]
Wolfram Language code: Plot[{BarnesG[x], 5}, {x, -5, 5}]

BarnesG 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[BarnesG[x], x]

BarnesG 没有奇点或断点：

Wolfram Language code: FunctionSingularities[BarnesG[x], x]
Wolfram Language code: FunctionDiscontinuities[BarnesG[x], x]

BarnesG 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[BarnesG[x], x]

TraditionalForm 格式：

Wolfram Language code: BarnesG[z]//TraditionalForm

微分  (2)

关于 z 的一阶导数：

Wolfram Language code: D[BarnesG[z], z]

关于 z 的高阶导数：

Wolfram Language code: Table[D[BarnesG[z], {z, k}], {k, 1, 3}]//FullSimplify

绘制关于 z 的高阶导数：

Wolfram Language code: Plot[%, {z, -4, 4}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

级数展开式  (3)

用 Series 求泰勒展开式：

Wolfram Language code: Series[BarnesG[x], {x, 0, 2}]//Normal//FullSimplify

绘制 处的前三个近似式：

Wolfram Language code: terms = Normal@FullSimplify[Table[Series[BarnesG[x], {x, 0, m}], {m, 1, 5, 2}]]; Plot[{BarnesG[x], terms}, {x, 0, 10}, PlotRange -> {-100, 100}]

普通点上的泰勒展开式：

Wolfram Language code: Series[BarnesG[x], {x, x0, 2}]// Normal//FullSimplify

求 Infinity 处的级数展开式：

Wolfram Language code: Series[BarnesG[x], {x, Infinity, 1}]

应用  (5)

BarnesG 的积分值与 superfactorial 相关：

Wolfram Language code: Table[ Product[k!, {k, n}], {n, 10}]
Wolfram Language code: Table[BarnesG[n + 2], {n, 10}]

BarnesG 可以通过符号求解产生：

Wolfram Language code: Product[Gamma[i] / CatalanNumber[i], i]
Wolfram Language code: Sum[Log[Pochhammer[3, i]], {i, 0, n}]
Wolfram Language code: RSolve[y[i + 1] == i! y[i], y, i]

计算存储一个数值较大的整数所需的比特数：

Wolfram Language code: Log2[BarnesG[500]]//N

与精确结果进行比较：

Wolfram Language code: BitLength[BarnesG[500]]

当 为一个奇质数时，威尔逊定理（Wilson's theorem） 有 TemplateBox[{{{{(, {p, -, 1}, )}, !!}, =, {G, (, {p, +, 1}, )}}, p}, Mod]. 对前几个质数进行验证：

Wolfram Language code: Table[Mod[(p - 1)!!, p] == Mod[BarnesG[p + 1], p], {p, Prime[Range[2, 11]]}]

定义一个由前 个正整数和一个整数位移 构建的柯西矩阵：

Wolfram Language code: cmat[b_, n_Integer] := CauchyMatrix[b + Range[n], Range[n]]

显示任意 值的柯西矩阵：

Wolfram Language code: MatrixForm[cmat[b, 5]]

这个柯西矩阵的行列式可以用 BarnesG 表示. 在前几种情况下，用 的具体数值进行验证：

Wolfram Language code: With[{b = 3, n = 9}, Table[Det[cmat[b, n]] == (BarnesG[n + b + 2]^2BarnesG[n + 1]^2/BarnesG[b + 2]BarnesG[2n + b + 2]), {k, n}]]

属性和关系  (2)

BarnesG 满足一个微分方程：

Wolfram Language code: DSolve[{y[1] == 1, y'[z] == y[z] BarnesG'[z] / BarnesG[z]}, y, z]
Wolfram Language code: y[15] /. First[%]//FullSimplify
Wolfram Language code: BarnesG[15]

FindSequenceFunction 可以识别 BarnesG 序列：

Wolfram Language code: Table[BarnesG[n], {n, 10}]
Wolfram Language code: FindSequenceFunction[%, n]

巧妙范例  (3)

用贝尔数（Bell number）建立的汉克尔矩阵的行列式：

Wolfram Language code: Table[Det[HankelMatrix[BellB[Range[n]], BellB[Range[n, 2n - 1]]]], {n, 10}]
Wolfram Language code: Table[BarnesG[n + 1], {n, 10}]

用欧拉数建立的汉克尔矩阵的行列式：

Wolfram Language code: Table[Det[HankelMatrix[EulerE[Range[0, n - 1]], EulerE[Range[n - 1, 2n - 2]]]], {n, 10}]
Wolfram Language code: Table[(-1)^Binomial[n, 2]BarnesG[n + 1]^2, {n, 10}]

希尔伯特矩阵的行列式可以用巴尼斯 G 函数来表示：

Wolfram Language code: hilbertDet[n_] := BarnesG[n + 1] ^ 4 / BarnesG[2 n + 1]

验证前几种情况的公式：

Wolfram Language code: Table[hilbertDet[n] == Det[HilbertMatrix[n]], {n, 2, 9}]
Wolfram Research (2008)，BarnesG，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BarnesG.html （更新于 2022 年）.

文本

Wolfram Research (2008)，BarnesG，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BarnesG.html （更新于 2022 年）.

CMS

Wolfram 语言. 2008. "BarnesG." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/BarnesG.html.

APA

Wolfram 语言. (2008). BarnesG. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BarnesG.html 年

BibTeX

@misc{reference.wolfram_2026_barnesg, author="Wolfram Research", title="{BarnesG}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/BarnesG.html}", note=[Accessed: 11-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_barnesg, organization={Wolfram Research}, title={BarnesG}, year={2022}, url={https://reference.wolfram.com/language/ref/BarnesG.html}, note=[Accessed: 11-August-2026]}