WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BooleanTable[bf]

ブール関数 bf に渡された変数値のすべての可能な組合せに対する真理値のリストを返す．

BooleanTable[expr,{a1,a2,…}]

aiの値のすべての可能な組合せに対するブール式 expr の真理値のリストを返す．

BooleanTable[expr,{a1,a2,…},{b1,…},…]

最も外側のレベルが aiの可能な組合せを与える expr のネストした真理値表を返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
アプリケーション  
確率  
セルオートマトン  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

BooleanTable

BooleanTable[bf]

ブール関数 bf に渡された変数値のすべての可能な組合せに対する真理値のリストを返す．

BooleanTable[expr,{a1,a2,…}]

aiの値のすべての可能な組合せに対するブール式 expr の真理値のリストを返す．

BooleanTable[expr,{a1,a2,…},{b1,…},…]

最も外側のレベルが aiの可能な組合せを与える expr のネストした真理値表を返す．

詳細

  • 変数値の可能な組合せはTuples[{True,False},n]の順で与えられる．
  • BooleanTableはTrue，Falseの値の配列のリストを返す．
  • Boole[BooleanTable[…]]は1，0の値を返す．
  • BooleanTable[expr,{a1,a2,…}]等では，ai等の中で明示的ではない expr 中の任意の変数は記号形式のままで残される．
  • BooleanTable[expr,vars1,…,varss]はFold[BooleanTable,expr,{varss,…,vars1}]と等価である． »
  • BooleanTable[bf,{r1,r2,…}]はブール関数 bf の r1, r2, … 番目の変数の可能な値に対応する真理値のリストを与える．
  • BooleanTable[bf,{r1,…},{s1,…},…]は，最も外側のレベルが ri番目の変数の組合せを与える真理値のネストした表を与える． »

例題

すべて開く すべて閉じる

例  (2)

Orの真理値のベクトル：

Wolfram Language code: BooleanTable[p || q, {p, q}]

1, 0形式に変換する：

Wolfram Language code: Boole[BooleanTable[p || q, {p, q}]]

Orの2Dの真理値表：

Wolfram Language code: BooleanTable[p || q, {p}, {q}]//TableForm

スコープ  (6)

ブール式の真理値表を生成する：

Wolfram Language code: BooleanTable[And[a, b], {a, b}]
Wolfram Language code: BooleanTable[And[a, b, c], {a, b, c}]

引数と値を持つ真理値表：

Wolfram Language code: BooleanTable[{a, b, And[a, b]}, {a, b}]//TableForm

ベクトル値のブール式：

Wolfram Language code: BooleanTable[{And[a, b], Or[a, b], Xor[a, b], Xnor[a, b]}, {a, b}]//TableForm

2Dの真理値表：

Wolfram Language code: BooleanTable[And[a, b], {a}, {b}]

3Dの真理値表：

Wolfram Language code: BooleanTable[And[a, b, c], {a}, {b}, {c}]

純ブール関数の真理値表を生成する：

Wolfram Language code: BooleanTable[BooleanFunction[30, 3]]
Wolfram Language code: BooleanTable[BooleanCountingFunction[2, 3]]
Wolfram Language code: BooleanTable[And[#1, #2, #3]&]

使用する引数の位置を指定する：

Wolfram Language code: BooleanTable[BooleanFunction[30, 3], {3, 1, 2}]
Wolfram Language code: BooleanTable[BooleanFunction[30, 3][a, b, c], {c, a, b}]

使用する引数の位置とグループ化：

Wolfram Language code: BooleanTable[BooleanFunction[30, 3], {1, 2}, {3}]

式はブール値を生成しなくてもよい：

Wolfram Language code: BooleanTable[f[a, b], {a, b}]
Wolfram Language code: BooleanTable[{a, b} -> And[a, b], {a, b}]
Wolfram Language code: BooleanTable[Xor[a, b, c], {a, b}]
Wolfram Language code: BooleanTable[Graphics[{If[a, Red, Green], If[b, EdgeForm[Yellow], EdgeForm[Blue]], If[c, Disk[], Rectangle[]]}, ImageSize -> 30], {a, b, c}]

一般化と拡張  (1)

値のリストを明示的に与えずに真理値表を生成する：

Wolfram Language code: t1 = BooleanTable[And[c, Or[a, b]]]

使用する変数と順序はBooleanVariablesによって与えられる：

Wolfram Language code: v = BooleanVariables[And[c, Or[a, b]]]
Wolfram Language code: t2 = BooleanTable[And[c, Or[a, b]], v]
Wolfram Language code: t1 === t2

アプリケーション  (3)

確率  (2)

イベントの確率を合計と真となる場合の割合として計算する：

Wolfram Language code: BooleanProbability[e_, v_] := Count[BooleanTable[e, v], True] / 2 ^ Length[v]

いくつかのイベントの確率：

Wolfram Language code: BooleanProbability[x∧y, {x, y}]
Wolfram Language code: BooleanProbability[Xor[x, y, z, w], {x, y, z, w}]

明示的に3つの変数が真となる確率：

Wolfram Language code: BooleanProbability[BooleanCountingFunction[{3}, {x, y, z, u, v}], {x, y, z, u, v}]

を示す：

Wolfram Language code: BooleanProbability[x∨y, {x, y}]
Wolfram Language code: BooleanProbability[x, {x, y}] + BooleanProbability[y, {x, y}] - BooleanProbability[x∧y, {x, y}]

のときに2単位支払い， のときに1単位儲けると仮定する：

Wolfram Language code: BooleanTable[-2 Boole[x∧y] + Boole[Xor[x, y, z]], {x, y, z}]

x,y,z のそれぞれが真または偽となる確率が等しいときの予想される儲け：

Wolfram Language code: Mean[%]

リスクすなわち分散：

Wolfram Language code: Variance[%%]

セルオートマトン  (1)

ブール式の真理規則を生成する：

Wolfram Language code: BooleanTable[{a, b, c} -> BooleanFunction[30, {a, b, c}], {a, b, c}]

セルオートマトンを進化させる規則を使う：

Wolfram Language code: CellularAutomaton[%, {{True}, False}, 2]
Wolfram Language code: CellularAutomaton[30, {{1}, 0}, 2]
Wolfram Language code: Boole[%%]

特性と関係  (6)

n 個の変数と個の要素を持つBooleanTable：

Wolfram Language code: X[n_] := Array[x, n]
Wolfram Language code: Table[Length@BooleanTable[Xor@@X[n], X[n]], {n, 10}]

変数が n と m のとき，結果の行列には個の値がある：

Wolfram Language code: Y[n_] := Array[y, n]
Wolfram Language code: Table[Dimensions@BooleanTable[Xor@@Join[X[n], Y[m]], X[n], Y[m]], {n, 5}, {m, 5}];
Wolfram Language code: Apply[Times, %, {2}]//MatrixForm

いくつかの変数の反復があるBooleanTableは最初に最も外側の反復子を評価する：

Wolfram Language code: f = BooleanFunction[12345, 5][a, b, c, d, e]
Wolfram Language code: t1 = BooleanTable[f, {a, b}, {c, d, e}]

同等の形：

Wolfram Language code: t2 = Fold[BooleanTable, f, {{c, d, e}, {a, b}}]
Wolfram Language code: t1 === t2

BooleanTableはTuples[{True,False},n]と同じ順序で値を列挙する：

Wolfram Language code: BooleanTable[Xor[a, b], {a, b}]
Wolfram Language code: Xor@@@Tuples[{True, False}, 2]

3つの変数：

Wolfram Language code: BooleanTable[Xnor[a, b, c], {a, b, c}]
Wolfram Language code: Xnor@@@Tuples[{True, False}, 3]

SatisfiabilityCountは事実上BooleanTable中のTrue要素の数を数える：

Wolfram Language code: Count[BooleanTable[BooleanFunction[200!, 10]], True]
Wolfram Language code: SatisfiabilityCount[BooleanFunction[200!, 10]]

この場合，BooleanTableは個の要素を持つだろう：

Wolfram Language code: SatisfiabilityCount[BooleanCountingFunction[500, 1000]]

列挙されたBooleanFunctionを返す：

Wolfram Language code: BooleanFunction[30, 3]

上記の真理値表を計算する：

Wolfram Language code: Boole[BooleanTable[%]]

列挙順はFromDigitsに等しい：

Wolfram Language code: FromDigits[%, 2]

BooleanFunctionを使って真理値表を関数または式に変換する：

Wolfram Language code: t = BooleanTable[Implies[a, b], {a, b}]

ブール関数に変換する：

Wolfram Language code: f = BooleanFunction[t]

他の任意の関数としてこれを使う：

Wolfram Language code: BooleanTable[f[a, b], {a, b}]

選言標準形に変換する：

Wolfram Language code: BooleanFunction[t, {a, b}]

「NAND」形に変換する：

Wolfram Language code: BooleanFunction[t, {a, b}, "NAND"]

おもしろい例題  (1)

BooleanCountingFunctionの真理値表：

Wolfram Language code: f = BooleanCountingFunction[8, 16]@@Array[x, 16];
Wolfram Language code: ArrayPlot[Boole@BooleanTable[f, Array[x, 8], Array[x, 8, 9]]]
Wolfram Research (2008), BooleanTable, Wolfram言語関数， https://reference.wolfram.com/language/ref/BooleanTable.html.

テキスト

Wolfram Research (2008), BooleanTable, Wolfram言語関数， https://reference.wolfram.com/language/ref/BooleanTable.html.

CMS

Wolfram Language. 2008. "BooleanTable." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BooleanTable.html.

APA

Wolfram Language. (2008). BooleanTable. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BooleanTable.html

BibTeX

@misc{reference.wolfram_2026_booleantable, author="Wolfram Research", title="{BooleanTable}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/BooleanTable.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_booleantable, organization={Wolfram Research}, title={BooleanTable}, year={2008}, url={https://reference.wolfram.com/language/ref/BooleanTable.html}, note=[Accessed: 18-August-2026]}