WOLFRAM

Wolfram 语言与系统参考资料中心

BinarySerialize[expr]

用 ByteArray 对象给出任何表达式 expr 的二进制表示.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Method  
PerformanceGoal  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

BinarySerialize

BinarySerialize[expr]

用 ByteArray 对象给出任何表达式 expr 的二进制表示.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

序列化一个表达式：

Wolfram Language code: BinarySerialize[{1, 2, 3}]

序列化一个图形：

Wolfram Language code: BinarySerialize[Plot[Sin[x], {x, 0, Pi}]]

把序列化格式转换回表达式：

Wolfram Language code: BinaryDeserialize[%]

范围  (7)

把 BinarySerialize 应用于符号表达式：

Wolfram Language code: BinarySerialize[f[Sin[g[x]]]]

序列化一副图像：

Wolfram Language code: BinarySerialize[[image]]

注意，序列化格式的大小大致等于表达式的字节数：

Wolfram Language code: ByteCount[[image]]

BinarySerialize 有效地存储机器整数：

Wolfram Language code: BinarySerialize[2 ^ 7 - 1]
Wolfram Language code: BinarySerialize[2 ^ 15 - 1]
Wolfram Language code: BinarySerialize[2 ^ 31 - 1]

BinarySerialize 有效地存储机器实数：

Wolfram Language code: BinarySerialize[N[1234 / 5678]]

与任意精度实数比较：

Wolfram Language code: BinarySerialize[N[1234 / 5678, 16]]

BinarySerialize 有效存储字符串：

Wolfram Language code: str = FromCharacterCode[RandomInteger[{0, 2 ^ 15}, 1000]];
Wolfram Language code: ByteCount[str]
Wolfram Language code: BinarySerialize[str]

BinarySerialize 支持 ByteArray：

Wolfram Language code: BinarySerialize[ByteArray[RandomInteger[255, 1000]]]

BinarySerialize 支持打包数组：

Wolfram Language code: ints = RandomInteger[2 ^ ($SystemWordLength - 2), 1000]; reals = RandomReal[1, 1000]; complexes = RandomComplex[{0, 1 + I}, 1000];
Wolfram Language code: ByteCount /@ {ints, reals, complexes}
Wolfram Language code: BinarySerialize /@ {ints, reals, complexes}

选项  (4)

Method  (3)

创建整数值的打包数组：

Wolfram Language code: integers = ConstantArray[2 ^ 14, 3];

默认情况下，BinarySerialize 使用适于数据的最小整数类型：

Wolfram Language code: BinarySerialize[integers]

使用更大的整数类型序列化打包的数组：

Wolfram Language code: BinarySerialize[integers, Method -> "PackedArrayIntegerType" -> "Integer32"]

创建实数值的打包数组：

Wolfram Language code: reals = RandomReal[1, 3]

序列化数组：

Wolfram Language code: real64 = BinarySerialize[reals]

使用机器浮点序列化数组，为了更小的输出而牺牲精度：

Wolfram Language code: real32 = BinarySerialize[reals, Method -> "PackedArrayRealType" -> "Real32"]

创建复数值得打包数组：

Wolfram Language code: complexes = RandomComplex[1 + I, 3]

序列化数组：

Wolfram Language code: BinarySerialize[complexes]

使用更低的精度序列化数组：

Wolfram Language code: BinarySerialize[complexes, Method -> {"PackedArrayComplexType" -> "Complex64"}]

PerformanceGoal  (1)

序列化一个 Dataset：

Wolfram Language code: data = ExampleData[{"NetworkGraph", "AstrophysicsCollaborations"}];
Wolfram Language code: uncompressed = BinarySerialize[data]

序列化同样的 Dataset， PerformanceGoal 设为 "Size"：

Wolfram Language code: compressed = BinarySerialize[data, PerformanceGoal -> "Size"]

两个格式表示同样的表达式：

Wolfram Language code: BinaryDeserialize[uncompressed] == BinaryDeserialize[compressed]

应用  (1)

序列化一个受训的神经网络：

Wolfram Language code: bin = BinarySerialize[NetTrain[NetGraph[{LinearLayer[1], LinearLayer[3], LinearLayer[3], LinearLayer["Real"]}, {1 -> 2 -> 3 -> 4}, "Input" -> "Real"], {.1 -> .07, .25 -> .24, .3 -> .32, .5 -> .5}, MaxTrainingRounds -> 1000]]

创建一个新文件：

Wolfram Language code: file = CreateFile[];

打开一个输出二进制流：

Wolfram Language code: ow = OpenWrite[file, BinaryFormat -> True]

把序列表达式写入文件：

Wolfram Language code: BinaryWrite[ow, bin]
Wolfram Language code: Close[ow];

从文件中读取数据：

Wolfram Language code: nettrained = BinaryDeserialize[ByteArray[BinaryReadList[file, "Byte"]]]

以输入函数绘制网络的预测：

Wolfram Language code: Plot[nettrained[x], {x, 0, 5}]

属性和关系  (4)

使用 PerformanceGoal->"Speed" 更快，但产生更大的输出：

Wolfram Language code: data = Range[10 ^ 6];
Wolfram Language code: BinarySerialize[data, PerformanceGoal -> "Speed"]//AbsoluteTiming

使用 PerformanceGoal->"Size" 更慢，但产生更小的输出：

Wolfram Language code: BinarySerialize[data, PerformanceGoal -> "Size"]//AbsoluteTiming

BinarySerialize 把字符串编码为 UTF-8：

Wolfram Language code: bytes = BinarySerialize["→ hello there ←"]
Wolfram Language code: ByteArrayToString[bytes, "UTF-8"]

BinaryDeserialize 是 BinarySerialize 的反函数：

Wolfram Language code: BinaryDeserialize[BinarySerialize[x]] === x

DumpSave 存储附加在文件中符号的定义：

Wolfram Language code: f[x_] := x ^ 2
Wolfram Language code: mx = FileNameJoin[{$TemporaryDirectory, "f.mx"}]; DumpSave[mx, f];

使用 Get 会返回 Null，但存储 f 的值：

Wolfram Language code: Clear[f]; restored = Get[mx]; DeleteFile[mx]; {restored, f[x]}

BinarySerialize 只存储输入表达式，可以用 BinaryDeserialize 恢复：

Wolfram Language code: BinarySerialize[f]; Clear[f]; restored = BinaryDeserialize[%%]; {restored, f[x]}

可能存在的问题  (2)

对于小型表达式，PerformanceGoal->"Size" 可能不能产生更小的输出：

Wolfram Language code: BinarySerialize[{1, 2, 3}, PerformanceGoal -> "Size"]
Wolfram Language code: BinarySerialize[{1, 2, 3}]

Method 参数 "PackedArrayIntegerType" 必须与数据选择一致：

Wolfram Language code: BinarySerialize[ConstantArray[2 ^ 17, 3], Method -> {"PackedArrayIntegerType" -> "Integer16"}]

这些值需要 32 位整数：

Wolfram Language code: BinarySerialize[ConstantArray[2 ^ 17, 3], Method -> {"PackedArrayIntegerType" -> "Integer32"}]

Automatic 的设置将总是使用适于数据的尺寸：

Wolfram Language code: BinarySerialize[ConstantArray[2 ^ 17, 3], Method -> {"PackedArrayIntegerType" -> Automatic}]
Wolfram Research (2017)，BinarySerialize，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BinarySerialize.html （更新于 2018 年）.

文本

Wolfram Research (2017)，BinarySerialize，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BinarySerialize.html （更新于 2018 年）.

CMS

Wolfram 语言. 2017. "BinarySerialize." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2018. https://reference.wolfram.com/language/ref/BinarySerialize.html.

APA

Wolfram 语言. (2017). BinarySerialize. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BinarySerialize.html 年

BibTeX

@misc{reference.wolfram_2026_binaryserialize, author="Wolfram Research", title="{BinarySerialize}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/BinarySerialize.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_binaryserialize, organization={Wolfram Research}, title={BinarySerialize}, year={2018}, url={https://reference.wolfram.com/language/ref/BinarySerialize.html}, note=[Accessed: 18-August-2026]}