WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CalendarType

すべての日付を解釈し出力するために使われる暦体系を決定するオプションである．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

CalendarType

CalendarType

すべての日付を解釈し出力するために使われる暦体系を決定するオプションである．

詳細

  • CalendarTypeは，通常，暦が指定されていない日付をどのように解釈するかを指定するため，または他の暦から日付オブジェクトを変換するために使用される．
  • 一般に，CalendarTypeは，デフォルトで，"Gregorian"に設定されている．
  • 日付の暦は，"Gregorian"あるいは"Julian"のような名前付きのオブジェクトとして，あるいはデフォルト以外のパラメータ値の暦については{"name",<|param1val1,param2value2,…|>}の形で与えられる．
  • 以下は暦のパラメータである．
  • "YearZero"暦が0年を含むかどうか
    "StartOfDay"日がいつ始まるか
    "Location"天文暦の参照測地位置
  • デフォルトの暦のパラメータはCalendarData["name"]で入手できる．
  • 次は，著名な算術暦である．
  • "Gregorian"先発グレゴリオ暦
    "Islamic"表形式のイスラム暦
    "Jewish"算術ヘブライ太陰太陽暦
    "Julian"先発ユリウス暦
  • 他にもCalendarData["ArithmeticCalendar"]で与えられる算術暦がある．天文暦はCalendarData["AstronomicalCalendar"]で得ることができる．

例題

すべて開く すべて閉じる

例  (3)

現行の日付をユダヤ暦で表す：

Wolfram Language code: DateObject[CalendarType -> "Jewish"]

ユリウス暦の日付を表す：

Wolfram Language code: DateObject[{2026, 8, 4}, CalendarType -> "Julian"]

中国太陰暦の翌月を求める：

Wolfram Language code: NextDate["Month", CalendarType -> "Chinese"]

"StartOfDay"あるいは"YearZero"の扱い方は，パラメータ化された暦を使って調節できる：

Wolfram Language code: DateObject[{1, 1, 1}, CalendarType -> "Gregorian"] - Quantity[2, "Days"]
Wolfram Language code: DateObject[{1, 1, 1}, CalendarType -> {"Gregorian", <|"YearZero" -> True|>}] - Quantity[2, "Days"]

スコープ  (3)

イスラム暦のラマダン月を表す：

Wolfram Language code: DateInterval[DateObject[{1446, 9}, "Month", "Islamic"], CalendarType -> "Islamic"]

日付範囲を計算し，その日付をイスラム暦で返す：

Wolfram Language code: DateRange[DateObject[{2022, 1, 1}], DateObject[{2022, 3, 1}], "Week", CalendarType -> "Islamic"]

"Julian"暦の日付があるTimeSeriesオブジェクトを作成する：

Wolfram Language code: TimeSeries[Range[5], {DateObject[{2024, 2, 14}, CalendarType -> "Julian"], Automatic, "Day"}]

これらの日付を"Islamic"暦に変換する：

Wolfram Language code: TimeSeries[%, CalendarType -> "Islamic"]
Wolfram Language code: Normal[%]

アプリケーション  (1)

現在の瞬間を使用可能なすべての暦で表現する：

Wolfram Language code: AssociationMap[DateObject[Now, CalendarType -> #]&, CalendarData[]]//Dataset

特性と関係  (2)

使用可能な暦の種類のリストはCalendarDataを使って入手できる：

Wolfram Language code: CalendarData["DateCalendar"]

これには算術暦と天文暦の両方が含まれる：

Wolfram Language code: CalendarData["ArithmeticCalendar"]
Wolfram Language code: CalendarData["AstronomicalCalendar"]

DateObjectのデフォルトの暦タイプは"Gregorian"である：

Wolfram Language code: range = DateRange[DateObject[{2022, 1, 1}], DateObject[{2022, 2, 1}], "Week"]

同じ日付の出力を"Jewish"暦に変更する：

Wolfram Language code: DateRange[DateObject[{2022, 1, 1}], DateObject[{2022, 2, 1}], "Week", CalendarType -> "Jewish"]
Wolfram Language code: % == range

入力の日付の暦も変更する：

Wolfram Language code: DateRange[DateObject[{2022, 1, 1}, CalendarType -> "Jewish"], DateObject[{2022, 2, 1}, CalendarType -> "Jewish"], "Week", CalendarType -> "Jewish"]

これで，日付範囲が異なる時期を表すようになった：

Wolfram Language code: % == range
Wolfram Research (2012), CalendarType, Wolfram言語関数， https://reference.wolfram.com/language/ref/CalendarType.html （2020年に更新）.

テキスト

Wolfram Research (2012), CalendarType, Wolfram言語関数， https://reference.wolfram.com/language/ref/CalendarType.html （2020年に更新）.

CMS

Wolfram Language. 2012. "CalendarType." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/CalendarType.html.

APA

Wolfram Language. (2012). CalendarType. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CalendarType.html

BibTeX

@misc{reference.wolfram_2026_calendartype, author="Wolfram Research", title="{CalendarType}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/CalendarType.html}", note=[Accessed: 17-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_calendartype, organization={Wolfram Research}, title={CalendarType}, year={2020}, url={https://reference.wolfram.com/language/ref/CalendarType.html}, note=[Accessed: 17-July-2026]}