WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BinarySerialize[expr]

任意の式 expr のバイナリ表現をByteArrayオブジェクトとして与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Method  
PerformanceGoal  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

BinarySerialize

BinarySerialize[expr]

任意の式 expr のバイナリ表現をByteArrayオブジェクトとして与える．

詳細とオプション

  • BinarySerializeには次のオプションが使える．
  • Method Automatic使用する直列化メソッドの詳細
    PerformanceGoal Automaticパフォーマンスのどの面を最適化するか
  • PerformanceGoalの可能な設定には次がある．
  • "Speed"直列化シードおよび非直列化シードの最適化
    "Size"直列化された出力の小ささについて最適化
    Automatic直列化の方法を自動的に選択する
  • Methodの可能な設定には次がある．
  • {typespec1enc1,…}特定のタイプの符号化を指定する
    Automaticデータに基づいて符号化を自動的に選択する
  • 次は，typespeci の可能な形式である．
  • "PackedArrayIntegerType"整数のパックアレー
    "PackedArrayRealType"実数値のパックアレー
    "PackedArrayComplexType"複素数値のパックアレー
  • "PackedArrayIntegerType"の可能な設定には，"Integer8"，"Integer16"，"Integer32"，"Integer64"（64バイトのシステムのみ）がある．
  • "PackedArrayRealType"の可能な設定には"Real32"と"Real64"がある．
  • "PackedArrayComplexType"の可能な設定には，"Complex64"と"Complex128"がある．
  • デフォルトの符号化指定 enciはAutomaticで，この場合はBinarySerializeが与えられたデータに適合するタイプを使用する．
  • BinarySerializeはWXF形式を使う．
  • BinaryDeserializeはBinarySerializeの逆関数である．

例題

すべて開く すべて閉じる

例  (2)

式を直列化する：

Wolfram Language code: BinarySerialize[{1, 2, 3}]

グラフィックスを直列化する：

Wolfram Language code: BinarySerialize[Plot[Sin[x], {x, 0, Pi}]]

直列化された形を式に変換し直す：

Wolfram Language code: BinaryDeserialize[%]

スコープ  (7)

BinarySerializeを記号式に適用する：

Wolfram Language code: BinarySerialize[f[Sin[g[x]]]]

画像を直列化する：

Wolfram Language code: BinarySerialize[[image]]

直列化された形のサイズは式のバイト数とほぼ等しい点に注意のこと：

Wolfram Language code: ByteCount[[image]]

BinarySerializeは効率的に機械サイズ整数を保存する：

Wolfram Language code: BinarySerialize[2 ^ 7 - 1]
Wolfram Language code: BinarySerialize[2 ^ 15 - 1]
Wolfram Language code: BinarySerialize[2 ^ 31 - 1]

BinarySerializeは，効率的に機械実数を保存する：

Wolfram Language code: BinarySerialize[N[1234 / 5678]]

任意精度の実数と比較する：

Wolfram Language code: BinarySerialize[N[1234 / 5678, 16]]

BinarySerializeは，効率的に数列を保存する：

Wolfram Language code: str = FromCharacterCode[RandomInteger[{0, 2 ^ 15}, 1000]];
Wolfram Language code: ByteCount[str]
Wolfram Language code: BinarySerialize[str]

BinarySerializeはByteArrayをサポートする：

Wolfram Language code: BinarySerialize[ByteArray[RandomInteger[255, 1000]]]

BinarySerializeはパックアレーをサポートする：

Wolfram Language code: ints = RandomInteger[2 ^ ($SystemWordLength - 2), 1000]; reals = RandomReal[1, 1000]; complexes = RandomComplex[{0, 1 + I}, 1000];
Wolfram Language code: ByteCount /@ {ints, reals, complexes}
Wolfram Language code: BinarySerialize /@ {ints, reals, complexes}

オプション  (4)

Method  (3)

整数値のパックアレーを作る：

Wolfram Language code: integers = ConstantArray[2 ^ 14, 3];

デフォルトで，BinarySerializeはデータに適合する最小の整数タイプを使用する：

Wolfram Language code: BinarySerialize[integers]

より大きい整数タイプを使ってパックアレーを直列化する：

Wolfram Language code: BinarySerialize[integers, Method -> "PackedArrayIntegerType" -> "Integer32"]

実数値のパックアレーを作る：

Wolfram Language code: reals = RandomReal[1, 3]

このパックアレーを直列化する：

Wolfram Language code: real64 = BinarySerialize[reals]

機械浮動整数を使ってこのパックアレーを直列化する（より小さい出力の精度を犠牲にする）：

Wolfram Language code: real32 = BinarySerialize[reals, Method -> "PackedArrayRealType" -> "Real32"]

複素数値のパックアレーを作る：

Wolfram Language code: complexes = RandomComplex[1 + I, 3]

このパックアレーを直列化する：

Wolfram Language code: BinarySerialize[complexes]

より低い精度でこのパックアレーを直列化する：

Wolfram Language code: BinarySerialize[complexes, Method -> {"PackedArrayComplexType" -> "Complex64"}]

PerformanceGoal  (1)

Datasetを直列化する：

Wolfram Language code: data = ExampleData[{"NetworkGraph", "AstrophysicsCollaborations"}];
Wolfram Language code: uncompressed = BinarySerialize[data]

PerformanceGoalを"Size"に設定して同じDatasetを直列化する：

Wolfram Language code: compressed = BinarySerialize[data, PerformanceGoal -> "Size"]

どちらの形も同じ式を表している：

Wolfram Language code: BinaryDeserialize[uncompressed] == BinaryDeserialize[compressed]

アプリケーション  (1)

訓練されたニューラルネットワークを直列化する：

Wolfram Language code: bin = BinarySerialize[NetTrain[NetGraph[{LinearLayer[1], LinearLayer[3], LinearLayer[3], LinearLayer["Real"]}, {1 -> 2 -> 3 -> 4}, "Input" -> "Real"], {.1 -> .07, .25 -> .24, .3 -> .32, .5 -> .5}, MaxTrainingRounds -> 1000]]

新たなファイルを作る：

Wolfram Language code: file = CreateFile[];

出力バイナリストリームを開く：

Wolfram Language code: ow = OpenWrite[file, BinaryFormat -> True]

直列化した式をファイルに書き込む：

Wolfram Language code: BinaryWrite[ow, bin]
Wolfram Language code: Close[ow];

ファイルからデータを読む：

Wolfram Language code: nettrained = BinaryDeserialize[ByteArray[BinaryReadList[file, "Byte"]]]

ネットワークの予測を入力の関数としてプロットする：

Wolfram Language code: Plot[nettrained[x], {x, 0, 5}]

特性と関係  (4)

PerformanceGoal->"Speed"を使うと速くなるが，大きい出力が生成される：

Wolfram Language code: data = Range[10 ^ 6];
Wolfram Language code: BinarySerialize[data, PerformanceGoal -> "Speed"]//AbsoluteTiming

PerformanceGoal->"Size"を使った方が遅くなるが，出力は小さい：

Wolfram Language code: BinarySerialize[data, PerformanceGoal -> "Size"]//AbsoluteTiming

BinarySerializeは，文字列をUTF-8で符号化する：

Wolfram Language code: bytes = BinarySerialize["→ hello there ←"]
Wolfram Language code: ByteArrayToString[bytes, "UTF-8"]

BinaryDeserializeはBinarySerializeの逆関数である：

Wolfram Language code: BinaryDeserialize[BinarySerialize[x]] === x

DumpSaveはシンボルに付けられた定義をファイルに保存する：

Wolfram Language code: f[x_] := x ^ 2
Wolfram Language code: mx = FileNameJoin[{$TemporaryDirectory, "f.mx"}]; DumpSave[mx, f];

Getを使うとNullが返されるが，f の値は回復される：

Wolfram Language code: Clear[f]; restored = Get[mx]; DeleteFile[mx]; {restored, f[x]}

BinarySerializeは，BinaryDeserializeで回復可能な入力式だけを保存する：

Wolfram Language code: BinarySerialize[f]; Clear[f]; restored = BinaryDeserialize[%%]; {restored, f[x]}

考えられる問題  (2)

小さい式については，PerformanceGoal->"Size"はより小さい出力を生成しないかもしれない：

Wolfram Language code: BinarySerialize[{1, 2, 3}, PerformanceGoal -> "Size"]
Wolfram Language code: BinarySerialize[{1, 2, 3}]

Methodパラメータの"PackedArrayIntegerType"はデータと互換のものを選ばなければならない：

Wolfram Language code: BinarySerialize[ConstantArray[2 ^ 17, 3], Method -> {"PackedArrayIntegerType" -> "Integer16"}]

これらの値には32-ビット整数が必要である：

Wolfram Language code: BinarySerialize[ConstantArray[2 ^ 17, 3], Method -> {"PackedArrayIntegerType" -> "Integer32"}]

Automaticに設定すると，常にデータにフィットしたサイズが使われる：

Wolfram Language code: BinarySerialize[ConstantArray[2 ^ 17, 3], Method -> {"PackedArrayIntegerType" -> Automatic}]
Wolfram Research (2017), BinarySerialize, Wolfram言語関数， https://reference.wolfram.com/language/ref/BinarySerialize.html （2018年に更新）.

テキスト

Wolfram Research (2017), BinarySerialize, Wolfram言語関数， https://reference.wolfram.com/language/ref/BinarySerialize.html （2018年に更新）.

CMS

Wolfram Language. 2017. "BinarySerialize." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2018. https://reference.wolfram.com/language/ref/BinarySerialize.html.

APA

Wolfram Language. (2017). BinarySerialize. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BinarySerialize.html

BibTeX

@misc{reference.wolfram_2026_binaryserialize, author="Wolfram Research", title="{BinarySerialize}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/BinarySerialize.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_binaryserialize, organization={Wolfram Research}, title={BinarySerialize}, year={2018}, url={https://reference.wolfram.com/language/ref/BinarySerialize.html}, note=[Accessed: 10-September-2026]}