WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CantorMesh[n]

カントール(Cantor)集合のステップ n を表すメッシュ領域を与える．

CantorMesh[n,d]

次元 d のカントール集合のステップ n を与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
DataRange  
MeshCellHighlight  
MeshCellLabel  
Show More Show More
MeshCellMarker  
MeshCellShapeFunction  
MeshCellStyle  
PlotTheme  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

CantorMesh

CantorMesh[n]

カントール(Cantor)集合のステップ n を表すメッシュ領域を与える．

CantorMesh[n,d]

次元 d のカントール集合のステップ n を与える．

詳細とオプション

例題

すべて開く すべて閉じる

例  (2)

1Dカントールメッシュ：

Wolfram Language code: CantorMesh[2]

カントールメッシュ線の近似の長さ：

Wolfram Language code: Table[RegionMeasure[CantorMesh[n]], {n, 5}]//Rationalize

式は以下のようになる：

Wolfram Language code: FindSequenceFunction[%, n]

2Dカントールメッシュ：

Wolfram Language code: CantorMesh[1, 2]

3Dカントールメッシュ：

Wolfram Language code: CantorMesh[1, 3]

スコープ  (4)

1Dカントールメッシュ：

Wolfram Language code: CantorMesh[2]

2Dカントールメッシュ：

Wolfram Language code: CantorMesh[2, 2]

3Dカントールメッシュ：

Wolfram Language code: CantorMesh[2, 3]

カントール集合の 番目の近似：

Wolfram Language code: Table[CantorMesh[n], {n, 0, 5}]//Column

オプション  (13)

DataRange  (1)

DataRangeを使うと生成するメッシュ座標の範囲を指定することができる：

Wolfram Language code: CantorMesh[1, 2]
Wolfram Language code: RegionBounds[%]

別の範囲を指定する：

Wolfram Language code: CantorMesh[1, 2, DataRange -> {{0, 1}, {0, 2}}]
Wolfram Language code: RegionBounds[%]

MeshCellHighlight  (2)

MeshCellHighlightを使ってCantorMeshの部分的なハイライトを指定することができる：

Wolfram Language code: CantorMesh[0, 2, MeshCellHighlight -> {{1, All} -> Red, {0, All} -> Black}]

個々のセルはセル指標を使ってハイライトすることができる：

Wolfram Language code: CantorMesh[0, 2, MeshCellHighlight -> {{1, 2} -> {Thick, Red}, {1, 3} -> {Dashed, Black}}]

セルそれ自身を使うこともできる：

Wolfram Language code: CantorMesh[0, 2, MeshCellHighlight -> {Line[{3, 4}] -> {Thick, Red}, Line[{2, 4}] -> {Dashed, Black}}]

MeshCellLabel  (2)

MeshCellLabelを使ってCantorMeshに部分的にラベルを付けることができる：

Wolfram Language code: CantorMesh[0, 2, MeshCellLabel -> {0 -> "Index"}]

個々のセルにはセル指標を使ってラベルを付けることができる：

Wolfram Language code: CantorMesh[0, 2, MeshCellLabel -> {{1, 1} -> "x", {1, 2} -> "y"}]

セルそれ自身を使うこともできる：

Wolfram Language code: CantorMesh[0, 2, MeshCellLabel -> {Line[{1, 3}] -> "x", Line[{3, 4}] -> "y"}]

MeshCellMarker  (1)

MeshCellMarkerを使ってCantorMeshに部分的に値を割り当てることができる：

Wolfram Language code: CantorMesh[0, 2, MeshCellMarker -> {{0, 1} -> 1, {0, 2} -> 2, {0, 3} -> 3, {0, 4} -> 4}]

MeshCellLabelを使ってマーカーを表示する：

Wolfram Language code: CantorMesh[0, 2, MeshCellMarker -> {{0, 1} -> 1, {0, 2} -> 2, {0, 3} -> 3, {0, 4} -> 4}, MeshCellLabel -> {0 -> "Marker"}]

MeshCellShapeFunction  (2)

MeshCellShapeFunctionを使ってCantorMeshに部分的に値を割り当てることができる：

Wolfram Language code: CantorMesh[0, 3, MeshCellShapeFunction -> {1 -> (Tube[#1, .1]&)}]

個々のセルはセル指標を使って描画することができる：

Wolfram Language code: CantorMesh[0, 3, MeshCellShapeFunction -> {{1, 2} -> (Tube[#1, .1]&)}]

セルそれ自身を使うこともできる：

Wolfram Language code: CantorMesh[0, 3, MeshCellShapeFunction -> {Line[{5, 7}] -> (Tube[#1, .1]&)}]

MeshCellStyle  (3)

MeshCellStyleを使ってCantorMeshの部分的なスタイルを指定することができる：

Wolfram Language code: CantorMesh[0, 2, MeshCellStyle -> {{1, All} -> Red, {0, All} -> Black}]

個々のセルはセル指標を使ってハイライトすることができる：

Wolfram Language code: CantorMesh[0, 2, MeshCellStyle -> {{1, 1} -> {Thick, Red}, {1, 2} -> {Dashed, Black}}]

セルそれ自身を使うこともできる：

Wolfram Language code: CantorMesh[0, 2, MeshCellStyle -> {Line[{1, 3}] -> {Thick, Red}, Line[{3, 4}] -> {Dashed, Black}}]

明示的な色指示子を与えることで個々のセルの色を指定する：

Wolfram Language code: CantorMesh[1, 2, MeshCellStyle -> {{2, All} -> Black, {2, 1} -> Red, {2, {2, 3}} -> Pink}]

PlotTheme  (2)

格子線と凡例のテーマを使う：

Wolfram Language code: CantorMesh[1, 2, PlotTheme -> "Detailed"]

テーマを使ってワイヤーフレームを描画する：

Wolfram Language code: CantorMesh[1, 2, PlotTheme -> "Lines"]

アプリケーション  (4)

カントール集合は，単位区間から，三等分したセルの中央部分を繰り返し削除することで生成される：

Wolfram Language code: Column[{CantorMesh[0], CantorMesh[1], CantorMesh[2], CantorMesh[3]}]

2Dで：

Wolfram Language code: Row[{CantorMesh[0, 2], CantorMesh[1, 2], CantorMesh[2, 2]}, Spacer[60]]

3Dで：

Wolfram Language code: Row[{CantorMesh[0, 3], CantorMesh[1, 3], CantorMesh[2, 3]}, Spacer[60]]

カントールメッシュの長さを求める：

Wolfram Language code: Table[RegionMeasure[CantorMesh[k]], {k, 5}]//Rationalize

一般公式：

Wolfram Language code: FindSequenceFunction[%, n]

2Dカントールメッシュの測度値を求める：

Wolfram Language code: Table[RegionMeasure[CantorMesh[k, 2]], {k, 5}]//Rationalize

一般公式：

Wolfram Language code: FindSequenceFunction[%, n]

3Dカントールメッシュの測度値を求める：

Wolfram Language code: Table[{k, RegionMeasure[CantorMesh[k, 3]]}, {k, 0, 3}]//Rationalize

一般公式：

Wolfram Language code: FindSequenceFunction[%, n]

特性と関係  (4)

CantorMeshの出力は，常に全次元のMeshRegionである：

Wolfram Language code: CantorMesh[3, 2]
Wolfram Language code: {MeshRegionQ[%], RegionDimension[%]}

1Dでは，CantorMeshは区間からなる：

Wolfram Language code: CantorMesh[2]
Wolfram Language code: MeshCells[%, RegionDimension[%]]

2Dでは矩形からなる：

Wolfram Language code: CantorMesh[1, 2]
Wolfram Language code: MeshCells[%, RegionDimension[%]]

3Dでは六面体からなる：

Wolfram Language code: CantorMesh[0, 3]
Wolfram Language code: MeshCells[%, RegionDimension[%]]

カントール集合から取り除かれた長さの合計は1である：

Wolfram Language code: Table[RegionMeasure[CantorMesh[n]] / 2, {n, 5}]//Rationalize

一般公式を推定する：

Wolfram Language code: FindSequenceFunction[%, i]
Wolfram Language code: Limit[Sum[%, {i, 1, n}], n -> Infinity]

DataRange->range はRescalingTransform[{…},range]を使うことに等しい：

Wolfram Language code: CantorMesh[1, 2, DataRange -> {{1, 2}, {1, 3}}, Frame -> True]

RescalingTransformを使う：

Wolfram Language code: box = TransformedRegion[CantorMesh[1, 2], RescalingTransform[{{0, 1}, {0, 1}}, {{1, 2}, {1, 3}}]];
Wolfram Language code: MeshRegion[box, Frame -> True]

考えられる問題  (1)

CantorMeshは大きすぎて生成できないことがある：

Wolfram Language code: CantorMesh[20, 3]
Wolfram Research (2017), CantorMesh, Wolfram言語関数， https://reference.wolfram.com/language/ref/CantorMesh.html.

テキスト

Wolfram Research (2017), CantorMesh, Wolfram言語関数， https://reference.wolfram.com/language/ref/CantorMesh.html.

CMS

Wolfram Language. 2017. "CantorMesh." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CantorMesh.html.

APA

Wolfram Language. (2017). CantorMesh. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CantorMesh.html

BibTeX

@misc{reference.wolfram_2026_cantormesh, author="Wolfram Research", title="{CantorMesh}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/CantorMesh.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_cantormesh, organization={Wolfram Research}, title={CantorMesh}, year={2017}, url={https://reference.wolfram.com/language/ref/CantorMesh.html}, note=[Accessed: 12-August-2026]}