BinomialProcess

事象確率が p の二項過程を表す．

詳細

BinomialProcessは，離散時間・離散状態の過程である．
時間 n におけるBinomialProcessは0から n までの区間内の事象数である．
0から n までの区間内の事象数はBinomialDistribution[n,p]に従う．
事象間の時間は独立でGeometricDistribution[p]に従う．
BinomialProcessは，Mean，PDF，Probability，RandomFunction等の関数に使うことができる．

例題

すべて開くすべて閉じる

例 (3)

二項過程のシミュレーションを行う：

Wolfram Language code: data = RandomFunction[BinomialProcess[1 / 3], {0, 50}]

Wolfram Language code: ListPlot[data, Filling -> Axis]

平均値関数と分散関数：

Wolfram Language code: Mean[BinomialProcess[p][t]]

Wolfram Language code: Variance[BinomialProcess[p][t]]

共分散関数：

Wolfram Language code: CovarianceFunction[BinomialProcess[p], s, t]

Wolfram Language code:

DiscretePlot3D[CovarianceFunction[BinomialProcess[.3], s, t], {s, 1, 10}, {t, 1, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

スコープ (11)

基本的な用法 (5)

経路の集合のシミュレーションを行う：

Wolfram Language code: data = RandomFunction[BinomialProcess[0.4], {0, 50}, 4]

Wolfram Language code: ListPlot[data, Filling -> Axis]

さまざまな過程母数の値について経路を比較する：

Wolfram Language code: sample[p_] := (SeedRandom[3];RandomFunction[BinomialProcess[p], {0, 30}])

Wolfram Language code: pars = {.1, .4, .7};

Wolfram Language code: ListPlot[sample[#], Filling -> Axis, PlotLabel -> StringJoin["p = ", ToString[#]]]& /@ pars

過程母数推定：

Wolfram Language code: sample = RandomFunction[BinomialProcess[.3], {1, 10 ^ 3}];

分布母数をサンプルデータから推定する：

Wolfram Language code: edist = EstimatedProcess[sample, BinomialProcess[p]]

相関関数：

Wolfram Language code: CorrelationFunction[BinomialProcess[p], s, t]

絶対相関関数：

Wolfram Language code: AbsoluteCorrelationFunction[BinomialProcess[p], s, t]

過程スライス特性 (6)

一変量SliceDistribution：

Wolfram Language code:

DiscretePlot[Evaluate@Table[PDF[BinomialProcess[.8][t], x], {t, times = {5, 7, 12}}], {x, 0, 15}, PlotStyle -> PointSize[Medium], PlotLegends -> (StringJoin["t = ", ToString[#]]& /@ times)]

Wolfram Language code: SliceDistribution[BinomialProcess[p], t]

一変量確率密度：

Wolfram Language code: PDF[BinomialProcess[p][t], x]

BinomialDistributionの確率密度と比較する：

Wolfram Language code: PDF[BinomialDistribution[t, p], x]

Wolfram Language code: % - %%

複数の時間スライスの分布：

Wolfram Language code: SliceDistribution[BinomialProcess[p], {1, 3, 7}]//Mean

高次確率密度関数：

Wolfram Language code: PDF[BinomialProcess[.3][{1, 3, 7}], {x, y, z}]

式の期待値を計算する：

Wolfram Language code: Expectation[x[t] ^ 2 + x[t], xBinomialProcess[p]]//PiecewiseExpand

事象の確率を計算する：

Wolfram Language code: Probability[x[t] > 8, xBinomialProcess[p]]

歪度：

Wolfram Language code:

DiscretePlot[Evaluate@Table[Skewness[BinomialProcess[p][t]], {p, pars = {.1, .3, .5, .7}}], {t, 1, 8}, PlotLegends -> (StringJoin["p = ", ToString[#]]& /@ pars)]

Wolfram Language code: Skewness[BinomialProcess[p][t]]

極限値：

Wolfram Language code: Limit[Skewness[BinomialProcess[p][t]], t -> ∞, Assumptions -> 1 > p > 0]

Wolfram Language code: Limit[Skewness[BinomialProcess[p][t]], t -> 0, Assumptions -> 1 > p > 0, Direction -> "FromAbove"]

BinomialProcessが母数のどの値について対称になるかを求める：

Wolfram Language code: Solve[Skewness[BinomialProcess[p][t]] == 0, p]

尖度：

Wolfram Language code:

DiscretePlot[Evaluate@Table[Kurtosis[BinomialProcess[p][t]], {p, pars = {.1, .2, .5, .7}}], {t, 1, 8}, PlotLegends -> (StringJoin["p = ", ToString[#]]& /@ pars)]

Wolfram Language code: Kurtosis[BinomialProcess[p][t]]

極限値：

Wolfram Language code: Limit[Kurtosis[BinomialProcess[p][t]], t -> ∞, Assumptions -> 1 > p > 0]

Wolfram Language code: Limit[Kurtosis[BinomialProcess[p][t]], t -> 0, Assumptions -> 1 > p > 0, Direction -> "FromAbove"]

BinomialProcessが母数のどの値について尖度が0になるかを求める：

Wolfram Language code: Solve[Kurtosis[BinomialProcess[p][t]] == 3, p]

Wolfram Language code: N[%]

Momentは記号次数について閉形式を持たない：

Wolfram Language code: Moment[BinomialProcess[p][t], 4]

母関数：

Wolfram Language code: CharacteristicFunction[BinomialProcess[p][t], w]

Wolfram Language code: MomentGeneratingFunction[BinomialProcess[p][t], w]

CentralMomentは記号次数について閉形式をたない：

Wolfram Language code: CentralMoment[BinomialProcess[p][t], 3]

Wolfram Language code: CentralMomentGeneratingFunction[BinomialProcess[p][t], w]

FactorialMomentとその母関数：

Wolfram Language code: FactorialMoment[BinomialProcess[p][t], r]

Wolfram Language code: FactorialMomentGeneratingFunction[BinomialProcess[p][t], w]

Cumulantは記号次数で閉形式をたない：

Wolfram Language code: Cumulant[BinomialProcess[p][t], 7]

Wolfram Language code: CumulantGeneratingFunction[BinomialProcess[p][t], w]

アプリケーション (4)

不良品が全体の20%になることで知られている製造工程から，品質管理検査官が一連の10個のパーツを無作為に選んだ．検査官が，多くても1個の不良品にしか当らない確率を求める：

Wolfram Language code: selectionProcess = BinomialProcess[0.2];

多くても1個の不良品にしか当らない確率：

Wolfram Language code: NProbability[x[10] ≤ 1, xselectionProcess]

ある都市住民の平均50%が特定のテレビ番組を好むことが知られている．選ばれた804人の住民の少なくとも55%がその番組を好む確率を求める：

Wolfram Language code: programPopularity = BinomialProcess[0.5];

サンプル中の少なくとも55%の住民が，そのプログラムを好む確率：

Wolfram Language code:

n = 804;
Probability[x[n] / n ≥ 0.55, xprogramPopularity]

個の記号の文字列からなるパケットがノイズの多いチャンネルを通して送信された．各記号の送信エラーの確率は0.0001である．不正確な送信（少なくても1つの記号の送信にエラーがある）の確率が0.001未満であるの最大値を求める：

Wolfram Language code: transmissionProcess = BinomialProcess[1 / 10000];

送信エラーの確率：

Wolfram Language code: prob[n_] = Probability[x > 0, xtransmissionProcess[n]]

送信エラーの確率をエラー限界とともにプロットする：

Wolfram Language code:

errlimit = 1 / 1000;
ListLogPlot[Transpose@Table[{prob[n], errlimit}, {n, 0, 15}], Joined -> True, PlotLegends -> {"probability", "error limit"}]

送信エラーが未満であるの最大値を求める：

Wolfram Language code: Maximize[{n, prob[n] ≤ errlimit && n∈Integers && 5 ≤ n ≤ 15}, n]

多期二項モデルにおいて第3期が過ぎた後の，ヨーロピアンコールオプションの価格を求める．もとになっているモデルの初期価格100ドル，行使価格102ドル，利率1パーセント，株式は7パーセント上昇あるいは1/1.07倍で下降するものとする：

Wolfram Language code:

s0 = 100;
strike = 102;
rate = 1.01;
up = 1.07;
down = 1 / 1.07;
T = 3;

この過程をモデル化する：

Wolfram Language code: price = BinomialProcess[(rate - down) / (up - down)];

コールオプションの価格：

Wolfram Language code: Expectation[1 / rate ^ T Max[s0 up ^ proc[T] down ^ (T - proc[T]) - strike, 0], procprice]

特性と関係 (5)

二項過程は p が0のときにのみ弱定常である：

Wolfram Language code: WeakStationarity[BinomialProcess[p]]

BinomialProcess は，のとき，BernoulliProcess の合計である：

Wolfram Language code:

SeedRandom[3];
bernoulli = RandomFunction[BernoulliProcess[p = 17 / 32], {20}];

Wolfram Language code: ListPlot[bernoulli, Filling -> Axis]

サンプルを累積する：

Wolfram Language code: accumulated = Accumulate[bernoulli]

Wolfram Language code: ListPlot[accumulated, Filling -> Axis]

二項過程と比較する：

Wolfram Language code:

SeedRandom[3];
sample = RandomFunction[BinomialProcess[p], {1, 21}];

タイムスタンプを揃える：

Wolfram Language code: binomial = TimeSeriesShift[sample, -1];

Wolfram Language code:

ListPlot[{binomial, accumulated}, Filling -> Axis, PlotStyle -> {PointSize[.05], PointSize[0.02]}, PlotLegends -> {"binomial", "accumulated Bernoulli"}]

二項過程における事象間の時間はPascalDistributionに従う：

Wolfram Language code: binomial = RandomFunction[BinomialProcess[1 / 3], {10 ^ 4}];

変化と変化の間の時間を計算する：

Wolfram Language code: times = Length /@ Split[binomial["Values"]];

Wolfram Language code: h = Histogram[times, {Min[times] - 0.5, Max[times] + 0.5, 1}, "PDF"]

パスカル分布をフィットする：

Wolfram Language code: edist = EstimatedDistribution[times, PascalDistribution[1, p]]

データヒストグラムを推定された確率密度関数と比較する：

Wolfram Language code: Show[h, DiscretePlot[PDF[edist, x], {x, 0, Max[times]}, PlotStyle -> PointSize[Medium]]]

適合度を調べる：

Wolfram Language code: DistributionFitTest[times, edist, "TestConclusion"]

2つの状態間の推移確率：

Wolfram Language code:

Table[DiscretePlot[Probability[(x[12] == Subscript[x, 2])(x[7] == Subscript[x, 1]), xBinomialProcess[.6]], {Subscript[x, 2], 0, 13}, ExtentSize -> 1 / 2, PlotLabel -> StringJoin["SubscriptBox[x, 1] = ", ToString[Subscript[x, 1]]]], {Subscript[x, 1], {1, 3, 5, 7}}]

Wolfram Language code:

Probability[(x[Subscript[t, 2]] == Subscript[x, 2])(x[Subscript[t, 1]] == Subscript[x, 1]), xBinomialProcess[p], Assumptions -> 0 < Subscript[t, 1] < Subscript[t, 2] && 0 ≤ Subscript[x, 1] ≤ Subscript[t, 1] && 0 ≤ Subscript[x, 2] ≤ Subscript[t, 2]]//Simplify

BinomialProcessは，CompoundRenewalProcessの特殊ケースである：

Wolfram Language code: proc = CompoundRenewalProcess[PascalDistribution[1, p], BernoulliDistribution[1]];

平均値関数は一致する：

Wolfram Language code: proc[t]//Mean

Wolfram Language code: Mean[BinomialProcess[p][t]]

経験的共分散関数を作成する：

Wolfram Language code: sample1 = RandomFunction[proc /. p -> .3, {30}, 10 ^ 3];

Wolfram Language code: cov1[s_, t_] := Covariance[sample1["SliceData", s], sample1["SliceData", t]]

Wolfram Language code: sample2 = RandomFunction[BinomialProcess[.3], {0, 30}, 10 ^ 3];

Wolfram Language code: cov2[s_, t_] := Covariance[sample2["SliceData", s], sample2["SliceData", t]]

共分散関数を比較する：

Wolfram Language code:

DiscretePlot3D[#[s, t], {s, 1, 15}, {t, 1, 15}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow", PlotRange -> {0, 4}]& /@ {cov1, cov2}

おもしろい例題 (1)

二項過程から500経路のシミュレーションを行う：

Wolfram Language code: data = RandomFunction[BinomialProcess[.7], {50}, 500];

50におけるスライスを取り，その分布を可視化する：

Wolfram Language code: sd = data["SliceData", 50];

Wolfram Language code:

cf = ColorData["Rainbow"];
sliced = BarChart[Last[#], Axes -> False, BarOrigin -> Left, AspectRatio -> 4, ChartStyle -> (cf /@ Rescale[MovingAverage[First[#], 2], {Min[sd], Max[sd]}, {0, 1}]), ImageSize -> 30]&[HistogramList[sd, {Range[Min[sd], Max[sd], (Max[sd] - Min[sd]) / 15]}]];

50におけるスライス分布の経路とヒストグラムの分布をプロットする：

Wolfram Language code:

ListLinePlot[data, ImageSize -> 400, PlotRange -> All, 
	AspectRatio -> 3 / 4, Epilog -> Inset[sliced, {50.5, Mean[sd]}, {0, 7.5}], PlotStyle -> (cf /@ Rescale[sd]), BaseStyle -> Directive[Thin, Opacity[0.5]], PlotRangePadding -> {{0, 20}, {.5, 7}}]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

BinomialProcess

詳細

例題

例 (3)

スコープ (11)

基本的な用法 (5)

過程スライス特性 (6)

アプリケーション (4)

特性と関係 (5)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

BinomialProcess

詳細

例題

例 (3)

スコープ (11)

基本的な用法 (5)

過程スライス特性 (6)

アプリケーション (4)

特性と関係 (5)

おもしろい例題 (1)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX