WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BlockMap[f,list,n]

list 中の長さ n の重なり合ない部分リストに f を適用する．

BlockMap[f,list,n,d]

list 中の部分リストにオフセット d で f を適用する．

BlockMap[f,list,{n1,n2,…},…]

f をサイズ n1×n2×…のブロックに適用する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

BlockMap

BlockMap[f,list,n]

list 中の長さ n の重なり合ない部分リストに f を適用する．

BlockMap[f,list,n,d]

list 中の部分リストにオフセット d で f を適用する．

BlockMap[f,list,{n1,n2,…},…]

f をサイズ n1×n2×…のブロックに適用する．

詳細

  • BlockMap[f,list,n]で f に渡される部分リストの長さはすべて n である．list の末尾にある要素の中には訪れられないものがあるかもしれない．
  • BlockMap[f,list,n,1]では，list の全要素が少なくとも1つの部分リストに含まれる．
  • BlockMap[f,list,n,d]で，d が n より大きければ，list の中間部分の要素に飛ばされるものが出る． »
  • BlockMapはSparseArrayオブジェクトに使うことができる．

例題

すべて開く すべて閉じる

例  (4)

重なり合ない長さ2のすべての部分リストに関数を適用する：

Wolfram Language code: BlockMap[f, Range[10], 2]

長さ2の重なり合う部分リストにオフセット1で関数を適用する：

Wolfram Language code: BlockMap[f, Range[10], 2, 1]

関数を行列に適用する：

Wolfram Language code: BlockMap[f, (| | | | | | ---- | ---- | ---- | ---- | | 1 | 2 | 3 | 4 | | 10 | 20 | 30 | 40 | | 100 | 200 | 300 | 400 | | 1000 | 2000 | 3000 | 4000 |), 2];
Wolfram Language code: Map[MatrixForm, %, {2}]

2x2のすべての部分行列に関数を適用する：

Wolfram Language code: BlockMap[f, (| | | | | | ---- | ---- | ---- | ---- | | 1 | 2 | 3 | 4 | | 10 | 20 | 30 | 40 | | 100 | 200 | 300 | 400 | | 1000 | 2000 | 3000 | 4000 |), {2, 2}];
Wolfram Language code: MatrixForm@Map[MatrixForm, %, {3}]

スコープ  (8)

不揃いな配列に関数を適用する：

Wolfram Language code: BlockMap[f, {{1, 2, 3, 4}, {5, 6}, 7, {{"hello"}}}, 2]

関数を階数3の配列のサイズ{2,1,2}のブロックに適用する：

Wolfram Language code: BlockMap[f, ArrayReshape[Range@48, {6, 2, 4}], {2, 1, 2}]

ブロックサイズ{2,2}でオフセット{1,2}を指定して，行は重なっても列は重ならないようにする：

Wolfram Language code: BlockMap[f, (| | | | | | ---- | ---- | ---- | ---- | | 1 | 2 | 3 | 4 | | 10 | 20 | 30 | 40 | | 100 | 200 | 300 | 400 | | 1000 | 2000 | 3000 | 4000 |), {2, 2}, {1, 2}];
Wolfram Language code: MatrixForm@Map[MatrixForm, %, {3}]

多次元オフセットは，事実上，強制的にブロックサイズ指定にマッチするようにされる：

Wolfram Language code: BlockMap[f, (| | | | | | ---- | ---- | ---- | ---- | | 1 | 2 | 3 | 4 | | 10 | 20 | 30 | 40 | | 100 | 200 | 300 | 400 | | 1000 | 2000 | 3000 | 4000 |), 2, {1, 2}]; MatrixForm@Map[MatrixForm, %, {3}]

ブロックサイズより大きいオフセットを使って要素を飛ばす：

Wolfram Language code: BlockMap[f, {1, 2, 3, 4, 5, 6, 7, 8}, 2, 3]

終端の不完全な部分リストは除去される：

Wolfram Language code: BlockMap[f, {1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11}, 4]

頭部はListではなくてもよい：

Wolfram Language code: BlockMap[f, h[1, 2, 3, 4], 2]
Wolfram Language code: BlockMap[f, h[h[1, 2, 3], h[4, 5, 6]], {2, 2}, 1]

BlockMapはSparseArrayオブジェクトに使うことができる：

Wolfram Language code: BlockMap[f, SparseArray[{i_, i_} -> 1, {6, 6}], {2, 2}]
Wolfram Language code: MatrixForm@Map[MatrixForm, %, {3}]

アプリケーション  (5)

要素の逐次差分を計算する：

Wolfram Language code: BlockMap[Last[#] - First[#]&, {a, b, c, d, e, f}, 2, 1]

3要素の連なりの移動平均を計算する：

Wolfram Language code: BlockMap[Mean, {a, b, c, d, e}, 3, 1]

行列の移動中央値を計算する：

Wolfram Language code: BlockMap[Median, {{1, 2}, {5, 3}, {1, 4}, {3, 2}, {5, 5}}, 2, 1]

あるデータの移動分位点を計算する：

Wolfram Language code: data = RandomFunction[WienerProcess[], {0, 10, 0.1}]["Values"];
Wolfram Language code: mq = BlockMap[Quantile[#, 0.75]&, data, 3, 1];
Wolfram Language code: ListLinePlot[{Rest@data, mq}]

シミュレーション結果の粒子軌道を平滑化する：

Wolfram Language code: n[] := RandomReal[CauchyDistribution[0, 1]]
Wolfram Language code: f[] := {u Cos[u] + n[], u Sin[u] + n[]};
Wolfram Language code: data = Table[f[], {u, 0, 6π, 1 / 100}];

もとになっている信号とノイズのあるシミュレーション結果の経路：

Wolfram Language code: {ParametricPlot[{u Cos[u], u Sin[u]}, {u, 0, 6π}], pd = ListPlot[data, AspectRatio -> 1]}

移動TrimmedMeanを使って軌道を平滑化する：

Wolfram Language code: smooth[r_] := BlockMap[TrimmedMean, data, r, 1]

窓を大きくすると軌道がより滑らかになる：

Wolfram Language code: Table[ListPlot[smooth[r], AspectRatio -> 1], {r, {25, 50, 100}}]

特性と関係  (2)

BlockMapは，事実上，MapとPartitionを使うことに等しい：

Wolfram Language code: BlockMap[f, Range[100], 4, 1] === Map[f, Partition[Range[100], 4, 1]]

BlockMapはすべての部分リストを構築する必要はなく，したがってメモリも少なくてよい：

Wolfram Language code: x = Range[10 ^ 4]; ByteCount[x]
Wolfram Language code: MemoryConstrained[BlockMap[Total, x, 4];, 10 ^ 5]
Wolfram Language code: MemoryConstrained[Map[Total, Partition[x, 4]];, 10 ^ 5]

ListCorrelate[ker,list]は，事実上，ker を list 中のスライディングブロックと組み合せる：

Wolfram Language code: ker = {x, y}; list = Range[10];
Wolfram Language code: ListCorrelate[ker, list]

BlockMapでオフセット 1 を使って関数を長さ ker の重なっている部分に適用する：

Wolfram Language code: BlockMap[ker.#&, list, Length[ker], 1]

ListConvolveは，カーネルの向きが逆である点を除いて同じである：

Wolfram Language code: ListConvolve[ker, list]
Wolfram Language code: BlockMap[Reverse[ker].#&, list, Length[ker], 1]
Wolfram Research (2015), BlockMap, Wolfram言語関数， https://reference.wolfram.com/language/ref/BlockMap.html.

テキスト

Wolfram Research (2015), BlockMap, Wolfram言語関数， https://reference.wolfram.com/language/ref/BlockMap.html.

CMS

Wolfram Language. 2015. "BlockMap." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BlockMap.html.

APA

Wolfram Language. (2015). BlockMap. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BlockMap.html

BibTeX

@misc{reference.wolfram_2026_blockmap, author="Wolfram Research", title="{BlockMap}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/BlockMap.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_blockmap, organization={Wolfram Research}, title={BlockMap}, year={2015}, url={https://reference.wolfram.com/language/ref/BlockMap.html}, note=[Accessed: 12-August-2026]}